Combineren voorwaarde met vert.zoeken

[jesper2019]

Beste lezer,

Ik probeer een formule op te stellen waarbij de vert.zoeken functie pas werkt wanneer aan een bepaalde voorwaarde wordt voldaan. Momenteel hanteer ik voor de vert.zoeken functie de volgende formule:

=VERT.ZOEKEN(W2;'Januari 2019'!A1:'Januari 2019'!B402;2;ONWAAR)


Nu wil ik deze formule pas in werking laten treden wanneer in tabel S1 (Blad 1) benzine wordt ingevuld. Slechts wanneer benzine wordt ingevuld zou de bovenstaande formule dus in werking moeten treden. Is er misschien iemand die een voorwaarde zou kunnen toevoegen aan de formule, waardoor dit mogelijk wordt?

Alvast bedankt!

 

[AlexCEL]

Zo wellicht?

=ALS(Blad1!S1="benzine";VERT.ZOEKEN(W2;'Januari 2019'!A1:B402;2;0);"")

 

[jesper2019]

Bedankt voor je reactie! Met de formule krijg ik het nog steeds niet werkend. Om het duidelijker te maken heb ik een Excel document toegevoegd om te laten zien wat ik precies wil berekenen.


De automatische in te vullen waarde in kolom D dient er dus alleen te komen als de brandstof in kolom B benzine is.


Heel erg bedankt voor je hulp!

 

[edmoor]

In dat document staat een spatie achter zowel Benzine als Diesel en gaat het nooit werken als je dat niet weet.
Zo zie je maar weer dat het altijd beter is om direct een voorbeeld document te plaatsen.

=ALS(B2="Benzine";VERT.ZOEKEN(C2;'2018'!A1:B12;2;ONWAAR);"")

 

[jesper2019]

Mijn excuses voor de veroorzaakte verwarring. Ik had inderdaad meteen het documenten moeten uploaden om het duidelijker te maken.

Hartelijk dank voor de hulp, het werk perfect nu!

 

[edmoor]

Geen probleem.
Het is opgelost en daar gaat het om

 

[jesper2019]

Nu ik eenmaal de smaak te pakken heb vraag ik me af of de formule nog uitgebreid kan worden. Is het nu ook mogelijk dat de formule uitgebreid kan worden met een andere tarief wanneer het "diesel" betreft?

Hiermee bedoel ik het volgende (zie bijlage) :


1. indien het benzine betreft dan dient de bijbehorende waarde uit het tabblad 2018 automatisch ingevuld te worden;

2. indien het geen benzine betreft, dus diesel, dan dient de bijbehorende waarde uit het tabblad 2019 automatisch ingevuld te worden;


Is het mogelijk dat dit omgezet wordt naar één formule (mijn excuses voor de vele vragen) ?

 

[edmoor]

Probeer eens of dit is wat je bedoelt:

=ALS(B2="Benzine";VERT.ZOEKEN(C2;'2018'!$A$1:$B$12;2;ONWAAR);VERT.ZOEKEN(C2;'2019'!$A$1:$B$12;2;ONWAAR))

 

[AlexCEL]

Of:

=VERT.ZOEKEN(C2;ALS(B2="Benzine";'2018'!$A$1:$B$12;'2019'!$A$1:$B$12);2;0)

 

[VenA]

Of:

=VLOOKUP(C2;INDIRECT("'"&2018+(B2<>"Benzine")&"'!$A$1:$B$12");2;0)

 

[jesper2019]

Hartelijke dank voor de reacties, het werkt perfect.

Als uitbreiding op het huidige bestand zou ik nu graag een formule toe willen voegen:

Indien in kolom E2 "nieuw model" staat en de brandstof "Benzine" is dan dient de waarde uit C2 verminderd te worden met 6. Indien in kolom E2 "nieuw model" staat, en de brandstof "Diesel" is (dus geen benzine) dan dient de waarde uit C2 verminderd te worden met 8. Ik geprobeerd om dit in een =ALS(EN formule te omschrijven, maar dit gaat ver boven mijn kennis van Excel.

 

[AlexCEL]

Zo?

=VERT.ZOEKEN(C2-ALS(E2="nieuw model";ALS(B2="Benzine";6;8);0);ALS(B2="Benzine";'2018'!$A$1:$B$12;'2019'!$A$1:$B$12);2;0)

N.B. weer de SPATIE achter "nieuw model" WEGHALEN

 

[jkpieterse]

INDIRECT

NIet de beste keuze in combinatie met VERT.ZOEKEN, zorgt dat de (trage) functie telkens moet worden berekend, ongeacht of de bron is gewijzigd.

 

[jesper2019]

Hartelijk bedankt voor de reactie. In mijn eerdere bericht heb ik de te berekenen waarde(s) niet geheel juist geschetst. De werkelijke situatie is als volgt:

Indien in kolom F2 "nieuw model" staat en de brandstof "Benzine" is dan dient de waarde uit D2 verminderd te worden met 6. Indien in kolom F2 "nieuw model" staat, en de brandstof "Diesel" is (dus geen benzine) dan dient de waarde uit D2 verminderd te worden met 8.

De herrekende waarde dient dus automatisch in kolom C(2) ingevuld te worden. Dit staat dus helemaal los van het bedrag in kolom E en de tabbladen 2018 en 2019.

Mijn excuses voor de gebrekkige schetst van het probleem!

 

[AlexCEL]

Zo dan?

C2: =D2-(F2="nieuw model")*ALS(B2="Benzine";6;8)

Let op de spaties...

 

[jesper2019]

Perfect! Heel erg bedankt!!