ISO.WEEKNUMMER met tweecijferig jaartal

[Archipel]

Hallo forumleden,

Ik gebruik ISO.WEEKNUMMER die gekoppeld is aan een datum.

Mijn vraag: is het ook mogelijk om een ISO,WEEKNUMMER uit te breiden met een 2 cijferig jaartal.

Ma 09-01-2023 is 202302 of anders om

Is dat mogelijk? Graag een reactie.

M.v.g. A

 

[AD1957]

zo?

=ISO.WEEKNUMMER(A1)&JAAR(A1)

 

[OctaFish]

Of je kunt niet goed tellen (en dan is Excel een verduveld handig programma ) of je wilt het volledige jaartal zien. Het eerste (je wilt tóch twee cijfers van het jaartal zien) is wat lastiger, maar kan bijvoorbeeld zo:

=TEKST(F4;"jj")& RECHTS("00"&ISO.WEEKNUMMER(F4);2)

Zo kun je ook de volledige variant doen natuurlijk, maar die gaat wat makkelijker:

=Jaar(F4)& RECHTS("00"&ISO.WEEKNUMMER(F4);2)

 

[AlexCEL]

Gaat dit ook goed voor 1 januari 2023 OctaFish? Niet helemaal...

 

[AD1957]

Deze lijkt me ook goed (als voorbeeld geeft TS 202302)

=JAAR(A1)&TEKST(ISO.WEEKNUMMER(A1); "00")

Adersom zal zelf wel lukken.

 

[AlexCEL]

Ook hier zul je wat moeten verzinnen voor de case 1 januari 2023. Anders krijg je als uitkomst 202352.

 

[popipipo]

#4

Gaat dit ook goed

#5

Deze lijkt me ook goed

Dat is het vervelende van weeknummers bij overgang van het jaar
De eerste dag(en) van het jaar kunnen altijd vallen onder het laatste weeknummer van het voorafgaande jaar.

 

[AlexCEL]

Dan zou ik als uitkomst 202252 verwachten bij input 1-1-23...

Dus zoiets:

=JAAR(F5)-EN(ISO.WEEKNUMMER(F5)>51;MAAND(F5)=1)&TEKST(ISO.WEEKNUMMER(F5);"00")

Excel 365:
=LET(j;ISO.WEEKNUMMER(F5);JAAR(F5)-EN(j>51;MAAND(F5)=1)&TEKST(j;"00"))

 

[Archipel]

Ik dank jullie voor alle aangedragen oplossingen. Geweldig. en zo snel!

M.v.g. A

 

[snb]

@Alex

Ik zat al te wachten:

=MOD(YEAR(A1-WEEKDAY(A1;2)+4);10^3) & RIGHT("0"& WEEKNUM(A1;21);2)