Aantal.als met tijden indien groter/kleiner

[ExcelFons]

Goedemorgen allemaal,

Ik heb denk ik iets kleins waar ik de hele ochtend me al op blind zit te staren.
Ik kom er maar niet achter waarom de aantal tijden kleiner dan of groter dan 12:00 uur niet worden opgeteld.

In de bijlage heb ik een voorbeeldje meegestuurd.
Hierin heb ik 2 tabelletjes gemaakt.

Tabel 1
De "RAW data" plak ik in een "format" tabel.

Vanuit deze "format tabel" heb ik de data in het tabel 1 gekopieerd (Kolom A).
Hierin krijg ik het niet voor elkaar om de tijden voor en na 12:00 uur bij elkaar op te tellen met de formules die ik er achter bij heb getikt.

Tabel 2
Heb ik in kolom "A" de tijden handmatig ingevuld en rekent dezelfde formule wel alles netjes uit.


Alle cellen, in beide tabellen hebben naar mijn idee dezelfde opmaak.
Voor de tijden, Custum>UU:MM.
Voor de uitkomst, "Number>0 decimals.

Wat zie ik over het hoofd?


Alvast bedankt,

Mvg Alfons

 

[AlexCEL]

A3:A8 wordt gezien als tekst. Doe maar eens =ISTEKST(A3) in een cel...

Probeer deze eens i.p.v. de AANTAL.ALS/COUNTIF:

[NL] =SOMPRODUCT(N(--A3:A8<12/24))
[EN] =SUMPRODUCT(N(--A3:A8<12/24))

N.B. De "--" zorgt ervoor dat de tekst wordt omgezet naar getal, de 12/24 staat voor "12:00" en de N-functie zorgt ervoor dat de WAAR/ONWAAR-waardes worden omgezet naar 1 en 0 en opgeteld kunnen worden.

 

[ExcelFons]

Hier was ik nooit op gekomen!

Daar is wel een beetje meer kennis voor nodig dan de basis.
Was al blij dat ik de COUNTIF doorhad.

Super bedankt,

Gr Alfons

 

[ExcelFons]

Sorry, toch nog 1 vraag.

Ik heb nu in de kolom A3:A8 een lege cel.
Deze mag niet meegerekend worden.

Hoe kan ik dit het beste voorkomen?

Bedankt,

 

[AlexCEL]

Formule beetje uitbreiden:

=SUMPRODUCT((A3:A8<>"")*(--A3:A8<12/24))

N.B. door de vermenigvuldiging is de N-functie overbodig geworden...

 

[ExcelFons]

Top ,

Werkt prima,

Dacht hem zelf nog even te bewerken, maar dit is nog iets te hoog gegrepen denk ik.

dacht nu het aantal tijden te tellen binnen een bereik (tussen 10:00 - 13:00 uur).


Zit ik hier wel mee in de buurt met mijn formule in Cel E5?

=SUMPRODUCT(IF(AND(--A3:A8>10/24;--A3:A8>13/24);A3:A8<>""))


Heb het voorbeeldje nogmaals toegevoegd.

Gr Alfons

 

[Timshel]

Je kunt in deze context geen AND gebruiken. Die functie werkt niet op een bereik

=SOMPRODUCT((A3:A8<>"")*(--A3:A8>10/24)*(--A3:A8<=13/24))

 

[ExcelFons]

Super,

Ook helemaal goed.
Begin de logica wel enigszins te zien, weet alleen niet exact waar ik de leestekens moet plaatsen.

Beetje bij beetje komen we er wel.

Bedankt,

 

[AlexCEL]

De logica is dat het een somPRODUCT is van diverse voorwaarden, die elk tussen haakjes () staan. Dit werkt als een EN (of AND) functie.

 

[ExcelFons]

Duidelijk,

en het sterretje "*" vervangt dan de tekst "AND"?

 

[AlexCEL]

Klopt. :thumb:

 

[ExcelFons]

Goedemiddag,

Ik kom steeds verder met de sheet.

De formule van Tim werkt super na wat aanpassingen.
=SOMPRODUCT((A3:A8<>"")*(--A3:A8>10/24)*(--A3:A8<=13/24))


Echter zou ik er nu nog een voorwaarde aan willen hangen.

Deze formule is alleen van toepassing ALS cel B3 ="Ja".
Nu dacht ik de IF functie ertussen te zetten, maar dat werkt niet.

=SOMPRODUCT(IF(B3="Ja";"");(A3:A8<>"")*(--A3:A8>10/24)*(--A3:A8<=13/24))

Willen jullie nog eens met mij meekijken aub.

In de bijlage het voorbeeldje.

Bedankt,

Alfons

 

[AlexCEL]

Lijkt je dit logisch?

=SUMPRODUCT((B3:B8="Ja")*(A3:A8<>"")*(--A3:A8>10/24)*(--A3:A8<12/24))

 

[ExcelFons]

Euh,

Ja best wel.
Ha ha!

Met andere woorden, alles wat al tussen de haakjes staat zijn al voorwaarden.
Dus eigenlijk gewoon een voorwaarde toevoegen.

Best logisch ja.

Bedankt,