Meerdere PPT-bestanden opslaan als JPG-bestand in 1 actie

Status
Niet open voor verdere reacties.

SA3

Gebruiker
Lid geworden
3 jan 2016
Berichten
127
Ik wil een groot aantal PPT-bestanden opslaan als jpg-bestanden.
Omdat één voor één veel werk is zoek ik naar een manier om dit te automatiseren.
Hoe kan ik hier een batch- of bulk actie voor maken?
 
Vroeger kon je dat bij Pdfcreator.... moet je de print optie als pdf veranderen in jpg en de naamgeving automatisch laten doen. Destijds was er een format voor de naamgeving.
Kijk even of het nog steeds kan....

De setting van pdf naar jpg moet je VOORAF doen bij de pdfcreator instellingen, niet bij eigenschappen als je print, dan zie je dat niet meer staan.
 
Is het misschien zo te doen. Online. :thumb: Heb het net geprobeerd met een eenvoudige pptx. Het lukte me.

Ik weet alleen niet als je met hele grote bulks werkt hoe het dan gaat. Het downloaden kan even duren.

Het komt binnen in een zip. Die zip kun je eenvoudig uitpakken. Bovenin staan nog veel meer dingetje. Wat je er mee kunt, best veel. Bestandsgrootte, weet ik niet precies. Afin neus maar eens rond/

Maar ja het scheelt een hoop gedoe. Probeer eens. Succes.

https://convertio.co/nl/ppt-jpg/
 
Laatst bewerkt:
Bij de nieuwere Pdfcreator kan het ook, via de button Profile settings (ENG) ... zal wel Profiel Instellingen in NL zijn...
Daar kiezen voor jpg en autosave en dan is er ook nog een stukje waar je de naam kunt kiezen met vervolg nummer of zo...
 
Code:
Sub Save_PowerPoint_Slide_as_Images(path As String)
    Dim sImagePath As String
    Dim sImageName As String
    Dim sPrefix As String
    Dim oSlide As Slide '* Slide Object
    Dim lScaleWidth As Long '* Scale Width
    Dim lScaleHeight As Long '* Scale Height
    On Error GoTo Err_ImageSave

    sImagePath = path
    sPrefix = Split(ActivePresentation.Name, ".")(0)
    For Each oSlide In ActivePresentation.Slides
    sImageName = sPrefix & "-" & oSlide.SlideIndex & ".jpg"
    oSlide.Export sImagePath & "\" & sImageName, "JPG"
    Next oSlide

Err_ImageSave:
    If Err <> 0 Then
    MsgBox Err.Description
    End If
End Sub
bron: http://www.free-power-point-templates.com/articles/using-vba-to-export-powerpoint-slides-to-images/

edit: getest met 1 presentatie in powerpoint2007, als je verder wil met deze code dan kunnen we wel de code aanpassen zodat alle presentaties in 1 map omgezet worden.
 
Laatst bewerkt:
Dag Alphamax. Ik wil verder met je VBA-code. Maar kan je me even op weg helpen. Hoe implementeer en start ik deze code in PP?
 
  1. unzip het bestand (we kunnen helaas geen .ppt-bestanden uploaden in dit forum)
  2. open de presentatie
  3. toets ALT+F8
  4. run de macro "PresentationsToImages"
  5. houd in de dialogbox, de SHIFT-toets vast om meerdere bestanden te selecteren
  6. click op "Openen"


De presentaties zullen achter elkaar open flitsen en sluiten, de afbeeldingen staan in dezelfde map als de presentaties
Probeer het eerst eens met een vijftal presentaties
Het kan zijn dat er een vertragingslus ingebouwd moet worden omdat de code niet snel genoeg de afbeeldingen wegschrijft

Code:
[SIZE=1]Option Explicit

Public Sub PresentationsToImages()

    Dim lngPresentations As Long
    Dim strImageName As String
    Dim strImagePath As String
    Dim strPresentationName As String
    Dim strPresentationPath As String
    Dim objSlide As Object

    On Error Resume Next

    With Application.FileDialog(msoFileDialogOpen)
        .AllowMultiSelect = True
        .Show
        For lngPresentations = 1 To .SelectedItems.Count
            strPresentationPath = .SelectedItems(lngPresentations)
            Presentations.Open strPresentationPath, msoTrue
            With ActivePresentation
                strPresentationName = Split(.Name, ".")(0)
                strImagePath = .path
                For Each objSlide In .Slides
                    With objSlide
                        strImageName = strPresentationName & "-" & Format(.SlideIndex, "000") & ".jpg"
                        .Export strImagePath & "\" & strImageName, "JPG"
                    End With
                Next
                .Close
            End With
        Next
    End With
    
    MsgBox "Presentations exported as images."
    
End Sub
[/SIZE]
 

Bijlagen

  • helpmij SA3 powerpoint presentations to images.zip
    30,7 KB · Weergaven: 53
Dag alphamax. Hartelijk dank. Werkt als een speer. Kan ik ook gebruiken voor andere PPT-wijzigingen.
 
Status
Niet open voor verdere reacties.
Terug
Bovenaan Onderaan