Alles Selectievakjes tegelijk (de)selecteren

[GerardHdorp]

Hallo Excel helpers,

Ik kan het niet op het forum vinden.
Ik heb 200+ selectievakjes in de cellen van kolom A, beginnende bij A2. Dus iedere cel heeft een eigen selectievakje. Soms wil ik alle selectievakjes tegelijk selecteren of deselecteren. Dit zou ik willen doen met een selectievakje in cel A1. Dus als ik het selectievakje in A1 selecteer (vinkje aan), dan gaan alle onderliggende selectievakjes op "WAAR" (vinkjes aan), als ik het selectievakje in A1 deselecteer (vinkje uit), dan gaan alle onderliggende selectievakjes op "ONWAAR" (vinkjes uit).
De selectievakjes komen uit de werkbalk "Formulieren". Niet uit de werkbalk "Werkset Besturingselementen".
Ik kom er niet uit... Ik heb het gevoel dat ik met de selectievakjes uit de werkbalk "Werkset Besturingselementen" moet gaan werken...
Ohja, op mijn werk zitten we nog met Excel 2003.

 

[HSV]

Koppel onderstaande macro eens aan het selectievakje in A1.

Sub hsv()
Dim i As Long
For i = 2 To ActiveSheet.Shapes.Count
  ActiveSheet.Shapes(i).ControlFormat.Value = IIf(ActiveSheet.Shapes(1).ControlFormat.Value = 1, 1, -4146)
 Next i
End Sub

 

[Ginger]

Hierbij nog een paar procedures voor acties met checkboxen...

Sub VerwijderCheckboxes()
Dim chkbx As CheckBox

    For Each chkbx In ActiveSheet.CheckBoxes
        chkbx.Delete
    Next
    
End Sub

Sub CheckboxOmkeren()
' keer de waarde van een checkbox om; aan wordt uit en uit wordt aan
Dim chkbx As CheckBox

    For Each chkbx In ActiveSheet.CheckBoxes
        chkbx.Value = (chkbx.Value = xlOff)
    Next
    
End Sub

Sub CheckboxAan()
' zet alle checkboxen op aan
Dim chkbx As CheckBox

    For Each chkbx In ActiveSheet.CheckBoxes
        chkbx.Value = xlOn
    Next
    
End Sub

Sub CheckboxUit()
' zet alle checkboxen op uit
Dim chkbx As CheckBox

    For Each chkbx In ActiveSheet.CheckBoxes
        chkbx.Value = xlOff
    Next
    
End Sub

 

[GerardHdorp]

Hé HSV & Ginger,

Het werkt! De codes van Ginger heb ik even in een documentje gestopt. Wellicht komen ze nog goed van pas! Bedankt!