Helpmij.nl
Helpmij.nl
Helpmij.nl
Steun Helpmij.nl! Klik hier     Computerprobleem? Klik hier!

Quote

Weergeven resultaten 1 tot 13 van 13

Onderwerp: Complexe if then else met lege cellen

  1. #1
    Vraag is opgelost

    Complexe if then else met lege cellen

    Allen,

    Ik heb jullie hulp nodig i.v.m. een complexe if then else in combinatie met lege cellen.

    Ik heb een tabel met een hele roop rijen en 3 kolommen. Ik wil controleren of de waarden uit de kolommen overeenkomen, ZONDER de lege cellen in beschouwing te nemen.
    Eenvoudig zou dit zijn: IF(A1=B1=C1;"ok";"nok"). Echter zitten er een hele reeks lege cellen in waardoor elke formule uitkomt op "nok" gezien een lege cel niet gelijk is aan een cel met een waarde in. Hoe kan ik met een complexe formule(?) deze lege cellen negeren en tot een controle komen?

    Bestandje onderstaand. Is dit mogelijk zonder VBA - ik ken niets van VBA dus in principe moet het zonder VBA...

    Book1.xlsx

    Alvast bedankt!
    Bijgevoegde kleine afbeeldingen Bijgevoegde kleine afbeeldingen Klik op afbeelding voor grotere versie

Naam:  excel.JPG‎
Bekeken: 26
Grootte:  26,1 KB  
    Laatst aangepast door zipke1988 : 14 september 2018 om 16:36

  2. #2
    Giga Senior AlexCEL's avatar
    Geregistreerd
    3 april 2014
    Locatie
    Groningen
    Afstand tot server
    ±117 km
    Mooi plaatje voor een photoshop forum. Plaats een excel bestand s.v.p.
    Laatst aangepast door AlexCEL : 14 september 2018 om 16:30
    -- een voorbeeldbestandje zegt meer dan 1000 woorden --

  3. #3
    Quote Origineel gepost door AlexCEL Bekijk Bericht
    Mooi plaatje voor een photoshop forum. Plaats een excel bestand s.v.p.
    Thanks! Heb m'n best gedaan

    Mijn excuses. Zie opening post voor het bestandje.

  4. #4
    Giga Senior AlexCEL's avatar
    Geregistreerd
    3 april 2014
    Locatie
    Groningen
    Afstand tot server
    ±117 km
    Forumetiquette: Niet QUOTEN s.v.p. Gebruik knop reageer op bericht of tekstvak "snel reageren" onderaan.

    On-topic:
    Code:
    E2: =ALS(SOMPRODUCT(($B2:$D2<>"")/AANTAL.ALS($B2:$D2;$B2:$D2&""))=1;"OK";"NOK")
    -- een voorbeeldbestandje zegt meer dan 1000 woorden --

  5. #5
    Volgens mij werkt dit ook, of zit ik helemaal verkeerd Alexcel

    =ALS(EN(B2=C2;B2=D2);"Ok";"Nok")

  6. #6
    Volgens je voorbeeld is het weer anders

    ALS(OF(B2=C2;B2=D2;C2=D2);"Ok";"Nok")

  7. #7
    AlexCEL, bedankt voor je reactie, dit werkt inderdaad voor het bestandje in bijlage.
    Ik had het vereenvoudigd om te uploaden, maar mijn eigenlijke tabel ziet er iets anders uit (de kolommen staan niet naast elkaar).

    Zie hier voor het bestandje.Book2 - Copy.xlsx

    De kolommen CODE moeten volledige genegeerd worden, en hebben niets te maken met de controle die ik wil uitvoeren. Enkel LAND moet in beschouwing worden genomen.

    Bedankt!


    wbvalk, ik test het even

  8. #8
    Tera Honourable Senior Member
    Verenigingslid
    OctaFish's avatar
    Geregistreerd
    6 februari 2009
    Locatie
    Rotterdam
    Afstand tot server
    ±151 km
    Quote Origineel gepost door AlexCEL Bekijk Bericht
    Mooi plaatje voor een photoshop forum.
    Nee hoor; je onderschat de gemiddelde photoshop-er schromelijk. Of je weet niet wat Photoshop is
    Gebruik de QUOTE knop alleen als je iets wit citeren.
    Op deze pagina kun je zien hoe je met TAGS werkt.

  9. #9
    Ik heb je 2 formules gemaakt
    omdat ik niet zeker ben, als enkel bijvoorbeeld Spanje is ingevuld, dat dit dan geldt als "ok"

    groeten,
    Attached Files Attached Files

  10. #10
    Senior Member
    Geregistreerd
    23 mei 2013
    de formule blijft gelijk enkel de kolomnaam veranderen

    Code:
    =ALS(OF(B2=D2;B2=F2;D2=F2);"Ok";"Nok")
    als er OF staat mag er een lege cel bijzijn
    Als er EN staat moeten ze alle 3 dezelfde waarde hebben.
    Laatst aangepast door emields : 14 september 2018 om 19:45

  11. #11
    Giga Senior AlexCEL's avatar
    Geregistreerd
    3 april 2014
    Locatie
    Groningen
    Afstand tot server
    ±117 km
    Deze geeft volgens mij de gewenste resultaten:
    Code:
    =ALS(SOMPRODUCT(IS.EVEN(KOLOM($B2:$G2))*($B2:$G2<>"")/AANTAL.ALS($B2:$G2;$B2:$G2&""))=1;"OK";"NOK")
    Formule in post #10 gaat niet goed als er bijvoorbeeld Engeland-Engeland-Spanje staat. Volgens mij moet de uitkomst dan NOK zijn...
    -- een voorbeeldbestandje zegt meer dan 1000 woorden --

  12. #12
    AlexCEL,

    Inderdaad, de post #10 geeft mij OK bij Engeland-Engeland-Spanje, terwijl dit NOK moet zijn.
    Jouw formule uit #11 werkt perfect! Bedankt! Kan je mij uitleggen wat de formule precies wil zeggen? Wat berekent de IS.EVEN?


    Bedankt ook aan de rest!
    Laatst aangepast door zipke1988 : 20 september 2018 om 12:39

  13. #13
    Giga Senior AlexCEL's avatar
    Geregistreerd
    3 april 2014
    Locatie
    Groningen
    Afstand tot server
    ±117 km
    1. Je kunt het aantal unieke waarden in het bereik B2:G2 tellen met:
    Code:
    =SOMPRODUCT(1/AANTAL.ALS($B2:$G2;$B2:$G2&""))
    Het rode deel zit erin om lege cellen (nulwaarden) om te zetten in tekst, waardoor deze geen foutmeldingen geven (delen door 0). De SOMPRODUCT zorgt ervoor dat deze functie als matrixfunctie wordt berekend door excel, oftewel dat de functie berekend wordt voor achtereenvolgens B2,C2,D2 etc. en de resultaten worden opgeteld. Ga ik verder niet op in...

    2. We willen niet alle unieke waarden tellen, maar alleen die uit de EVEN kolommen (B, D, F) en alleen als die cel niet leeg is. Elk kolom heeft een nummer (op te vragen via functie KOLOM, A=1, B=2 etc.), de functie IS.EVEN controleert of we met een EVEN of ONEVEN kolomnummer te maken hebben. De waarden meenemen uit niet-lege cellen daar zorgt het gedeelte B2:G2<>"" voor. Deze 2 voorwaarden komen nu als volgt gecombineerd in plaats van de 1 in vorige formule:
    Code:
    =SOMPRODUCT(IS.EVEN(KOLOM($B2:$G2))*($B2:$G2<>"")/AANTAL.ALS($B2:$G2;$B2:$G2&"")
    3. De ALS functie zorgt ervoor dat als bovenstaande gelijk is aan 1 (oftewel in de niet-lege cellen in kolom B, D en F komt slechts 1 unieke waarde voor), dat dan de waarde OK getoond wordt en anders NOK.

    Hopelijk voldoende uitleg zo.
    Laatst aangepast door AlexCEL : 20 september 2018 om 14:54
    -- een voorbeeldbestandje zegt meer dan 1000 woorden --

Berichtenregels

  • U mag geen nieuwe vragen starten.
  • U mag niet reageren op berichten.
  • U mag geen bijlagen versturen.
  • U mag uw berichten niet bewerken.
  •  
Helpmij.nl
Helpmij.nl

Helpmij.nl en business

Partners
Sponsoren