aantal.als over de laatste rijen tellen

[voerman]

Hoi Allemaal,

voor een project hou ik bij welke personen een gebeurtenis melden. Dan staat er in de kolom een "X". Iedere dag vul ik dit in. sommige melden niks en anderen weer een gebeurtenis. Zo wordt de lijst steeds langer.
Nu kan ik wel alle X-en tellen in het totaal maar nu wil ik ook weten wat de telling is over de laatste 30 rijen. Met aantal.als in combinatie met End(xlUp) lukt dat niet. Het gaat om alle scores vanaf de laatst ingevoerde dag en dan 30 dagen terug.
Een voorbeeld zet ik erbij.
Weet iemand de juiste formule om de telling in het sheet te zetten in rij 4 onder de persoon?

 

[AlexCEL]

Zoiets?

=AANTAL.ALS(INDIRECT(ADRES((VERGELIJKEN(MAX($A:$A);$A:$A;0)-30);KOLOM();1;1)&":"&ADRES((VERGELIJKEN(MAX($A:$A);$A:$A;0));KOLOM();1;1));"X")

Kopieren in B4 en doortrekken naar rechts. Heb aangenomen dat de dagen in kolom A staan, omdat je over de laatste 30 rijen sprak.

 

[Jezet]

Hoi Voerman,

Ook er even van uit gegaan dat je de dagen in kolom A hebt staan. Je kunt het bereik B6:B35 verschuiven over een aantal rijen dat ingevuld is minus 30. In je sheet dus 125-30. In formule ziet het zo uit:

=AANTAL.ALS(VERSCHUIVING(B$6:B$35;MAX(0;MAX($A:$A)-30);0);"X")

je kun MAX($A:A) ook vervangen door MAX(ISGETAL($A$6:$A$9999)*RIJ($A$6:$A$9999)), maar dan ingevoerd als een matrix-formule. Dit doe je als in kolom A niet altijd 1 opgeteld wordt.
MAX(0;....) heb ik toegevoegd om te voorkomen dat je een foutmelding krijgt als je op nieuw begint en je nog geen 30 rijen hebt ingervoerd.

Groet,
Jeroen

Groet,
Jeroen

 

[AlexCEL]

Elegant... :thumb:

 

[voerman]

Hoi,
Het werkt perfect Heel erg bedankt!!

Groet,
Jaap