Select van Range mislukt

[wieter]

Als je op blad1, op de knop [Nieuw toernooi] klikt, worden op 2 bladen bepaalde cellen gewist.
Daarna zouden de begincellen moeten geselecteerd worden.
En hier loopt het mis: Op blad2, wordt cel G3 niet geselecteerd.
Foutmelding: "Select van range mislukt"
Ik zal wel iets heel dom doen, maar wat?

Sub leegmaken()
Application.ScreenUpdating = False
With Sheets(1)
.Unprotect
.Range("B2:C" & .Cells(.Rows.Count, 1).End(xlUp).Row + 1).ClearContents
.Range("B2").Select
.Protect
End With
With Sheets(2)
.Unprotect
.Range("A3:B214").ClearContents
.Range("H3:G214").ClearContents
.Range("M2").ClearContents
.Range("G3").Select
.Protect
End With
Application.ScreenUpdating = True
End Sub

[edmoor]

Dat zal komen omdat je op dat moment Sheets(1) als active sheet hebt.
Als sheets(2) actief is zal het wel werken maar dan zal de select van b2 op Sheets(1) fout gaan.
Laat het gewoon weg, het is niet nodig.
Of controleer eerst welk blad je actief hebt voordat je een cel actief maakt.

[wieter]

Dat zal het zijn Ed,
Ik was in de veronderstelling, dat als de [ClearContents] werkt, dan zal de [Select] ook wel werken.
Niet dus.
Maar je hebt gelijk, het is niet echt nodig, het is maar verfraaiing.
Bedankt!

[edmoor]

Probeer deze maar eens:

Sub leegmaken()
    Application.ScreenUpdating = False
    With Sheets(1)
        .Unprotect
        .Range("B2:C" & .Cells(.Rows.Count, 1).End(xlUp).Row + 1).ClearContents
        .Protect
    End With
    
    With Sheets(2)
        .Unprotect
        .Range("A3:B214, H3:G214, M2").ClearContents
        .Protect
    End With
    
    Select Case ActiveSheet.Name
        Case "Blad1": Range("B2").Select
        Case "Blad2": Range("G3").Select
    End Select
    Application.ScreenUpdating = True
End Sub

[wieter]

Ik had het opgelost met 2 extra regels:

Sheets(2).Activate

En daarna opnieuw

Sheets(1).Activate

Maar die ACTIVATE in een code is maar niks.
Jouw voorstel is professioneler.
Bedankt

[edmoor]

Let ook op de gegroepeerde range bij ClearContents op Sheets(2).
Wellicht ook een leermomentje

[wieter]

Dat had ik opgemerkt Ed,
Ik heb die groepering vroeger al toegepast, maar ik vergeet nogal vlug (Alzheimer?)

[edmoor]

Wellicht. De Light versie dan