1ste datum ophalen voor bepaalde datum

[PedroJV]

Beste Forum, ik ben hier nieuw en heb een datum vraag.

In het voorbeeld bestand zie je twee tabellen.

De formule van C2-C8 [Patientdata] zou van patient 6534 met afsluitdatum 28-01-2017, van tabblad [Tabel1_2017_rapport] antwoordatum bij patient 6534 de eerste datum op moeten halen die ligt voor 28-01-2017 ligt.
In dit geval dus 26-01-2017 (C7).

Ik heb meerdere (matrix)formules geprobeerd, maar deze halen altijd de eerste of laatste datum op van de betreffende patient.
Het moet dus de eerste datum ervoor zijn.

Wie kan me helpen.

Dank je wel.

Groet

Pedro

 

[SjonR]

Probeer deze eens:

=MAX((Tabel1_2017!$A$2:$A$34=A7)*(Tabel1_2017!$B$2:$B$34<B7)*(Tabel1_2017!$B$2:$B$34))

Invoeren met CTRL+SHIFT+ENTER

 

[PedroJV]

Hallo SjonR,

werkt perfect.

Dank je wel.

Groet

Pedro

 

[SjonR]

Dat is mooi! :thumb:

 

[PedroJV]

Beste SjonR,

als ik de eerste datum na de vraagdatum (ipv ervoor zoals mijn org vraag was) wil uitvragen, dan verander ik de formule in

=MAX((Tabel1_2017!$A$2:$A$34=A7)*(Tabel1_2017!$B$2:$B$34>B7)*(Tabel1_2017!$B$2:$B$34))

- dus alleen ">" aangepast, alleen dat krijg ik niet de goede waarde terug.

voor patient 6534 zou datum 01-02-2017 terug moeten krijgen, alleen ik krijg de allerlaatste datum van patient 6534 terug 24-03-2017 ???

 

[AlexCEL]

Terwijl je op het antwoord van SjonR wacht (je bent erg specifiek m.b.t. diegene van wie je antwoord verwacht) zou je deze matrixfunctie eens kunnen proberen:

=ALS.FOUT(INDEX(Tabel1_2017!$B:$B;MIN(ALS(Tabel1_2017!$A$2:$A$34=$A7;1;9^99)*ALS(Tabel1_2017!$B$2:$B$34>$B7;1;9^99)*RIJ($2:$34)));"")

Afsluiten met Control+Shift+Enter dus.

 

[PedroJV]

Hallo AlexCEL,

deze werk perfect.
Ik zal voortaan niet meer op specifiek iemand wachten

 

[snb]

Of matrixformule:

=MIN(IF((Tabel1_2017!A2:A34=A7)*(Tabel1_2017!B2:B34>B7);Tabel1_2017!B2:B34))

 

[snb]

Pedro

svp niet citeren/quoten !

Zie https://www.helpmij.nl/forum/announcement.php?f=5

 

[PedroJV]

Beste Groep, wat betekent de - 9^99 - in de eerder gegeven onderstaande matrixformule?

=ALS.FOUT(INDEX(Tabel1_2017!$B:$B;MIN(ALS(Tabel1_2017!$A$2:$A$34=$A7;1;9^99)*ALS(Tabel1_2017!$B$2:$B$34>$B7;1;9^99)*RIJ($2:$34)));"")

 

[AlexCEL]

9^99 = een heel groot getal...

Als de conditie niet waar is komt dit in de matrix te staan, de INDEX geeft een fout want die regel bestaat niet, en de ALS.FOUT maakt er dan een lege cel van.

 

[garfield007]

=ALS.FOUT(GROOTSTE(ALS(Tabel1_2017!$A$2:$A$34=Patientdata!A7;ALS(Tabel1_2017!$B$2:$B$34<Patientdata!B7;Tabel1_2017!$B$2:$B$34));1);"")

zo leert het men op de excel academy
dan krijg je als resultaat 26/01/2017

 

[PedroJV]

Dank AlexCEL en garfield007 voor jullie hulp.