1 formule hele kolom

[evinx]

beste,

ik heb deze formule

=(I3*(ALS(H3=R4;S4;(ALS(H3=R5;S5;(ALS(H3=R6;S6;(ALS(H3=R7;S7)))))))))

nu is deze dus geschreven in CEL J3 en gebaseerd op Waarde Cel I3 * Waarde H3

De Cellen R en S zijn vaste waardes zie screenshot


nu wil ik dus eigenlijk de formule gebruiken op hele kolom J

iemand een idee ?

 

[evinx]

ik wil dus dit alleen dan over gehele kolom

=(I3*(ALS(H3=R4;S4;(ALS(H3=R5;S5;(ALS(H3=R6;S6;(ALS(H3=R7;S7)))))))))
=(I4*(ALS(H4=R4;S4;(ALS(H4=R5;S5;(ALS(H4=R6;S6;(ALS(H4=R7;S7)))))))))
=(I5*(ALS(H5=R4;S4;(ALS(H5=R5;S5;(ALS(H5=R6;S6;(ALS(H5=R7;S7)))))))))

 

[MarcelBeug]

Zo uit mijn hoofd: =I3*VERT.ZOEKEN(H3;$R$4:$S$7;2;0) en kopiëren naar beneden.

 

[evinx]

Zo uit mijn hoofd: =I3*VERT.ZOEKEN(H3;$R$4:$S$7;2;0) en kopiëren naar beneden.

dit werkt inderdaad top

1 volgend klein vraagje ik krijg nu in alle lege cellen "#N/B"

 

[MarcelBeug]

Dan komt omdat de waarde in H leeg is en niet gevonden wordt in R4:S7.
Het beste kun je dit afvangen met een test of de waarde in H is ingevuld:
=ALS(H3="";"";I3*VERT.ZOEKEN(H3;$R$4:$S$7;2;0))

 

[evinx]

dit werkt prima

nu werkt alleen mijn CEL opmaak niet meer
CEL J 5-50 kleur (blauw 1)
CEL J 50-500 Kleur (blauw 2)
CEL J >500 Kleur (Blauw 3)


sorry voor die simpele vragen(voor jullie) ben best handig maar die formulies snap ik nog altijd niet zo veel van

 

[MarcelBeug]

Zo met alleen plaatjes en zonder voorbeeldbestand, zijn het ook voor ons moeilijke vragen.

Je kunt ook formules naar beneden doorvoeren zonder de opmaak mee te kopiëren.
Anders moet je even de kleuren opnieuw aanbrengen.

Toelichting op =ALS(H3="";"";I3*VERT.ZOEKEN(H3;$R$4:$S$7;2;0))
Als H3 "" (leeg is), dan is het resultaat "" (leeg dus).
Anders wordt de waarden van H3 opgezocht in de eerste kolom van het gebied R4:S7 en wordt de corresponderende waarde uit de tweede kolom teruggeven.
Met de laatste 0 (mag ook ONWAAR zijn i.p.v. 0), wordt aangegeven dat er een exacte overeenkomst moet zijn.
Met de dollartekens wordt aangegeven dat het betreffende element van de celverwijzing (kolomletter, rijnummer) niet wijzigt als je de formule kopieert.
Dus als je de formule van regel 3 naar beneden kopieert, dan blijft de verwijzing naar R4:S7 ongewijzigd, maar de verwijzingen I3/H3 wijzigen wel (I4/H4 etcetera).

 

[evinx]

oh jah natuurlijk stom van mij sorry


Bekijk bijlage installaties lijst.xlsx


maar de kleuren werken wel maar de cellen waar geen waarde instaat zijn blauw

 

[MarcelBeug]

maar de kleuren werken wel maar de cellen waar geen waarde instaat zijn blauw

Bijna goed: de cel waar helemaal niets in staat (J2) wordt niet blauw, terwijl deze zich wel in het bereik van de voorwaardelijke opmaak bevindt.
De cellen waarin de formule "" oplevert, kleuren wél blauw.

De oorzaak: Excel beschouwt alle tekstwaarden als groter dan elk getal (heb ik ook weer wat geleerd). Dus de vergelijking >500 levert WAAR op voor cellen met "" (deze kleuren dus blauw) en ONWAAR voor lege cellen (J2) (deze kleurt dus niet blauw).

Remedie: ik heb de voorwaardelijke opmaak voor >500 aangepast in voorwaardelijke opmaak met formule: =EN(ISGETAL(J2);J2>500)

 

[evinx]

super bedankt voor je hulp top !!!