• Privacywetgeving
    Het is bij Helpmij.nl niet toegestaan om persoonsgegevens in een voorbeeld te plaatsen. Alle voorbeelden die persoonsgegevens bevatten zullen zonder opgaaf van reden verwijderd worden. In de vraag zal specifiek vermeld moeten worden dat het om fictieve namen gaat.

Nieuwe vraag, kopieren van een formule in de formulebalk met veranderende waarden

Status
Niet open voor verdere reacties.
P

pilsfan

Gebruiker
Lid geworden
30 mei 2017
Berichten
11
Hallo allemaal,

Ik heb weer een nieuwe vraag. Ik heb een bestand gemaakt om een weekstaat in te vullen.

Hier kan gekozen worden voor een weeknummer (B3) ( lopend van zaterdag t/m vrijdag ) en een dag in de week (B4). Als uitslag van deze combinatie moet automatisch de datum worden ingevuld in een enkele cel. Ik krijg dit wel voor elkaar voor een week. Maar hoe ga ik dit nu doortrekken in de formulebalk zodat ik geen 365 regels hoef in te voeren.

De formule tot nu toe:

=ALS(EN(B3=25;B4="zaterdag");"17-6-2017";
ALS(EN(B3=25;B4="zondag");"18-6-2017";ALS(EN(B3=25;B4="maandag");"19-6-2017";ALS(EN(B3=25;B4="dinsdag");"20-6-2017";ALS(EN(B3=25;B4="woensdag");"21-6-2017";
ALS(EN(B3=25;B4="donderdag");"22-6-2017";ALS(EN(B3=25;B4="vrijdag");"23-6-2017";
ALS(EN(B3=26;B4="zaterdag");"24-6-2017";"niet bekend"))))))))
 
De maandag in een bepaald weeknummer is met onderstaande functie te bepalen. A1 bevat het jaar, B3 het weeknummer volgens de bij ons gebruikelijke ISO methode:

Code: 
=DATE($A$1;1;1)+($B$3-IF(WEEKDAY(DATE($A$1;1;1);2)<5;1;0))*7-WEEKDAY(DATE($A$1;1;1);2)+1
of in NL versie:
Code: 
=DATUM($A$1;1;1)+($B$3-ALS(WEEKDAG(DATUM($A$1;1;1);2)<5;1;0))*7-WEEKDAG(DATUM($A$1;1;1);2)+1
Als je een tabelletje maakt met Maandag, dinsdag, ... onder elkaar en je hebt dit tabelletje in de cellen Z1:Z7 staan, dan krijg je de datum van een bepaalde dag als volgt:

Code: 
=DATE($A$1;1;1)+($B$3-IF(WEEKDAY(DATE($A$1;1;1);2)<5;1;0))*7-WEEKDAY(DATE($A$1;1;1);2)+MATCH($B$4;$Z$1:$Z$7;0)
of in NL versie:
Code: 
=DATUM($A$1;1;1)+($B$3-ALS(WEEKDAG(DATUM($A$1;1;1);2)<5;1;0))*7-WEEKDAG(DATUM($A$1;1;1);2)+VERGELIJKEN($B$4;$Z$1:$Z$7;0)
 
Misschien is het onbekend voor jou maar een voorbeeld bestand heeft meer nut om tot een gerichte oplossing te komen. Dus de volgende keer zelf even plaatsen. Klik op Ga geavanceerd en vervolgens op de paperclip.

Zonder tabelletje B1 en B2 zijn de variabelen.
Code: 
=7*($B$2-1)+DATE($B$1;1;4)-WEEKDAY(DATE($B$1;1;4);2)+MATCH(A5;{"za";"zo";"ma";"di";"wo";"do";"vr"};0)-2
 

Bijlagen

  • Datum obv weeknummer.xlsb
    9,3 KB · Weergaven: 46
Status
Niet open voor verdere reacties.
Steun Ons

Nieuwste berichten

Terug
Bovenaan Onderaan