Option Compare Database
Option Explicit
Dim byt_teller As Byte
Dim byt_AantalOverslaan As Byte
'
Private Sub Report_Open(Cancel As Integer)
byt_teller = 0
'hoeft eigenlijk niet, wordt sowieso als 0 geïnitialiseerd
byt_AantalOverslaan = InputBox("Hoe veel etiketten wilt u overslaan?", , 2)
End Sub
Private Sub Detail_Format(Cancel As Integer, FormatCount As Integer)
'Als je bvb. 2 etiketten wil overslaan kan je het eerste 3 keer drukken,
'waarvan de 2 eerste keren onzichtbaar.
Dim bln_NietNaarVolgend As Boolean, besturingselement As Control
bln_NietNaarVolgend = (byt_teller < byt_AantalOverslaan)
'rechterkant resulteert in true (-1) of false (0)
'eerste keer: teller = 0, dus kleiner dan 2
'in een volgende stap wordt de teller al dan niet met 1 verhoogd
'tweede keer: teller = 1, dus kleiner dan 2
'derde keer:teller = 2, dus niet kleiner dan 2 en bln_NietNaarVolgend wordt false
Me.NextRecord = Not bln_NietNaarVolgend
'indien bln_NietNaarVolgend = true dan nextrecord false
byt_teller = byt_teller - bln_NietNaarVolgend
'eerste keer: byt_teller wordt 0 -(-1) = 1
'tweede keer: byt_teller wordt 1 -(-1) = 2
'derde keer: byt_teller wordt 2 -(-1) = 3
For Each besturingselement In Me.Controls
besturingselement.Visible = Not bln_NietNaarVolgend
'eerste en tweede etiket: visible = false want bln_NietNaarVolgend = true
'derde etiket: terug zichtbaar
Next
End Sub