Als een waarde voorkomt, dan specifieke tekst

[DonCarillon]

Ik heb een vraag waar ik helaas niet volledig uit komt.

In een table met verschillende waarden [1, 2 en 3] wil ik controleren of specifieke waarden voorkomen, zo ja, dan een specifieke tekst tonen.

Specifiek:
als waarde 1 voorkomt, dan 1 tonen
als waarde 1 voorkomt, dan 1 tonen. ANDERS Als waarde 2 voorkomt, dan 2 tonen.
als waarde 1 voorkomt, dan 1 tonen. ANDERS Als waarde 2 voorkomt, dan 2 tonen. ANDERS Als waarde 3 voorkomt, dan 3 tonen.

Ik heb nu de volgende formule bedacht, maar dit bepaald slechts of 1 waarde voorkomt.

=ALS(ISNB(VERGELIJKEN(1;A2:A4;0));"waarde komt niet voor";"hoogste waarde is 1")

Weet iemand hoe dit op te lossen?

In bijgesloten bestand heb ik bovenstaande situatie uitgewerkt.
Bekijk bijlage waarden + bijbehorende tekst.xlsx

 

[OctaFish]

Bedoel je zoiets?

=ALS(ISNB(VERGELIJKEN(3;A2:A4;0));ALS(ISNB(VERGELIJKEN(2;A2:A4;0));ALS(ISNB(VERGELIJKEN(1;A2:A4;0));"waarde komt niet voor";"hoogste waarde is 1");"hoogste waarde is 2");"hoogste waarde is 3")

 

[DonCarillon]

Ja, dit is precies wat ik zoek!

Ontzettend bedankt voor de snelle reactie. Een fijne (werk)dag :thumb:

 

[Conseclusie]

Waarom niet gewoon:

="Hoogste waarde is "&MAX(A2:A4)

?

 

[DonCarillon]

@conseclusie

Is dat ook mogelijk met waarden, anders dan 1/2/3 (zeg appel, peer, bloemkool)?

 

[Timshel]

Nog eentje dan.
Matrixformule (afsluiten met CTRL SHIFT ENTER):

=ALS.FOUT("Hoogste waarde is "&GROOTSTE(ALS($A$2:$A$4={1\2\3};{1\2\3});1);"waarde komt niet voor")

 

[Timshel]

@conseclusie

Is dat ook mogelijk met waarden, anders dan 1/2/3 (zeg appel, peer, bloemkool)?

Appels en peren: wat is de hoogste?

 

[DonCarillon]

Appels en peren: wat is de hoogste?

Peer is de hoogste waarde

 

[snb]

Altijd al gedacht , vandaar natuurlijk: toffe peer !

 

[DonCarillon]

Eigenlijk had mijn antwoord moeten zijn "Appels, nog Peren en daarom is Bloemkool de hoogste waarde".

Maar voor de formule mag de volgorde (van hoog naar laag) Peer, Appel, Bloemkool

 

[OctaFish]

Eigenlijk had mijn antwoord moeten zijn "Appels, nog Peren en daarom is Bloemkool de hoogste waarde".

Dat moet dan toch zeker zijn: "Appels noch Peren en daarom is Bloemkool de hoogste waarde"

 

[snb]

Je bedoelt waarschijnlijk 'noch' in plaats van 'nog'.

Gebruik de matrixformule:

=MAX(MATCH(A1:A30;{"bloemkool";"appel";"peer"};0))

En als je een tekstwaarde wil tonen:

=INDEX({"bloemkool";"appel";"peer"};MAX(MATCH(A1:A30;{"bloemkool";"appel";"peer"};0));1)

 

[Timshel]

Ik kom uit op deze:

=ALS.FOUT("De hoogste waarde is "&ZOEKEN(1E+23;VERGELIJKEN({"Peer";"Appel";"Bloemkool"};A2:A8;0);{"Peer";"Appel";"Bloemkool"});"Niet gevonden")

 

[DonCarillon]

Gebruik de matrixformule:

=MAX(MATCH(A1:A30;{"bloemkool";"appel";"peer"};0))

En als je een tekstwaarde wil tonen:

=INDEX({"bloemkool";"appel";"peer"};MAX(MATCH(A1:A30;{"bloemkool";"appel";"peer"};0));1)

Waarschijnlijk vergeet ik een stap, maar bovenstaande krijg ik niet werkend..
Onderstaande code werkt wel

=INDEX({"bloemkool";"appel";"peer"};MAX(ALS.FOUT(VERGELIJKEN(A2:A9;{"bloemkool";"appel";"peer"};0);-1));1)

Ik kom uit op deze:

=ALS.FOUT("De hoogste waarde is "&ZOEKEN(1E+23;VERGELIJKEN({"Peer";"Appel";"Bloemkool"};A2:A8;0);{"Peer";"Appel";"Bloemkool"});"Niet gevonden")

Deze optie werkt perfect.