Minimize en close button uitschakelen of verbergen.

[bgoo]

De close button heb ik op deze manier weten we omzeilen.

Private Sub Workbook_BeforeClose(Cancel As Boolean)

Cancel = True

End Sub

Echter kan je nogsteeds minimaliseren en verkleinen. Dit wil ik niet mogelijk laten zijn.
Wat ook kan is zorgen dat het scherm in full screen naar boven verschuift zodat je simpelweg niet bij de knoppen kan.

Heeft iemand tips, bedankt!

[HSV]

Probeer onderstaande eens.
In ThisWorkbook.

Private Sub Workbook_WindowResize(ByVal Wn As Window)
 Wn.WindowState = xlMaximized
End Sub

[bgoo]

Bedankt, maar dit werk niet op het programma zelf, alleen op de worksheet.

[Ginger]

De Guru's van Mr.Excel hebben dit ook al 'ns behandeld. Klik hier voor het engelstalige draadje...

Groet, Leo

[bgoo]

Ok super, maar codes met declare etc. Hoe werkt dat precies als ik vragen mag.

Bedankt!

[Warme bakkertje]

Heb je enkele weken de tijd om dat uitgelegd te krijgen. Google maar eens op API.

[bgoo]

Nougoed ik denk dat ik met mijn learningcurve het aardig snel onder de knie. Heb nog nooit gehoord van API maar als je me een kant op kan sturen zou het super zijn. Is API in excell zelf of?

Thanks!

[Warme bakkertje]

http://allapi.mentalis.org/vbtutor/api1.shtml
Maar de code die jij nodig hebt is toch al uitgewerkt in het antwoord van Leo. Je moet die enkel naar jouw bestand kopieëren en klaar is kees.

[bgoo]

Zou je een voorbeeldbestandje kunnen maken voor me?
Ik snap die functies met declare niet.

Dank!

[Warme bakkertje]

Zet deze in een standaardmodule

Option Explicit

Declare Function GetSystemMenu Lib "User32" (ByVal hwnd As Long, ByVal _
    bRevert As Long) As Long
Declare Function DeleteMenu Lib "User32" (ByVal hMenu As Long, ByVal _
    nPosition As Long, ByVal wFlags As Long) As Long
Declare Function FindWindowA Lib "User32" (ByVal lpClassName As String, _
ByVal lpWindowName As String) As Long

Const MF_BYPOSITION As Long = &H400
Const mlNUM_SYS_MENU_ITEMS As Long = 7 'min, max & close
'Const mlNUM_SYS_MENU_ITEMS As Long = 6 'min & max

Sub DisableActiveDialogMenuControls()
    Dim DialogCaption As String
    Dim lHandle As Long, lcount As Long
    On Error Resume Next
    DialogCaption = Application.Caption
    DialogCaption = DialogCaption & vbNullChar
    lHandle = FindWindowA(vbNullString, DialogCaption)
    If lHandle <> 0 Then
        For lcount = 1 To mlNUM_SYS_MENU_ITEMS
            DeleteMenu GetSystemMenu(lHandle, False), 0, MF_BYPOSITION
        Next lcount
    End If
End Sub

Sub EnableActiveDialogMenuControls()
    Dim lHandle As Long
    Dim DialogCaption As String
    On Error Resume Next
    DialogCaption = Application.Caption
    DialogCaption = DialogCaption & vbNullChar
    lHandle = FindWindowA(vbNullString, DialogCaption)
    GetSystemMenu lHandle, True
End Sub

En deze in ThisWorkbook

Private Sub Workbook_Open()
    DisableActiveDialogMenuControls
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    EnableActiveDialogMenuControls
End Sub

[bgoo]

Super dank je wel!!!