Klanten weergeven op basis van land

[lvisser]

graag zou ik een lijst met waarden willen op basis van een waarde die te kiezen is.
zie het voorbeeld bestand.

van cel A4 tot F19 een weergave van een aantal klanten die geleverd worden in het land wat staat op rij 4.

nu wil ik in cel b23 het land kiezen en dan daaronder alleen de klanten zien die in dat land geleverd worden.
is dit met excel te doen ?

 

[AlexCEL]

Ik hoop dat je Excel 365 gebruikt, dan is het minder ingewikkeld.

=FILTER(A5:A19;VERSCHUIVING(A5:A19;;VERGELIJKEN(B23;B4:F4;0))="x";"")

 

[lvisser]

nee, excel 2019, helaas

 

[emields]

met een macro

 

[JEC.]

Met een formule, doortrekken naar beneden (geen matrix)

=ALS.FOUT(INDEX($A$5:$A$19;AGGREGAAT(15;6;RIJ($1:$15)/(($B$5:$F$19="x")*($B$4:$F$4=$B$23));RIJ(A1)));"")

 

[JEC.]

En een niet-volatiele voor office 365

=FILTER($A$5:$A$19;PRODUCTMAT(($B$5:$F$19="x")*($B$4:$F$4=$B$23);REEKS(5;;1;0)))

 

[HSV]

Ook nog..

=FILTER(A5:A19;--(X.ZOEKEN(B23;A4:F4;A5:F19)="x"))

 

[JEC.]

Ik vergeet vaak hoe goed X.ZOEKEN werkt:thumb:

 

[HSV]

Ja, dat kan je zo hebben.

Ach, ik moet alles nog onder de knie krijgen en voel me een beginneling met Excel 365.
Zoek me rot in de nieuwe materie (zowel de userinterface design als de functies).

Ook geen idee welke functies vanaf welke versie geschikt zijn (15 jaar lang blijven hangen in Excel 2007).

 

[JEC.]

Nog even en je weet niet meer beter. Wat moet je zonder de Filter functie

 

[lvisser]

Werkt prima, bedankt !!

 

[lvisser]

Met een formule, doortrekken naar beneden (geen matrix)

=ALS.FOUT(INDEX($A$5:$A$19;AGGREGAAT(15;6;RIJ($1:$15)/(($B$5:$F$19="x")*($B$4:$F$4=$B$23));RIJ(A1)));"")

deze bedoel ik dan ...