connectie beeindigen veroorzaakt onstabiel gedrag windows7

Status
Niet open voor verdere reacties.
H

hellboy01

Gebruiker
Lid geworden
18 jun 2006
Berichten
333
Hi ,
Ik heb een scriptje (met hulp van Edmoor) dat een csv oppakt omzet naar xl en in een workbook zet.
Nu had ik gezien in een YouTube filmpje van Alex Cantu dat het verstandig is om aan het eind van het script je connectie te termineren. Alleen merk ik dat mijn windows wat raar begon te doen, dus heb ik het connectie beeindig gedeelte uit gecomment en toen was het windows gebeuren ook voorbij.
Weet iemand of dat noodzakelijk is om een connectie te termineren?
En weet iemand of al die opties noodzakelijk zijn om aan te geven , ik heb eigenlijk alleen commadelimited nodig?
Alvast bedankt.
Rob

Code: 
Sub CSV_2_XLFile()

Dim fName As String

'ChDir ("D:\ING CSV downloads\")
'fName = Application.GetOpenFilename()

With Application.FileDialog(msoFileDialogOpen)
        .InitialFileName = "D:\ING CSV downloads"
        .Title = "Selecteer bestand"
        .ButtonName = "KIES NU"
        .FilterIndex = 6
        .AllowMultiSelect = False
        If .Show Then
            fName = .SelectedItems(1)
            'MsgBox fName
        End If
    End With

Sheet15.Activate
Sheet15.Range("A1:Z1000").Clear


    With ActiveSheet.QueryTables.Add(Connection:= _
        "TEXT;" + fName, _
        Destination:=Sheet15.Range("$A$1"))
        .FieldNames = True
        .RowNumbers = False
        .FillAdjacentFormulas = False
        .PreserveFormatting = True
        .RefreshOnFileOpen = False
        .RefreshStyle = xlInsertDeleteCells
        .SavePassword = False
        .SaveData = True
        .AdjustColumnWidth = True
        .RefreshPeriod = 0
        .TextFilePromptOnRefresh = False
        .TextFilePlatform = 850
        .TextFileStartRow = 1
        .TextFileParseType = xlDelimited
        .TextFileTextQualifier = xlTextQualifierDoubleQuote
        .TextFileConsecutiveDelimiter = False
        .TextFileTabDelimiter = False
        .TextFileSemicolonDelimiter = False
        .TextFileCommaDelimiter = True
        .TextFileSpaceDelimiter = False
        .TextFileColumnDataTypes = Array(4, 1, 1, 1, 1, 1, 1, 1, 1)
        .TextFileTrailingMinusNumbers = True
        .Refresh BackgroundQuery:=False
    End With
    
'    Dim wb_Connection As WorkbookConnection
'    For Each wb_Connection In ActiveWorkbook.Connections
'      If InStr(fName, wb_Connection.Name) > 0 Then
'         wb_Connection.Delete
'      End If
'    Next wb_Connection
      
End Sub
 
Alle standaard opties die je middels een macro-opmame krijgt mag je weglaten.

Gebruik geen zaken als Sheet15.Activate je kan dit beter oplossen met
Code: 
With Sheet15
..code
End with
 
Hi VenA, bedankt voor de tip, alles werkt, ik heb de code nu zo staan.

Code: 
Sub CSV_2_XLFile()

Dim fName As String

With Application.FileDialog(msoFileDialogOpen)
        .InitialFileName = "D:\ING CSV downloads"
        .Title = "Selecteer bestand"
        .ButtonName = "KIES NU!!!"
        .FilterIndex = 6
        .AllowMultiSelect = False
        If .Show Then
            fName = .SelectedItems(1)
        End If
    End With

Sheet15.Range("A1:Z1000").Clear

With Sheet15.QueryTables.Add(Connection:= _
    "TEXT;" + fName, _
    Destination:=Sheet15.Range("$A$1"))
        .TextFileCommaDelimiter = True
        .Refresh BackgroundQuery:=False
End With
    
End Sub
 
Laatst bewerkt:
Misschien handig om ook even te toetsen of er niet op cancel geklikt is.

Code: 
Sub CSV_2_XLFile()
  Dim fName As String

  With Application.FileDialog(msoFileDialogOpen)
    .InitialFileName = "D:\ING CSV downloads"
    .FilterIndex = 6
    .AllowMultiSelect = False
    If .Show Then fName = .SelectedItems(1)
  End With
  
  If fName <> "" Then
    With Sheet15
      .Range("A1:Z1000").Clear
      With .QueryTables.Add("TEXT;" & fName, .Range("$A$1"))
        .TextFileCommaDelimiter = True
        .Refresh BackgroundQuery:=False
      End With
    End With
  End If
End Sub
 
Als je niet zeker bent van het bereik.
Onderstaand vreet geen tijd.
Code: 
.cells.clear
of:
Code: 
.cells.clearcontents
of:
Code: 
.cells(1).currentregion.clearcontents
 
Status
Niet open voor verdere reacties.
Steun Ons

Nieuwste berichten

Terug
Bovenaan Onderaan