aanpassen web java applet

[crz_06]

Heb een java applet in een webpagina en wil deze dmv 2 image buttons in mijn html starten en stoppen. Hoe kan je dat het beste aanpakken?

(ben niet echt thuis in java of html). Thanks

/*
* Life
* By William Ngan (http:/www.metaphorical.net)
* Processing BETA code (http://www.processing.org)
*/


int W = 133;
int H = 66;
boolean[][] life = new boolean[W][H];
boolean[][] next = new boolean[W][H];
int cellw, cellh;

boolean running = true;

void setup() {

    size( 798, 393 );
    cellw = 6;
    cellh = 6;

    reset();

    life[49][49] = true;
    life[48][49] = true;

    life[49][50] = true;
    life[50][49] = true;
    life[50][48] = true;


    stroke(255, 255, 255);

    framerate(30);
}



void draw() {

    
    background( 255 );

    life();

    if (running) {
        generate();
    }

    if (mousePressed) {
        int mx = mouseX/cellw;
        int my = mouseY/cellh;
        life[mx][my] = true;

    }

}


void life() {

    for (int i=0; i<W; i++) {
        for (int k=0; k<H; k++) {
            
            fill( 255, ((life[i][k]) ? 0 : 255), 255 );
            rect( i*cellw, k*cellh, cellw, cellh );

        }
    }

}


void reset() {

    for (int i=0; i<W; i++) {
        for (int k=0; k<H; k++) {
            
            life[i][k] = false;
        }
    }
}


void keyPressed() {

    running = false;
    reset();
    life();

}


void mousePressed() {
    running = false;
}

void mouseReleased() {
    running = true;
}




void generate() {

    for (int i=0; i<W; i++) {
        for (int k=0; k<H; k++) {

            int cnt = 0;
            for ( int m=i-1; m<i+2; m++) {

                int mm = (m<0) ? W-1 : ( (m>=W) ? m-W : m );
                
                for ( int n=k-1; n<k+2; n++) {
                    int nn = (n<0) ? H-1 : ( (n>=H) ? n-H : n );

                    if (mm==i && nn==k) continue;
                    else if (life[mm][nn]) cnt ++;
                    
                }
            }


            next[i][k] = (!life[i][k] && cnt==3) || (life[i][k] && cnt>=2 && cnt<=3);
        
        }
    }


    for (int i=0; i<W; i++) {
        System.arraycopy( next[i], 0, life[i], 0, life[i].length );
    }


}