Access uitleg

[MartijnWils]

Is het mogelijk om een beetje uitleg te geven wat er moet gebeuren als je over bv een keuzelijst gaat.

zoiets gelijk Tooltip in VB.NET maar dan in Access ?

mvg Martijn Wils

 

[OctaFish]

Je kunt bijvoorbeeld een Balloon actie oproepen bij de gebeurtenis <Bij muis verplaatsen> van de keuzelijst.

 

[MartijnWils]

En hoe doe ik dat juist ?

 

[OctaFish]

't Is heel wat code, maar hier komt-ie!

Om te beginnen, heb je uiteraard een formulier nodig. Bij het opstarten van dat formulier moet de Balloon worden aangezet. Dat gebeurt met onderstaande code. Deze zet de balloon ook weer uit, als je het formulier sluit, vandaar twee routines.

Private Sub Form_Load()
    If Assistant.On = True Then
        bolAssistantOn = True
    Else
        bolAssistantOn = False
        Assistant.On = True
    End If
End Sub

Private Sub Form_Close()
    If bolAssistantOn = False Then
        Assistant.On = False
    End If
End Sub

In een Nieuwe module (al hoeft dat iet, je kunt het ook op hetzelfde formulier houden) zet je de onderstaande twee procedures:

Sub OpenBalloon()
    Dim offBalloon As Office.Balloon
    Set offBalloon = Application.Assistant.NewBalloon
    With offBalloon
       ' Show the Office Assistant.
       .Parent.Visible = True

       ' Set the heading and text of the balloon.
       .Heading = "Welcome to the Microsoft Office 2000 Assistant!"
       .Text = "Click one or more of the check boxes below, and " _
              & "also click either a label or a button."

       ' Make the balloon modeless.
       .Mode = msoModeModeless

       ' Display the Back, Next, and Close Buttons.
       ' To determine the constants for other buttons you can place
       ' on a balloon, view the Microsoft Office 9.0 Object library
       ' in the Object Browser.
       .Button = msoButtonSetBackNextClose

       ' Display two labels.
       .Labels(1).Text = "First Label"
       .Labels(2).Text = "Second Label"
       
        ' Display two check boxes.
       .Checkboxes(1).Text = "First Checkbox"
       .Checkboxes(2).Text = "Second Checkbox"

       ' Define which Callback procedure to run.
       .Callback = "WhichButton"
       .Show
    End With
End Sub
      
Sub WhichButton(bln As Balloon, iBtn As Long, iPriv As Long)
    Dim cBox As Office.BalloonCheckbox
    Dim intCBCount As Integer
    Dim strCBMessage As String
    bln.Close
    intCBCount = 0
    For Each cBox In bln.Checkboxes
        If cBox.Checked Then
            If cBox.Item = "First Checkbox" Then intCBCount = intCBCount + 1
            If cBox.Item = "Second Checkbox" Then intCBCount = intCBCount + 2
       End If
    Next
    Select Case intCBCount
        Case 1
            strCBMessage = "You selected the first checkbox."
        Case 2
            strCBMessage = "You selected the second checkbox."
        Case 3
            strCBMessage = "You selected both checkboxes."
        Case Else
            strCBMessage = "You didn't select a checkbox."
    End Select
    
    MsgBox strCBMessage, vbOKOnly, "Callback Test Result"
    Select Case iBtn
       Case 1
          MsgBox "You clicked the first label", vbOKOnly, "Callback Test Result"
       Case 2
          MsgBox "You clicked the second label", vbOKOnly, "Callback Test Result"
       Case msoBalloonButtonBack
          MsgBox "You clicked the Back button", vbOKOnly, "Callback Test Result"
       Case msoBalloonButtonClose
          MsgBox "You clicked the Cose button", vbOKOnly, "Callback Test Result"
       Case msoBalloonButtonNext
          MsgBox "You clicked the Next button", vbOKOnly, "Callback Test Result"
    End Select
End Sub

Nu kun je op het formulier de balloon aanroepen op een door jouw te bepalen plek.
Je kunt bijvoorbeeld een knop maken. Bij de gebeurtenis <Bij klikken> zet je dan de opdracht:

OpenBalloon

Dat is alles!

Dit voorbeeld heb ik van de Microsof website gehaald. Je kunt daar ook een voorbeeld downloaden met bovenstaand voorbeeld.

 

[MartijnWils]

Bedankt octafish !!!! :thumb: