De "Behalve" Code VBA excel

[Jay305]

Goedendag Allemaal,
Ik heb een code die ervoor zorgt dat alle actieve werkbladen worden gecheckt en dat alles van die datum in 1 werkblad terecht komen.
Nu heb ik 1 blad die ik niet wil laten samenvoegen maar hoe verwerk ik dit in mijn code?
De code die ik hiervoor nu gebruik is:

Sub VoegSamen()
    Dim oWs As Worksheet
    Dim lMaxRegel As Long
    Dim cl As Range
    Dim sq As Variant
    
   Blad1.[F7:F1000].WrapText = False
    Blad1.[A7:M1000].ClearContents
    
    For Each oWs In ActiveWorkbook.Worksheets                                                           'Doorloop alle werkbladen
        If oWs.Name <> "Hoofdmenu" Or oWs.Name <> "Werkzaamheden" Or oWs.Name <> "Verzamelblad" Then    'Behalve "Totaal"
            lMaxRegel = oWs.Range("A100000").End(xlUp).Row                                              'Bepaal nummer laatste regel
            With oWs
                For Each cl In .Range("A6").Resize(lMaxRegel)                                           'Doorloop alle regels
                    If cl = Blad1.Range("D2").Value Then
                        sq = .Cells(cl.Row, "A").Resize(, 10).Value
                        Blad1.Cells(Rows.Count, "A").End(xlUp).Offset(1).Resize(1, 10).Value = sq
                        Blad1.Cells(Rows.Count, "A").End(xlUp).Offset(, 4).Value = oWs.Name
                        
                        sq = ""
                    End If
                Next cl                                                                                 'Ga naar volgende regel
            End With
        End If
    Next oWs                                                                                            'Ga naar volgende werkblad
    
    Blad1.[F7:F1000].WrapText = True
End Sub

 

[cow18]

opletten, als je niets specifieert, dan maakt excel onderscheid tussen hoofdletters en kleine letters, dus ...

Sub VoegSamen()
     Dim oWs   As Worksheet
     Dim lMaxRegel As Long
     Dim cl    As Range
     Dim sq    As Variant

     Blad1.[F7:F1000].WrapText = False
     Blad1.[A7:M1000].ClearContents

     For Each oWs In ActiveWorkbook.Worksheets                                                           'Doorloop alle werkbladen
          Select Case LCase(oWs.Name)     'de naam van het werkblad in kleine letters
               Case "hoofdmenu", "werkzaamheden", "verzamelblad", "mijn ander blad"     'opsomming van alle niet te behandelen werkbladen, in kleine letters !!!!
               Case Else     'alle andere bladen
                    lMaxRegel = oWs.Range("A100000").End(xlUp).Row                                              'Bepaal nummer laatste regel
                    With oWs
                         For Each cl In .Range("A6").Resize(lMaxRegel)                                           'Doorloop alle regels
                              If cl = Blad1.Range("D2").Value Then
                                   sq = .Cells(cl.Row, "A").Resize(, 10).Value
                                   Blad1.Cells(Rows.Count, "A").End(xlUp).Offset(1).Resize(1, 10).Value = sq
                                   Blad1.Cells(Rows.Count, "A").End(xlUp).Offset(, 4).Value = oWs.Name

                                   sq = ""
                              End If
                         Next cl                                                                                 'Ga naar volgende regel
                    End With
          End Select
     Next oWs                                                                                            'Ga naar volgende werkblad

     Blad1.[F7:F1000].WrapText = True
End Sub

 

[AHulpje]

Stel dat je For-loop het werkblad "Verzamelblad" tegenkomt.
Dan is oWs.Name <> "Hoofdmenu" True en oWs.Name <> "Werkzaamheden" ook True en oWs.Name <> "Verzamelblad" False.
Dus krijg je dus:
If True Or True Or False, dat levert True op en dus wordt Verzamelblad verwerkt.
Hoe je werkblad ook heet, het wordt altijd verwerkt, dat lijkt mij niet de bedoeling.

 

[snb]

Zet alle gegevesn in 1 werkblad, maak op als dynamische tabel en gebruik autofilter of advancedfilter of een draaitabel met slicers.
Gebruik VBA niet om struktuurfouten 'op te lossen'.

Voor een voorbeeld zie: https://www.helpmij.nl/forum/showth...ie-lezen-uit-nieuw-blad?p=6342256#post6342256
Toevallig een soortgelijke vraag op dezelfde dag.