hoogste scores aftrekbaar in uitslagen programma

[novec]

Ik heb een Excel sheet voor zeilwedstrijd uitslagen.
dus 20 races is 20 uitslagen.
Per vier wedstijden krijgt de deelnemer recht op één aftrek. Bij 20 races dus 5 aftrek. En dus worden de overig 15 races opgeteld om de totaal score te bepalen.
Maar nu wil ik dat Excel zelf bepaald wat de hoogste scores zijn om die af te kunnen trekken.
Ik zit zelf te denken aan een formule waarbij de som van de hele reeks wordt berrekend minus de hoogste getallen waarbij het aantaal hoge getallen dus nog verschillend kan zijn ook.
ik heb al bepaald in mijn sheet hoeveel aftrek in de reeks zit. Maar nu dus nog wlek ik mag aftrekken.
Wie helpt ?


Steven

 

[Wigi]

Gebruik

=GROOTSTE(cellen;1)
=GROOTSTE(cellen;2)
=GROOTSTE(cellen;3)
=GROOTSTE(cellen;4)
=GROOTSTE(cellen;5)

voor de 5 grootste getallen uit een reeks getallen. cellen verwijst naar het bereik met jouw getallen.

Wigi

 

[oeldere]

waarschijnlijk kan dit wel met de formule MAX.

anders plaats eens een bestandje ontdaan van gevoelige info.

wellicht dat iemand jou kan helpen.

met vriendelijke groeten,

Oeldere

 

[novec]

dit werkt nog niet

de suggestie met grootste is niet toepasbaar omdat ik per reeks een verschillend aantal kan aftrekken
Heeft een zeiler 18 starts dan zijn er 4 aftrek en bij 20 5 aftrek
ik sluit even een bestandje bij dan kun je even meekijken svp

 

[Joske2000]

Het voorstel van Wigi werkt wel degelijk :thumb:

=ALS(C2=5;GROOTSTE(H2:AA2;1)+GROOTSTE(H2:AA2;2)+GROOTSTE(H2:AA2;3)+GROOTSTE(H2:AA2;4)+GROOTSTE(H2:AA2;5);ALS(C2=4;GROOTSTE(H2:AA2;1)+GROOTSTE(H2:AA2;2)+GROOTSTE(H2:AA2;3)+GROOTSTE(H2:AA2;4);ALS(C2=3;GROOTSTE(H2:AA2;1)+GROOTSTE(H2:AA2;2)+GROOTSTE(H2:AA2;3);ALS(C2=2;GROOTSTE(H2:AA2;1)+GROOTSTE(H2:AA2;2);ALS(C2=1;GROOTSTE(H2:AA2;1))))))

Joske

 

[oeldere]

de suggestie met grootste is niet toepasbaar omdat ik per reeks een verschillend aantal kan aftrekken
Heeft een zeiler 18 starts dan zijn er 4 aftrek en bij 20 5 aftrek
ik sluit even een bestandje bij dan kun je even meekijken svp

welke waardes dienen dan opgeteld te worden?

de 5 aftrek (waar gaan deze dan vanaf => van welke cel?

laat toch even weten, hoe je het bedoeld, want het is me niet helemaal duidelijk.

Met vriendelijke groeten,

Oeldere

 

[Wigi]

Voor rij 2:

=SOM(O2: DJ2)-SOM(GROOTSTE(O2: DJ2;RIJ($1:$5)))

en niet bevestigen met Enter maar Ctrl-Shift-Enter daar het een matrixformule betreft.

Wigi

 

[bandito bob]

Voor de punten, waarbij de hoogste afvallen:

=ALS(AANTAL(H2:DC2)<4;SOM(H2:DC2);SOMPRODUCT(((H2:DC2+KOLOM(H2:DC2)/1000)<GROOTSTE((H2:DC2+KOLOM(H2:DC2)/1000);INTEGER(AANTAL(H2:DC2)/4)))*H2:DC2))

p.s. wel ff de spaties in het bereik wissen.

 

[bandito bob]

Voor rij 2:

=SOM(O2: DJ2)-SOM(GROOTSTE(O2: DJ2;RIJ($1:$5)))

en niet bevestigen met Enter maar Ctrl-Shift-Enter daar het een matrixformule betreft.

Wigi

Die trekt altijd de hoogste 5 getallen af, terwijl de hoogste 5 er pas afgaan bij een invoer van 20 t/m 23 getallen....geloof ik....

 

[HSV]

En deze voor G2, en doorvoeren naar onderen.

=SOMPRODUCT(GROOTSTE((H2:DC2<>"")*(H2:DC2);RIJ($A$1:INDIRECT("A"&C2))))

Pffff, heb me rot gezocht wat er aan mankeerde.
De spatie die ik maar niet kon vinden.
Wel de opmaak van datum in AH2

 

[Wigi]

Die trekt altijd de hoogste 5 getallen af, terwijl de hoogste 5 er pas afgaan bij een invoer van 20 t/m 23 getallen....geloof ik....

Inderdaad, heb ik over het hoofd gezien, maar kan ook wel ingebouwd worden door de vraagsteller vermoed ik.

 

[bandito bob]

En deze voor G2, en doorvoeren naar onderen.

=SOMPRODUCT(GROOTSTE((H2:DC2<>"")*(H2:DC2);RIJ($A$1:INDIRECT("A"&C2))))

Pffff, heb me rot gezocht wat er aan mankeerde.
De spatie die ik maar niet kon vinden.
Wel de opmaak van datum in AH2

:thumb: De methode met indirect wou ik ook toepassen, maar het lukte me niet omdat ik hem over het hele bereik wou toepassen... Het is zo wel veel makkelijker.
De formule voor het aantal punten kan dan een stukkie korter:

=SOM(H2:DC2)-ALS(C2=0;0;SOMPRODUCT(GROOTSTE((H2:DC2);RIJ($A$1:INDIRECT("A"&C2)))))

 

[novec]

Wow,

Paul, Wigi, Oeldere, Joske en Frans !
Mijn complimenten.
Ik ben geweldig geholpen met de oplossing.
Inderdaad werkt de formule voorbeeldig. Ik probeer hem te begrijpen en doe dat nog niet helemaal, maar daar ga ik uitkomen. In ieder geval reuze bedankt allemaal!!

Steven