Gemiddelde uit een serie gemiddelden berekenen??

[RoyMaessen]

Hallo,

Ik zit momenteel met een probleem binnen excel dat ik niet getackeld krijg.
Ik hoop dat hier iemand is die mij kan verder helpen.

in een tabel worden 4 afzonderlijke getallen berekend middels een formule: =ALS(H6="";"";ALS(H6<11;"4";ALS(H6=11;"4";ALS(H6=12;"5";ALS(H6=13;"5,5";ALS(H6=14;"6";ALS(H6=15;"6,5";ALS(H6=16;"7";ALS(H6=17;"7,5";ALS(H6=18;"8";ALS(H6=19;"9";ALS(H6=20;"9,5";ALS(H6=21;"10")))))))))))))

Dus ik krijg dan in 4 aparte cellen een waarde die gebaseerd op 4 van deze formules.

Als ik nu een gemiddelde (=gemiddelde....) wil berekenen van deze 4 getallen, gebeurt er niets.
Ik vermoed dat excel de cellen niet als getallen ziet maar als een formule waar geen gemiddelde mee te berekenen is.

Hoe krijg ik nu een gemiddelde van deze cellen berekend?

Roy

 

[de klaes]

ik zou dan deze aanpassing van de formule doen


=ALS.FOUT(WAARDE(ALS(H6="";"";ALS(H6<=11;"4";ALS(H6=12;"5";ALS(H6=13;"5,5";ALS(H6=14;"6";ALS(H6=15;"6,5 ";ALS(H6=16;"7";ALS(H6=17;"7,5";ALS(H6=18;"8";ALS(H6=19;"9";ALS(H6=20;"9,5";ALS(H6=21;"10")))))))))))));0)

heb nu een 0 als je niets invult toegevoegd
anders ging het fout als de cel leeg is

 

[zapatr]

De reden dat je met jouw oplossing het gemiddelde niet kunt berekenen is dat je geen getallen maar tekst laat weergeven ("4"in plaats 4, "5" in plaats van 5, enz.) Er is overigens een veel kortere oplossing mogelijk, nl:

=ALS.FOUT(KIEZEN(MAX(H6-10;1);4;5;5,5;6;6,5;7;7,5;8;9;9,5;10);"")

Vreemd is dat je in jouw gegevens vanaf 5 oplopende waarden hebt met 0,5 maar dat 8,5 ontbreekt.

 

[zapatr]

Ik zie dat er nog wat moet worden toegevoegd voor het geval er in H6 geen waarde staat. Het wordt dan:

=ALS(H6="";"";ALS.FOUT(KIEZEN(MAX(H6-10;1);4;5;5,5;6;6,5;7;7,5;8;9;9,5;10);""))

 

[RoyMaessen]

bijna....

Bedankt voor jullie reacties.
De formule van Klaes werkt inderdaad wel! Mijn dank daarvoor.

@zapatr
Bedankt voor de tip van de "4" en 4
Dit had ik nog niet in de gaten!

De reden dat de waarde onlogisch verspringt (8,5 ontbreekt), heeft te maken met een verdeelsleutel voor rapport punten bij ons op school.

Met jullie hulp heb ik nu een Mooi gemiddelde op drie verschillende tabbladen.
Het gemiddelde wordt middels deze formule berekend: =ALS(ISFOUT(GEMIDDELDE(I6;O6;U6;AA6));"";GEMIDDELDE(I6;O6;U6;AA6))
Deze drie gemiddelden moeten tot slot op een vierde tabblad weer gemiddeld worden.

De formule die ik geprobeerd heb is de volgende:
=GEMIDDELDE('tabblad1'!P6;'tabblad2'!AB6;'tabblad3'!AB6)

Helaas berekent deze formule een leeg veld als 0 en klopt het gemiddelde dus niet.

Hoe zorg ik ervoor dat een lege cel op één of meerdere tabbladen niet wordt meegeteld in het gemiddelde.

Alle pogingen vanuit de helpfunctie en mso-site werken niet. Ik vermoed dat dit met de tabbladen te maken heeft ?!?

Thanx

 

[zapatr]

Daar is wel een oplossing voor.
Wat wil je: dat een lege cel wel bij de aantallen wordt meegeteld of niet?
Voorbeeld: op het eerste blad staat 4, op het tweede blad is de betreffende cel leeg, en op het derde blad staat een 8.
Hoe wil je dan dat het gemiddelde berekend wordt: als (4+0+8)/3 = 12/3 = 4 ?
Of als (4+0+8)/2 = 12/2 =6 ?

 

[RoyMaessen]

hoi zapatr,

ik wil inderdaad dat de lege cellen niet meetellen. dus 4+0+8 = 12/2=6

 

[zapatr]

Je schrijft wel: een lege cel, maar is de cel wel echt leeg ?
Of staat er een 0 in ?
Of staat er een formule in die als resultaat een 0 geeft of een formule die als resultaat een blanco cel oplevert ?
Dat is wel belangrijk voor de te geven oplossing.

 

[zapatr]

Als je het gemiddelde berekent zoals hieronder zal het niet fout gaan (als ik tenminste goed heb begrepen wat je wil):

=SOM(Blad1!P6;Blad2!AB6;Blad3!AB6)/SOM(Blad1!P6>0;Blad2!AB6>0;Blad3!AB6>0)

Wijzig de namen Blad1, 2, en 3 in de werkelijke namen.

 

[RoyMaessen]

Hoi zapatr.
Ik ga dit even proberen als ik weer aan mijn pc zit.
Het gaat om een cel die leeg is na de formule met "". Hij is dan denk ik niet echt leeg. ..

Bedankt alweer en ik houd je op de hoogte.

 

[zapatr]

Als het (zoals je schrijft) gaat om een cel met een formule die als resultaat "" geeft, dan kun je daarvoor nijn formule uit bericht #9 niet gebruiken. Dan zou deze (gebruikelijke) formule het moeten doen:

=GEMIDDELDE(Blad1!P6;Blad2!AB6;Blad3!AB6)

Als de mogelijkheid bestaat dat in alle drie die cellen "" komt te staan, dan kun je, ter voorkoming van de vermelding #DEEL0! er dit van maken:

 =ALS.FOUT(GEMIDDELDE(Blad1!P6;Blad2!AB6;Blad3!AB6);"")

 

[zapatr]

En Roy..., gelukt ?

 

[RoyMaessen]

Gelukt!

Hoi Zapatr,

De eerdere "som" formule heeft gedaan wat ik graag wilde!
Super!!

Excuses voor de late reactie, maar ik heb zeer weinig tijd gehad afgelopen week!


Nogmaals bedankt voor je hulp :thumb: