AANTALLEN.ALS met EN en OF functie

[vincet88]

Dag Allen,

Ik probeer een formule op te stellen waarbij meerdere functies in 1 staan.

voorbeeld: Ik wil weten hoeveel fruit er in 2016 gegroeid, waarbij er sprake is van een peer, appel !OF! kiwi.

ik zat te denken aan: AANTALLEN.ALS(A2:A10;"2016";OF(B2:B10;"appel","Peer","kiwi"))

Helaas werkt dit niet..

Hoe werkt dit wel?

 

[VenA]

Ik zou een draaitabel gebruiken.

Op <F1> drukken en de syntax van aantallen.als bekijken helpt je mogelijk ook wel verder. Jouw bestandje plaatsen is ook een optie.

 

[vincet88]

draaitabel

Het moet met een formule gebeuren, omdat het een enorme database is waarbij ik de formule nodig heb.

het probleem zit hem erin dat ik binnen een AANTALLEN.ALS een of & en functie wil gebruiken.

 

[HSV]

Bv.
Het kan zijn dat je de puntkomma moet wijzigen in een backslash (versie afhankelijk).

[COLOR=#333333]=somproduct((A2:A10=2016)*(B2:B10={"appel";"Peer";"kiwi"}))[/COLOR]

 

[VenA]

Bij een enorme database, wat dat in Excel ook mag zijn, is een draaitabel vele malen sneller dan een matrixformule.

 

[HSV]

Als het maar om een enkele formule gaat.........

 

[vincet88]

Database

Het gaat om 2 kolommen, maar dan met 32000 regels. Het is voor onderzoek en moet reproduceerbaar zijn, dus daarom moet er een formule aangekoppeld worden helaas.

Alleen kan ik de ik de formule niet werkend maken..

 

[HSV]

Het bereik in de formule van #4 groter maken naar 32000.

 

[vincet88]

database

dit heb ik nu:

=AANTALLEN.ALS(Blad1!$K$2:$K$31733=EH/Geen vervoer;OF(Blad1!$BW$2:$BW$31733={“Verbal”;”Pain”;”Unresponsive”})

Hij moet dus voldoen aan EH/Geen vervoer EN (Verbal OF Pain OF unresponsive), maar hij pakt m niet

ik maak gebruik van excel 2010

 

[HSV]

Tja, dat heb ik er niet staan.

Hier een voorbeeld met DBAANTAL (geel) en SOMPRODUCT (groen).

 

[AlexCEL]

...maar hij pakt m niet.

Er is dan ook nogal wat mis met de formule:

1. geen OF gebruiken,
2. wel (juiste) aanhalingstekens gebruiken,
3. geen = gebruiken, maar een ;
4. SOM-functie toevoegen;

=SOM(AANTALLEN.ALS(Blad1!$K$2:$K$31733[COLOR="#FF0000"];"[/COLOR]EH/Geen vervoer[COLOR="#FF0000"]"[/COLOR];Blad1!$BW$2:$BW$31733[COLOR="#FF0000"];[/COLOR]{"Verbal";"Pain";"Unresponsive"}))

 

[vincet88]

-

Dankje!

hij doet het nu in ieder geval, alleen het lijkt dat die nu alleen meerekend wanneer er sprake is van verbal..

groetjes

 

[snb]

Zonder voorbeeldbestand... ???

mij lijkt :

=SUMPRODUCT((A1:A23="aa4")*((B1:B23="aa4")+(B1:B23="aa10")))

 

[AlexCEL]

Pas de formule zo aan:

=SOM(AANTALLEN.ALS(Blad1!$K$2:$K$31733;"EH/Geen vervoer";Blad1!$BW$2:$BW$31733;{"Verbal";"Pain";"Unresponsive"}))

Heb de formule in post #11 ook aangepast.

En, voortbordurend op de voorgestelde SOMPRODUCT formules hierboven, zou dit ook kunnen (geen matrixformule!):

=SOMPRODUCT((Blad1!$K$2:$K$31733="EH/Geen vervoer")*(Blad1!$BW$2:$BW$31733="Verbal")+(Blad1!$BW$2:$BW$31733="Pain")+(Blad1!$BW$2:$BW$31733="Unresponsive"))

 

[snb]

@AlexC

Bij sumproduct moeten nog 2 haakjes toegevoegd worden

=SOMPRODUCT((Blad1!$K$2:$K$31733="EH/Geen vervoer")*((Blad1!$BW$2:$BW$31733="Verbal")+(Blad1!$BW$2:$BW$31733="Pain")+(Blad1!$BW$2:$BW$31733="Unresponsive")))

 

[AlexCEL]

Misschien wel zo netjes, maar versie zonder haakjes geeft wel de juiste resultaten bij mij (Edit: bij nader inzien is deze bewering niet waar.. ))

En wat ik net constateerde is dat de eerste formule in #13 ook werkt zonder afsluiten met CSE. Weer wat geleerd...

Conclusie, 2 mogelijke oplossingen zijn:

=SOM(AANTALLEN.ALS(Blad1!$K$2:$K$31733;"EH/Geen vervoer";Blad1!$BW$2:$BW$31733;{"Verbal";"Pain";"Unresponsive"}))
=SOMPRODUCT((Blad1!$K$2:$K$31733="EH/geen vervoer")*((Blad1!$BW$2:$BW$31733="pain")+(Blad1!$BW$2:$BW$31733="unresponsive")+(Blad1!$BW$2:$BW$31733="verbal")))

 

[HSV]

Je kan de criteria toch tussen de accolades zetten zonder de dubbele bereiken in de somproduct zoals in het bestand wat ik plaatste.

 

[snb]

@Alexc

y=x*a+b+c
is niet hetzelfde als
y=x*(a+b+c)

 

[AlexCEL]

Klopt als een bus snb. Dacht even dat het in mijn sheet geen verschil maakte, maar Mea Culpa: met haakjes is correct.

De versie met backslash wordt (bij mij):

=SOMPRODUCT((Blad1!$K$2:$K$31733="EH/geen vervoer")*(Blad1!$BW$2:$BW$31733={"Pain"\"Unresponsive"\"Verbal"}))

Heb alle varianten maar even in voorbeeldje gezet. Al met al een leerzaam draadje voor mij :thumb: