Macro automatisch verzenden met 3G

Status
Niet open voor verdere reacties.

sph

Gebruiker
Lid geworden
21 feb 2014
Berichten
160
Ik heb op een formulier een knop toegevoegd gekoppeld aan een macro dat automatisch een .pdf van 2 werkbladen maakt,
waarbij de .pdf via .send in outlook verzonden wordt.

Met wifi verbinding gaat het allemaal goed,
maar tijdens het verzenden tijdens 3g blokkeert outlook het automatisch verzenden onbedoelt door te vragen of er echt 3g contact moet worden gemaakt i.v.m. extra kosten.

Kan ik dit oplossen binnen de macro?

De instellingen van outlook zijn niet te wijzigen, omdat ik geen admin rechten heb (werk laptop).
 
Laatst bewerkt:
Dat is een onderdeel van beveiligsinstellingen in Oulook die in de instellingen en/of in het register gewijzigd kunnen worden.
Vraag dus je systeembeheerder.
 
Het lijkt me geen Outlookinstelling maar een connectie-instelling.
 
Het is een instelling die ik niet kan veranderen vanwege het niet hebben van admin rechten.
Via het register schijnt dat ik de 'metered connection' melding kan omzeilen.
 
Daarom zeg ik, vraag het je systeembeheerder.
 
Dat is nogal omslachtig in mijn geval vanwege een taal- en afstandsbarriére.

Kan ik de macro zo aanpassen dat wanneer ik akkoord ga met outlook data tijdens de metered melding, de mail alsnog verzonden wordt ipv dat de macro stopt?
 
Nee. Dat is echt een Outlook beveiliging die door een Admin moet worden aangepast.
Wat je wel kan doen is de macro zo ombouwen dat deze geen Outlook maar CDO gebruikt om de mail via een op te geven SMTP server te versturen.

Een voorbeeld:
Code:
Sub CDOmail()
    Dim iMsg As Object
    Dim iConf As Object
    Dim Flds As Variant

    Dim SMTPsendusing As Byte
    Dim SMTPauthenticate As Byte
    Dim SMTPserver As String
    Dim SMTPserverport As Integer
    Dim SMTPusessl As Boolean
    Dim SMTPusername As String
    Dim SMTPpassword As String
    Dim SMTPconnectiontimeout As Integer
    
    Set iMsg = CreateObject("CDO.Message")
    Set iConf = CreateObject("CDO.Configuration")

    SMTPsendusing = 2
    SMTPauthenticate = 1
    SMTPserver = "smtp.gmail.com"
    SMTPserverport = 465
    SMTPusessl = True
[COLOR="#FF0000"]    SMTPusername = "jouwmailaddress@gmail.com"
    SMTPpassword = "JouwGMAILwachtwoord"[/COLOR]
    SMTPconnectiontimeout = 10
    
    iConf.Load -1    ' CDO Source Defaults
    Set Flds = iConf.Fields
    With Flds
        .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = SMTPsendusing
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = SMTPauthenticate
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = SMTPserver
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = SMTPserverport
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = SMTPusessl
        .Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = SMTPusername
        .Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = SMTPpassword
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = SMTPconnectiontimeout
        .Update
    End With

    With iMsg
        Set .Configuration = iConf
[COLOR="#008000"]        .To = "iemand@eenmailbox.nl"
        .CC = ""
        .BCC = ""
        .From = SMTPusername
        .Subject = "Belangrijk bericht"
        .TextBody = "De mail tekst"
        .AddAttachment "C:\Map\Bestand.pdf"[/COLOR]
        .Send
    End With

    Set iMsg = Nothing
    Set iConf = Nothing
    Set Flds = Nothing
End Sub

Je hoeft dan alleen maar een Gmail adres te hebben en de rood gemarkeerde instellingen te wijzigen.
En de berichtgegevens uiteraard. Hierboven groen gemarkeerd.
Iedere andere SMTP server kan uiteraard ook als je daar alle gegevens van weet.
 
Laatst bewerkt:
Status
Niet open voor verdere reacties.
Steun Ons

Nieuwste berichten

Terug
Bovenaan Onderaan