aantallen met SOMPRODUCT op weeknummer via datum

[SjonR]

Goedemorgen Helpers,

Ik wil via een somproduct-formule de aantallen per gebruiker in een bepaald weeknummer verkrijgen. Echter zonder hulpkolom lukt het me niet. Jullie een idee?

Gr.

Sjon

 

[emields]

probeer het zo eens

=AANTALLEN.ALS(Tabel1[gebruiker];"a";Tabel1[weeknummer];2)

 

[SjonR]

@ Emields

dank voor je antwoord. Het is echter de bedoeling om het zonder hulpkolom ( kolom weeknummer ) voor elkaar te krijgen.

 

[snb]

Blijkbaar werkt weeknum niet in een matrix (of soortgelijke i.c sumproduct) formule

Het lukt mij wel met year, month en weekday, maar niet met weeknum.

 

[SjonR]

Dat idee had ik dus ook. Met maand, jaar etc werkt het inderdaad wel. Ik sluit mijn vraag.

Thanks @snb & @emields

 

[cow18]

workaround zonder hulpkolom, maar met een paar hulpcellen

 

[SjonR]

Bedankt Cow! :thumb:

 

[HSV]

De tabel converteren naar een normaal bereik.
Matrix:

=SOM((A2:A7="a")*(WEEKNUMMER(RIJ(INDIRECT(B2&":"&B7));21)=2))

of:

=SOMPRODUCT((A2:A7="a")*(WEEKNUMMER(RIJ(INDIRECT(B2&":"&B7));21)=2))

Of in de tabel tot 10000 rijen.

=SOMPRODUCT((Tabel1[gebruiker]="a")*(WEEKNUMMER(RIJ(INDIRECT($B$2&":"&INDEX(B1:B10000;AANTALARG(B1:B10000))));21)=2))

 

[snb]

@HSV

werkt hier niet in Excel 2010:

=SUMPRODUCT(N(A2:A7&WEEKNUM(B2:B7;2)="a1"))

 

[HSV]

Vreemd, werkt in Excel 2007 als een zonnetje.

Die laatste van jou werkt hier niet.

 

[snb]

MS zal wel weer iets 'verbeterd' hebben...

 

[HSV]

@snb,

Hoe werkt deze in jouw versie?

=SOMPRODUCT((A2:A9="a")*(WEEKNUMMER(--INDEX(B2:B9;0;0);2)=3))

Werkt hier ook nog in de tabel.

=SOMPRODUCT((Tabel1[gebruiker]="a")*(WEEKNUMMER(--INDEX(Tabel1[[datum ]];0;0);2)=3))

 

[snb]

Dit werkt hier allemaal:

=SUMPRODUCT((A2:A9="a")*(WEEKNUM(--INDEX(B2:B9;0;0);21)=3))
=SUMPRODUCT(N(A2:A9&WEEKNUM(--INDEX(B2:B9;0;0);21)="a3"))
=SUMPRODUCT((Tabel1[gebruiker]="a")*(WEEKNUM(--INDEX(Tabel1[[datum ]];0;0);21)=3))
=SUMPRODUCT(N(Tabel1[gebruiker]&WEEKNUM(--INDEX(Tabel1[[datum ]];0;0);21)="a3"))

Heb jij er een verklaring voor waarom index nodig is?

 

[HSV]

Niet echt, maar ik zie het jou wel eens in een evaluatie gebruiken in VBA.

Toen ik me dat bedacht had zag ik in het evaluatievenster dat ik wel een matrix verkreeg en niet overal meer #waarde.

Daarna was het appeltje eitje om er twee keer het minteken voor te plaatsen.

 

[E v R]

Zonder Index, werkt het ook zolang je maar de dubbele -- gebruikt:

=SUMPRODUCT((Tabel1[gebruiker]="a")*(WEEKNUM(--Tabel1[[datum ]];2)=3))

 

[snb]

@HSV

Compliment voor de scherpzinnigheid :thumb:

@EvR

T'is wat.
werkt nu ook:

=SUMPRODUCT(N(Tabel1[gebruiker]&WEEKNUM(--Tabel1[datum];21)="a3"))

Maar ja, sjiek is anders.

 

[E v R]

Yep,
Middels die -- lijkt een benodigde evaluatie-stap uitgevoerd te worden, maar dat is mijn perceptie

 

[HSV]

Mooi dat we er even op door zijn gegaan. :thumb:
De laatste twee werken ook in Excel 2007.

Nog wel een opmerking voor eventuele 2007 gebruikers,.... de 21 aanpassen in een 2 (21 is voor nieuwere versies).

 

[E v R]

Nog een kleine toevoeging:
ipv --
kan ook:
0&
of
1*

 

[snb]

Dan kunnen we nog wel even doorgaan:
Bijv ABS en N

=SUMPRODUCT(N(Tabel1[gebruiker]&WEEKNUM(ABS(Tabel1[datum]);21)="a3"))
=SUMPRODUCT(N(Tabel1[gebruiker]&WEEKNUM(N(Tabel1[datum]);21)="a3"))