VBA Selectie op voorwaarden die er niet zijn

Status
Niet open voor verdere reacties.
H

Haikom

Gebruiker
Lid geworden
2 aug 2011
Berichten
27
Hallo,

Al veel stukken code om mijn functionaliteiten te coderen heb ik op dit forum kunnen vinden :cool: .
Andere stukken functionaliteit neem ik via 'marco opnemen' op om ze vervolgens over de andere tabbladen te kopiëren.
Maar het lukt mij niet om via Google de juiste vraag te stellen die antwoord geeft op de volgende vraag.

Daarom probeer het nu via het forum.

Hierbij de situatie schets.

  • Het gaat om een testresultaten sheet.
  • Op een overzicht-tabblad heb ik knoppen gemaakt om de resultaten van de tabbladen te selecteren en te kopiëren naar het overzicht tabje, om ze van daaruit te mailen.
  • Er zijn meerdere tabbladen met allemaal dezelfde titelbalk.
  • Ik gebruik het volgende stuk code om op de verschillende tabbladen de rijen te selecteren die aan de voorwaarden voldoen: "Known Issue", "NOK", "Opmerking"
  • Voor ieder tabblad gebruik ik deze code waarbij "Blad1" steeds de naam van het tabblad bevat.​
  • In kolom D (Field4) staat de 'Status' waarden waarop gefilterd moet worden: "Known Issue", "NOK", "Opmerking".

    ActiveSheet.Range("A1:F" & Range("A1").End(xlDown).Row - 0).AutoFilter Field:=4, Criteria1:=Array( _
    "Known Issue", "NOK", "Opmerking"), Operator:=xlFilterValues

  • Nadat dit filter gezet is het de bedoeling dat de Kolommen C2 t/m E geselecteerd worden om naar het overzicht-tabje te worden gekopieerd. Let wel: de onderste regel is variabel omdat je niet weet tot welke regel het filter selecteert.
  • De volgende code gebruik ik daarvoor:

    Range("C2:E" & Range("C2").End(xlDown).Row - 0).Copy
Dit werkt prima totdat de volgende situaties zich voordoen:
  1. Als er geen regels zijn met "Known Issue", "NOK", "Opmerking"
  2. Of Als alleen regel 2 wordt gefilterd.
  3. In deze situatie worden alle regels van C2:E t/m regel 1048576 geselecteerd. Bij het plakken op het overzicht-tabje breekt de code omdat er niet genoeg ruimte is: plakken begint op regel B30 dus dan past C2:E t/m regel 1048576 niet meer.
Als er echter vanaf regel 3 wordt gefilterd (aan het filter voldoet) dan selecteert hij, zoals bedoeld alleen C3:E3.

Omdat ik alle stukjes code bij elkaar Google en zo prima uit de voeten kan gaat het goed. Ik heb helaas nog niet de kennis om precies te 'lezen' wat een regel exact doet, anders dan dat het voor mij werkt.
Tot dit punt dus...Omdat ik de knoppen (met code) dummy-proof wil maken blijkt in de genoemde situaties de code te breken.

Heeft iemand een idee? Alvast bedankt voor de reactie.
 

Bijlagen

  • Map1.xlsm
    16,2 KB · Weergaven: 33
Zo op het eerste zicht (ik spreek me liever niet uit over het feit dat je daar 2 aparte macro's voor gebruikt...) zou je macro 2 zo kunnen wijzigen:
Code: 
If Range("C" & Rows.Count).End(xlUp).Row > 1 Then
    Range("C2:E" & Range("C1").End(xlDown).Row - 0).Copy
End If
 
Wat zal -0 doen?

Hier wordt het geplaatst in K1:M??
Code: 
Sub Macro1()
 With Cells(1).CurrentRegion
    .AutoFilter Field:=4, Criteria1:=Array( _
        "Known Issue", "NOK", "Opmerking"), Operator:=xlFilterValues
    .Offset(1, 2).Resize(, 3).Copy Range("K1")
    .AutoFilter
 End With
End Sub

verkort:
Code: 
Sub Macro1()
 With Cells(1).CurrentRegion
    .AutoFilter 4, Array( _
        "Known Issue", "NOK", "Opmerking"), 7   'of xlfiltervalues
    .Offset(1, 2).Resize(, 3).Copy Range("K1")
    .AutoFilter
 End With
End Sub
 
Enigmasmurf zei:
Z
Code: 
[B]If Range("C" & Rows.Count).End(xlUp).Row > 1 Then[/B]
    Range("C2:E" & Range("C1").End(xlDown).Row - 0).Copy
End If
Klik om te vergroten...

Hallo Enigmasmurf,

Bedankt!

Dat is dus net het stukje code wat ik miste. Dit werkt!

En v.w.b.
Enigmasmurf zei:
Zo op het eerste zicht (ik spreek me liever niet uit over het feit dat je daar 2 aparte macro's voor gebruikt...)
Klik om te vergroten...
In mijn ongetwijfeld niet logisch opgezette code (ben geen programmeur) is het bij mij trial and error: ik bedenk steeds een los stukje functionaliteit met 'wat wil ik?'.
Dan neem ik dat op met een 'macro' en verbaster dat stukje dan met zoeken op Google zodat ik bijvoorbeeld niet met een vast selectie werk, maar met een variabele selectie.
Ik knoop dus steeds meer macro's aan elkaar: ik heb 1 module waar alle code instaat, gescheiden door Sub selecteer_regels(), Sub selecteer_testgevallen(), Sub kopier_bevindingen().

Nu ik de code van HSV zie is dat wel de way to go. Maar zoals gezegd: ben meer een jip&janneke VBA-er van Make it work then next problem.
Als ik het voorbeeld van HSV in de code plak zie ik dat dit bijna is wat ik wil, alleen kan ik die code niet lezen/begrijpen. Zie m'n antwoord op zijn post.
 
HSV zei:
Wat zal -0 doen?

Hier wordt het geplaatst in K1:M??
Code: 
Sub Macro1()
 With Cells(1).CurrentRegion
    .AutoFilter Field:=4, Criteria1:=Array( _
        "Known Issue", "NOK", "Opmerking"), Operator:=xlFilterValues
    .Offset(1, 2).Resize(, 3).Copy Range("K1")
    .AutoFilter
 End With
End Sub

verkort:
Code: 
Sub Macro1()
 With Cells(1).CurrentRegion
    .AutoFilter 4, Array( _
        "Known Issue", "NOK", "Opmerking"), 7   'of xlfiltervalues
    .Offset(1, 2).Resize(, 3).Copy Range("K1")
    .AutoFilter
 End With
End Sub
Klik om te vergroten...

Hallo Harry,

Bedankt voor je reactie. Dit lijkt op echt efficiënte code, anders dan mijn Jip&Janneke code die soms doet wat ik wil, en soms ook niet.

Jou code doet bijna wat ik wil. Alleen gaat bij mij nu de trial and error weer beginnen. (Zie vorige post: ik ben geen programmeur...)

Ik snap uit jou code dat hij de selectie naar K1 kopieert. Hoe hij selecteert kan ik er niet uit opmaken (maar goed, dat ter zijde).

Waar ik nu vastloop is:
  • Dat hij nu naar een vaste waarde kopieert waar ik de plak actie variabel wil hebben zodat hij alles van de tabbladen onder elkaar plakt.
  • Omdat ik niet vooraf weet hoeveel regels per tabblad aan de voorwaarden voldoen moet hij bij iedere plakactie eerst de onderste regel in tabbald 'Overzicht-mail' kolom B opzoeken.
  • De onderste regel opzoeken doe ik nu met dit stukje:
    Code: 
    Range("C2:E" & Range("C2").End(xlDown).Row - 0)
  • Maar hoe ik nu sheet(Overzicht-mail).select en vervolgens de onderste regel vind, om dan de selectie daar te plakken, gaat mijn pet helaas te boven.

Ik heb in het voorbeeld 2 tabs toegevoegd: Overzicht-mail waar de selectie heen moet worden gekopieerd vanaf B9, en nog een tabblad met testresultaten.
Als jou code runt zou hij dus van beide sheets Blad1 en Blad2 de regels die aan de voorwaarden voldoen naar het overzicht moeten kopiëren en wel op de eerste vrije onderste regel.

Heb je daar ook een oplossing voor?

Alvast bedankt voor de reacties.

Zou je daar nog mee kunnen helpen.
 

Bijlagen

  • Map1.xlsm
    19,8 KB · Weergaven: 21
Uiteraard.
Code: 
Sub hsv()
Dim sh As Worksheet, OvzM As Worksheet
Set OvzM = Sheets("Overzicht-mail")
For Each sh In Sheets
 If sh.Name <> OvzM.Name Then
   With sh.Cells(1).CurrentRegion
    .AutoFilter 4, Array("Known Issue", "NOK", "Opmerking"), 7
    .Offset(1, 2).Resize(, 3).Copy OvzM.Cells(Rows.Count, 2).End(xlUp).Offset(Abs(OvzM.Cells(1, 2) <> ""))
    .AutoFilter
   End With
 End If
Next sh
End Sub
 
HSV zei:
Uiteraard.
Code: 
Sub hsv()
Dim sh As Worksheet, OvzM As Worksheet
Set OvzM = Sheets("Overzicht-mail")
For Each sh In Sheets
 If sh.Name <> OvzM.Name Then
   With sh.Cells(1).CurrentRegion
    .AutoFilter 4, Array("Known Issue", "NOK", "Opmerking"), 7
    .Offset(1, 2).Resize(, 3).Copy OvzM.Cells(Rows.Count, 2).End(xlUp).Offset(Abs(OvzM.Cells(1, 2) <> ""))
    .AutoFilter
   End With
 End If
Next sh
End Sub
Klik om te vergroten...


Harry,

Dank je wel. Dit is exact wat ik wil.

Nu komt echter mijn dilemma: als ik deze code ga gebruiken moet ik het begrijpen om a) deze code te kunnen ombouwen zodat het in de daadwerkelijke sheet gaat werken én b) om onderhoud te kunnen plegen als er dingen wijzigen (kolommen toevoegen etc.)

Daar heb ik nog een beetje hulp bij nodig om e.e.a. te begrijpen. Hieronder de delen waar ik niet zo snel uitkom:

1. In de echte sheet zijn er meerdere tabbladen waarbij er 6 tabbladen (BladE, BladF etc, niet de echte namen) zijn met testresultaten. Dit maak ik er nu van (met mijn SQL-kennis) maar dat werkt niet, en de zoekvraag stellen op het forum lukt me ook niet:
WAS
For Each sh In Sheets
If sh.Name <> OvzM.Name Then

WORDT (of iets in deze trant: )
For Each sh In Sheets
If sh.Name IN ("BladE","BladF", BladG", "BladH") Then of If sh.Name = "BladE" OR "BladF" OR BladG" OR "BladH"

2. De .Autofilter is de status kolomD = 4, die kan ik aanpassen naar de 'echte' = 11.

Dan vanaf .Offset(1, 2).Resize(, 3) raak ik de tel kwijt: in mijn voorbeeld worden de kolommen C t/m E vanaf regel 2 geselecteerd 'tot de onderste regel die aan de voorwaarde voldoen'.
In de echte sheet zijn het Kolommen J, K, L. Maar door Offset's te gebruiken ben je natuurlijk af van de kolom-namen.

In het onderstaande stukje kom ik er niet achter waar hij de selectie op baseert: Begint hij in 'Kolom 4' om van daaruit links en rechts van '4' de cellen te selecteren?

.AutoFilter 4, Array("Known Issue", "NOK", "Opmerking"), 7
.Offset(1, 2).Resize(, 3).Copy OvzM.Cells(Rows.Count, 2).End(xlUp).Offset(Abs(OvzM.Cells(1, 2) <> ""))
.AutoFilter

Alvast bedankt voor de reactie.
 
Code: 
Sub hsv()
Dim sh As Worksheet, OvzM As Worksheet
Set OvzM = Sheets("Overzicht-mail")
For Each sh In Sheets(Array("bladE", "bladF", "bladH"))
   With sh.Cells(1).CurrentRegion
    .AutoFilter 11, Array("Known Issue", "NOK", "Opmerking"), 7
    .Offset(1, 9).Resize(, 3).Copy OvzM.Cells(Rows.Count, 2).End(xlUp).Offset(Abs(OvzM.Cells(1, 2) <> ""))
    .AutoFilter
   End With
Next sh
End Sub
1:
Code: 
For Each sh In Sheets(Array("bladE", "bladF", "bladH"))
2: juist
3: De Offset (verschuiving) wordt gedaan vanaf cells(1) → Range("a1"): Offset(rij,kolom)
Offset(1) = 1 rij naar onderen
Offset(0,2) = nul rijen naar onderen en 2 naar rechts.
Offset(2,-3) = 2 rijen naar onderen en 3 kolommen naar links (niet mogelijk vanaf cel A1).
Offset(1,9) = 1 rij naar onderen en 9 naar rechts vanaf A1 = J2.

De Resize (wijzig de grootte): Resize(rij,kolom).
Offset(1,9).Resize(,4): vanaf J2 is dit J,K,L,M.

Ik hoop dat je hiermee geholpen bent, mocht je er niet uitkomen verneem ik het wel.
 
@HSV, Had jouw post gemist en mijn reactie inmiddels verwijderd.
 
Laatst bewerkt:
Fair. :thumb:
 
HSV zei:
Ik hoop dat je hiermee geholpen bent, mocht je er niet uitkomen verneem ik het wel.
Klik om te vergroten...

Harry,

wederom hartelijk dank voor je reactie. Nu begin ik de code beter te begrijpen. Ik vind het wel opvallend hoe verschillend 'opgenomen-code' is t.o.v. (hoe noem je dat) 'echte code' die jij maakt.

Ik ga aan de slag om de code in te bouwen en laat je weten wat het resultaat is.

Nu heb ik in de sheet nog andere 'eigen 'opgenomen' code', die prima werkt, maar er natuurlijk niet uitziet. Ieder stapje wordt tig keer herhaald. Er wordt o.b.v. een waarde (type platform) bepaalde kolommen verborgen en worden testcases geselecteerd.
Met de voorbeelden hierboven en wat zoeken ga ik proberen daar mooie code van te maken.
Mocht ik daarmee tegen problemen aanlopen mag ik die dan in deze post plaatsen?

Groet,
Haiko
 
Uiteraard mag dat, en anders maak je een nieuwe vraag bij je nieuw probleem om deze als opgelost te markeren in je openingsvraag.

Ps. de recorder stelt niet zoveel voor.
Ik gebruik het alleen bij bepaalde methodes die niet of nooit voorbij komen, en maak het met de ingrediënten die ik verkrijg het op mijn manier.

Ik heb ook zo'n vermoeden dat ze daarom Power Query hebben bedacht zodat programmeren straks verleden tijd is.
 
Harry,

Dank voor je hulp. Het is gelukt en werkt (korte testjes gedaan) zoals ik het uitgewerkt had.

Ik ga nu a.d.h.v. jou code kijken of ik de rest voor mekaar kan krijgen.
 
Alvast dank voor al de hulp.

Ik heb een tijdje zitten puzzelen met de hier verkregen code(s) om daar zelf mee verder te bouwen. Helaas kom ik er, na veel proberen, zoeken, proberen nog steeds niet uit.

Vanuit het tabblad Overzicht_Email is een knop om testgevallen 'klaar te zetten'.
De macro die onder de knop zit heb ik opgenomen en daar maakt hij dan het volgende van. Met de inmiddels verkregen code dacht ik: hier kan ik ook 'kort nette code' van maken. (Nee dus.)
Wens:
PHP: 
ALS platform = 1 
DAN verberg dan op tabbladen 1 en 2 de betreffende kolommen
EN filter kolom (afhankelijk van platform) 6, 7, 8 en kolom 18 (onafhankelijk).
ANDERS 
ALS platform = 2 
etc.

Opneem code: of te wel herhaal iets tig X maar toon steeds een andere kolom afhankelijk van platform
Code: 
' Platform1
If Range("K1").Value = 1 Then

    Sheets("Tabblad1").Select
    Columns("C:E").Select
    Selection.EntireColumn.Hidden = True
    Columns("G:I").Select
    Selection.EntireColumn.Hidden = True
    Columns("N:P").Select
    Selection.EntireColumn.Hidden = True
    
    ActiveSheet.Range("A1:R" & Range("A1").End(xlDown).Row - 0).AutoFilter Field:=6, Criteria1:="V"
    ActiveSheet.Range("A1:R" & Range("A1").End(xlDown).Row - 0).AutoFilter Field:=18, Criteria1:="Actief"
        Range("A2").Select
    
    Sheets("Tabblad2).Select
    Columns("C:E").Select
    Selection.EntireColumn.Hidden = True
    Columns("G:I").Select
    Selection.EntireColumn.Hidden = True
    Columns("N:P").Select
    Selection.EntireColumn.Hidden = True

    ActiveSheet.Range("A1:R" & Range("A1").End(xlDown).Row - 0).AutoFilter Field:=6, Criteria1:="V"
    ActiveSheet.Range("A1:R" & Range("A1").End(xlDown).Row - 0).AutoFilter Field:=18, Criteria1:="Actief"
        Range("A2").Select

Else
        'Platform2
        If Range("K1").Value = 2 Then
        
            Sheets("Tabblad2").Select
            Columns("C:G").Select
            Selection.EntireColumn.Hidden = True
            Columns("I:I").Select
            Selection.EntireColumn.Hidden = True
            Columns("N:P").Select
            Selection.EntireColumn.Hidden = True
            
            ActiveSheet.Range("A1:R" & Range("A1").End(xlDown).Row - 0).AutoFilter Field:=8, Criteria1:="V"
            ActiveSheet.Range("A1:R" & Range("A1").End(xlDown).Row - 0).AutoFilter Field:=18, Criteria1:="Actief"
                Range("A2").Select
        
            Sheets("Tabblad2").Select
            Columns("C:G").Select
            Selection.EntireColumn.Hidden = True
            Columns("I:I").Select
            Selection.EntireColumn.Hidden = True
            Columns("N:P").Select
            Selection.EntireColumn.Hidden = True
            
              ActiveSheet.Range("A1:R" & Range("A1").End(xlDown).Row - 0).AutoFilter Field:=8, Criteria1:="V"
              ActiveSheet.Range("A1:R" & Range("A1").End(xlDown).Row - 0).AutoFilter Field:=18, Criteria1:="Actief"
                Range("A2").Select

Ik heb de code gemaakt o.b.v. wat Harry heeft voorgesteld hierboven maar dan net weer even anders.
Vooraf alvast mijn excuses voor als dit de plank helemaal mis slaat...

Code: 
Sub kladje1()

'testgevallen klaarzetten

Dim sh As Worksheet, OvzM As Worksheet
Set OvzM = Sheets("Overzicht_Email")
For Each sh In Sheets(Array("Tabblad1", "Tabblad2"))
    With sh.Cells(1).CurrentRegion
    
    ' Platform1
        If Range("K1").Value = 1 Then
        ' Verberg kolommen
        Range("C:E,G:I,N:P").EntireColumn.Hidden = True
            'Filter op Kolom F(6) en R(18)
            .AutoFilter Field:=6, Criteria1:="V"
            .AutoFilter Field:=18, Criteria1:="Actief"

    Else
    ' Platform2
        If Range("K1").Value = 2 Then
        Range("C:F,H:I,N:P").EntireColumn.Hidden = True
        
            .AutoFilter Field:=7, Criteria1:="V"
            .AutoFilter Field:=18, Criteria1:="Actief"
            .AutoFilter
        End If

    End With
Next sh
    
End Sub
 
Volgens mij klopt het laatste bestand niet met de code en verder heb ik niet alles doorgelezen.

Je gebruikt
Code: 
Set OvzM = Sheets("Overzicht_Email")
Hier doe je vervolgens niets mee.

Code: 
If Range("K1").Value = 2 Then
        Range("C:F,H:I,N:P").EntireColumn.Hidden = True
Gaat uit van het actieve werkblad.

Mogelijk moet het zo
Code: 
If [COLOR="#FF0000"]OvzM.[/COLOR]Range("K1").Value = 2 Then
        [COLOR="#FF0000"]sh.[/COLOR]Range("C:F,H:I,N:P").EntireColumn.Hidden = True
 
Bedankt VenA,

Dat was wat miste. En ik heb de oude regel voor het filteren erbij geplakt.

Code: 
Sub kladje1()

'testgevallen klaarzetten


Dim sh As Worksheet, OvzM As Worksheet
Set OvzM = Sheets("Overzicht_Email")
For Each sh In Sheets(Array("Tabblad1", "Tabblad2", "etc"))

    
    ' PlatformA
        If OvzM.Range("K1").Value = 1 Then
        ' Verberg kolommen
        sh.Range("C:E,G:I,N:P").EntireColumn.Hidden = True
            'Filter op Kolom F(6) en R(18)
            sh.Range("A1:R" & Range("A1").End(xlDown).Row - 0).AutoFilter Field:=6, Criteria1:="V"
            sh.Range("A1:R" & Range("A1").End(xlDown).Row - 0).AutoFilter Field:=18, Criteria1:="Actief"

    Else
    ' PlatformB
        If OvzM.Range("K1").Value = 2 Then
        sh.Range("C:F,H:I,N:P").EntireColumn.Hidden = True
        
            sh.Range("A1:R" & Range("A1").End(xlDown).Row - 0).AutoFilter Field:=7, Criteria1:="V"
            sh.Range("A1:R" & Range("A1").End(xlDown).Row - 0).AutoFilter Field:=18, Criteria1:="Actief"

        End If
    End If
Next sh
    
End Sub
 
Wat mij opvalt als ik van de onderstaande code gebruik maak (middels een knop) dat de gegevens netjes gekopieerd worden,
maar dat op de tabbladen waar vandaag gekopieerd wordt de filtering van de betreffende kolommen afgaat.

Niet dramatisch, maar ik haal dat ontfilteren niet uit onderstaande code.
Herkennen je zoiets?

Verder had ik ineens een probleem met het mailen van een selectie uit het Overzicht_email (body mailtje was zwart met hier en daar een lijntje).
Om dat op te lossen heb ik het blad Overzicht_email opnieuw aangemaakt onder aan andere naam en het originele blad verwijderd. (Waarschijnlijk het toevoegen van selectie-buttons is de oorzak hiervan, maar zeker weten doen ik dat niet.)

Doordat ik in het nieuwe tabblad, om het optische redenen, een extra regel boven regel 1 had toegevoegd deed onderstaande code niet meer wat ik wilde. Immers, de bovenste regel was leeg dus de eerste lege regel was niet de locatie (B27) om te plakken maar B1. Alsnog plakte hij het soort van goed, maar net niet. Nu heb ik in B1 een 'witte' tekst gezet en doet de code het weer zoals verwacht.

Is de code aan te passen dat wanneer er een lege regel tussengevoegd wordt hij alsnog even verder kijkt of er niet nog ergens tekst staat om het vervolgens daaronder te plakken?

Code: 
Sub hsv()
Dim sh As Worksheet, OvzM As Worksheet
Set OvzM = Sheets("Overzicht-mail")
For Each sh In Sheets(Array("bladE", "bladF", "bladH"))
   With sh.Cells(1).CurrentRegion
    .AutoFilter 11, Array("Known Issue", "NOK", "Opmerking"), 7
    .Offset(1, 9).Resize(, 3).Copy OvzM.Cells(Rows.Count, 2).End(xlUp).Offset(Abs(OvzM.Cells(1, 2) <> ""))
    .AutoFilter
   End With
Next sh
End Sub
 
Gokje zonder bestand, ik word helaas van je schrijven niet veel wijs.
Code: 
.Offset(1, 9).Resize(, 3).Copy OvzM.Cells(Rows.Count, 2).End(xlUp).Offset([COLOR=#ff0000][SIZE=3]1[/SIZE][/COLOR]))
 
Hallo,

Hierbij het bestand.

De Selectie (1) bullet verwijst naar K1. Op basis daarvan wordt de code van knop 2. uitgevoerd.

Issue 1
Knop 3. is waar ik nu tegenaan loopt: op het moment dat je die klikt kopieert hij netjes de betreffende gevallen, maar ontfiltert hij de tabbladen BladA t/m BladE.
(In het voorbeeld niet gehele zuiver omdat ik random wat regels een NOK etc heb gegeven, geen rekening houdend met platform.
In de echte wereld zal je niet bij platform 'Kolom6' regels van 'Kolom7' op NOK zetten.)

Issue 2
Verder heb ik nog 1 'wit-regel' op B25 gevuld met witte tekst omdat anders knop 4. niet de juiste selectie maakt: die stopt dan bij B24.

Wens
Wat nog een wens is, ik heb wel geprobeerd, maar kom daar niet uit:
- bij knop 3. zou ik ook kolom 1 van de tabbladen At/mE mee kopieren: het testgeval identifier.
Code: 
     .Offset(1, 9).Resize(, 4).Copy OvzM.Cells(Rows.Count, 2).End(xlUp).Offset(1)
zou ook Offset 1,0 mee moeten nemen. (in het voorbeeld: BladA Cel A3.)

In het mail overzicht is regel 26 'vast', dus die moet ik dan de huidige kolommen eentje naar rechts verplaatsen.

Alvast bedankt voor de hulp. Ik hoop dat het met het voorbeeld duidelijker wordt.
 

Bijlagen

  • VBA helpmij v01.xlsm
    88 KB · Weergaven: 30
Regel 25 kan je gewoon leegmaken.

Code: 
[COLOR=#ff0000] Union([/COLOR].Offset(1, 9).Resize(, 4)[COLOR=#ff0000], .Offset(1).Resize(, 1)[/COLOR]).Copy OvzM.Cells(Rows.Count, 2).End(xlUp).Offset(1)
 
Status
Niet open voor verdere reacties.
Steun Ons

Nieuwste berichten

Terug
Bovenaan Onderaan