=als functie & =min functie combineren

[ric00]

Goede middag,

Wie kan mij helpen? Ik ben bezig met een formulier voor tijdregistratie en ik kom niet verder.

In kolom E wordt telkens tijd1 geregistreerd, in kolom F wordt tijd2 geregistreerd. In kolom G wordt vervolgens de snelste tijd bepaald door de formule, in rij 9 is dat bijvoorbeeld: =MIN(E9;F9). Tot zover lukt het nog.

Maar men kan ook gediskwalificeerd worden, dan wordt er in kolom E en/of F DSQ geregistreerd. Nu wil ik, wanneer iemand twee diskwalificaties heeft, er in kolom G "DSQ" komt te staan, wanneer men enkel één diskwalificatie heeft, dat gewoon de tijd geregistreerd wordt. Ik heb wel verstand van excel en ik heb gezocht op internet, maar ik loop vast. Ik heb een half werkende functie =ALS(E9="DSQ";"DSQ";MIN(E9:F9)), wanneer je in E9 en F9 een tijd zet, zet excel in G9 de snelste tijd neer, wanneer je in E9 DSQ zet, wordt er in G9 ook DSQ gezet. Nu heb ik de ALS voorwaarde DSQ van F9 er niet ingezet, wanneer ik dat wel doe krijg ik een foutmelding =ALS(E9="DSQ"; "DSQ";ALS(E9=”DSQ”; ”DSQ”; MIN(E9;F9))).

Hopelijk kan iemand mij helpen?

Greetz,
Rico

 

[boomen]

=ALS(E9="DSQ"; "DSQ";ALS(E9=”DSQ”; ”DSQ”; MIN(E9;F9)))
Misschien dat je alleen een E9 voor F9 moet vervangen.(met voorbeeld duidelijker)

Anders bedoel je denk ik dit.
=ALS(EN(E9="DSQ";F9="DSQ");"DSQ";ALS(E9="DSQ";F9;ALS(F9=”DSQ”;E9;MIN(E9;F9))))

grtz

 

[ric00]

Dat komt al aardig in de buurt, maar het werkt nog niet correct.

Wanneer je bij tijd 1 & tijd 2 DSQ registreert, komt er inderdaad DSQ uit de functie. Wanneer de skiër de eerste keer een DSQ haalt en de tweede keer een tijd, dan komt inderdaad de tijd uit de functie. Maar, wanneer de skiër de eerste keer een tijd skiet en de tweede keer een DSQ, komt er #naam? uit de functie, dezelfde foutcode komt uit de functie wanneer de skiër twee tijden heeft.

In de bijlage heb ik het excel bestand gezet wat ik tot nu toe heb, daar heb ik de bovengenoemde beschreven uitkomsten allemaal even ingezet.

In ieder geval al bedankt voor je tijd

Greetz,
RicoBekijk bijlage Concept tijdregistratie.xlsx

 

[arrie23]

Formule van boomen was in principe correct maar de laatste quotes om DSQ waren niet juist

=ALS(EN(E9="DSQ";F9="DSQ");"DSQ";ALS(E9="DSQ";F9;ALS(F9="DSQ";E9;MIN(E9;F9))))

 

[sylvester-ponte]

=als(min(e9:f9)=0;e9;min(e9:f9))

 

[boomen]

Formule van boomen was in principe correct maar de laatste quotes om DSQ waren niet juist

=ALS(EN(E9="DSQ";F9="DSQ");"DSQ";ALS(E9="DSQ";F9;ALS(F9="DSQ";E9;MIN(E9;F9))))

Momentje facepalm?:FACEPALM:

Rico werkt die nu?

 

[ric00]

Thank you guys, deze werkt!

Nu maken ze het me nog moeilijker hogerop, ze willen het liefste niet dat de skiërs twee keer gaan skiën maar drie keer.
-Men moet minimaal twee tijden skiën, de twee snelste tijden worden bij elkaar opgeteld, de langzaamste tijd vervalt dus.
-Als iemand één keer een DSQ heeft en twee tijden, worden deze twee tijden bij elkaar opgeteld.
-Als iemand twee keer een DSQ heeft, heeft diegene als uiteindelijke uitslag ook een DSQ.

Nu heb ik jullie functie uitgebreid, 1) hij is te lang volgens Excel en 2) Volgens mij klopt hij ook niet.

=ALS(EN(E9="DSQ";F9="DSQ";G9="DSQ");"DSQ";ALS(E9="DSQ";F9="DSQ";G9;ALS(E9="DSQ";F9;G9="DSQ";ALS(E9;F9="DSQ";G9="DSQ")));"DSQ";ALS(E9="DSQ";F9;G9;SOM(F9:G9);ALS(E9;F9="DSQ";G9;SOM(E9;G9);ALS(E9;F9;G9="DSQ";SOM(E9;F9);ALS(E9;F9;G9;SOM(E9;F9;G9))))))

Wat ze willen, kan daar een werkende functie van gemaakt worden?? Of vragen ze nu te veel?Bekijk bijlage 219671Bekijk bijlage 219673

 

[ric00]

Ik ben ietsjes verder, ik heb nu

=ALS(MIN(E9:F9:G9)=0;E9;SOM(MIN(E9:F9:G9)+(MIN(E9:F9:G9))))

Het enige probleem is nu dat hij twee keer dezelfde min neemt.

Voorbeeld: tijd1: 12,00 tijd2: 13,00 tijd3: 11,00 , dan doet hij 11+11 (want hij ziet 11 twee keer als MIN). Hoe kan ik dat voorkomen?

 

[VenA]

gebruik ipv MIN() KLEINSTE()

 

[ric00]

Hebbes!

Ik heb ipv min+min, laat ik nu alle drie de tijden bij elkaar optellen en daar trek ik de langste tijd vanaf.

=ALS(MIN(E9:F9:G9)=0;E9;SOM(E9:F9:G9)-(MAX(E9:F9:G9)))

Thank you everybody!

 

[ric00]

wat is precies het verschil van MIN & KLEINSTE?

 

[VenA]

iets andere aanpak voor H9:

=ALS(AANTAL.ALS(E9:G9;"DSQ")>1;"DSQ";KLEINSTE(E9:G9;1)+KLEINSTE(E9:G9;2))

Bekijk bijlage Concept tijdregistratie 3 manches.xlsx

Edit Ik had jouw vraag niet gezien. MIN() = KLEINSTE(Reeks, 1). Met KLEINSTE() kan je ook het 1 na kleinste etc getal vinden.

 

[ric00]

Held! Dank je VenA, deze werkt nog beter en het is precies wat ik bedoelde!! :thumb: