Als groter dan formule werkt niet

[Peha5772]

Ik wil van een getal tussen 0 en 15 0% aftrekken, als het tussen 15 en 30 ligt 15%, ligt het tussen 30 en 50 20% etc. Ik heb de volgende formule gemaakt maar die werkt niet.

=ALS(B25<15;C29;ALS(B25>=15<30;(C29*(1-15%));ALS(B25>=30<50;(C29*(1-20%));ALS(B25>=50<70;(C29*(1-25%));ALS(B25>=70;(C29*(1-30%)))))))

Waar ga ik de fout in en hoe los ik het op ?

 

[popipipo]

...ALS(B25>=15<30...

Maak hiervan:

....ALS(EN(B25>=15;B25<30)...

Enz.

 

[Peha5772]

Ik ben bezig maar krijg een foutmelding.

=ALS(B25<15;C28;ALS(en(B25>=15<30;(C28*(1-15%))));ALS(en(B25>=30<50;(C28*(1-20%))));ALS(en(B25>=50<70;(C28*(1-25%))));ALS(en(B25>=70;(C28*(1-30%)))))

 

[oeldere]

Werk met vertikaal zoeken in een tabel.

Kijk voor een dergelijke oplossing bij deze vraag.

Heb je hier vragen of opmerkingen over, laat het gewoon even weten.

 

[popipipo]

....ALS(EN(B25>=15;B25<30[COLOR="red"])[/COLOR]....

Even goed naar de sluitingshaakjes kijken en de herhaling van 'B25' in de en formule.

...ALS(EN(B25>=1;B25<30);(C29*(1-15%)))...

 

[Peha5772]

Het lukt me niet. Ik ben al een halve week bezig. Wat doe ik niet goed ?

=ALS(EN(B25<15);C28);ALS(EN(B25>=15;B25<30);(C28*(1-15%)));ALS(EN(B25>=30;B25<50);(C28*(1-20%)));ALS(EN(B25>=50;B25<70);(C28*(1-25%)));ALS(EN(B25>=70);(C28*(1-30%)))

 

[oeldere]

Dan maar eens een voorbeeldbestandje, ontdaan van gevoelige info, plaatsen.

Als het op dit forum niet lukt, gebruik dan www.mijnbestand.nl

 

[robdgr]

Een paar haakjes verplaatst:

=ALS(B25<15;C28;ALS(EN(B25>=15;B25<30);(C28*(1-15%));ALS(EN(B25>=30;B25<50);(C28*(1-20%));ALS(EN(B25>=50;B25<70);(C28*(1-25%));ALS(EN(B25>=70);(C28*(1-30%)))))))

 

[zapatr]

Peha5772,
wat is het verband tussen de cellen B25 en C28 ?
Want het lijkt erop dat in B25 de percentages staan, dat is dubbelop.
Je zou al lang geholpen zijn als je hier een voorbeeldbestandje had geplaatst.

 

[dirktimm]

Als groter dan enz

Hallo Peha,

Ik ben met de suggesties eens om een voorbeeldbestand te plaatsen, maar ik hou het op:

=ALS(B25<15;C28;ALS(B25<30;(C28*(1-15%));ALS(B25<50;(C28*(1-20%));ALS(B25<70;(C28*(1-25%));(C28*(1-30%))))))

Groet

Dirk

 

[Thankyou]

Hallo Peha,

Ik ben met de suggesties eens om een voorbeeldbestand te plaatsen, maar ik hou het op:


Maak een Tabel met de percentage's (kan je ook simpel veranderen zonder alle formules na te moeten lopen) bijvoorbeeld:
0 0%
15 15%
30 20%
50 25%
60 30%
70 35%

De formule kan dan zo:

=A1-VERT.ZOEKEN(A1;$C$1:$D$6;2)*A1

in Engels:  =A1-VLOOKUP(A1,$C$1:$D$6,2)*A1

In A1 je getal, in C1 : D6 je tabel

Succes,

P.S.
Met voorbeeldbestand had je waarschijnlijk al in post #2 of #3 het juiste antwoord gehad.

 

[zapatr]

Ik ben er zelf voorstander van om in het werkblad een lijstje te maken, zodat je altijd een overzicht bij de hand hebt dat, indien nodig, eenvoudig is aan te passen Een oplossing daarop gebaseerd, is hierboven al door verschillende mensen gegeven. Wil je beslist een oplossing zonder een lijst in het werkblad, dan kan dat op diverse manieren. Ook daarvan zijn hierboven al voorbeelden gegeven. Ik wil er daaraan nog 1 toevoegen, namelijk onderstaande.
Als het getal waarop de korting in mindering moet worden gebracht in C28 staat, typ dan in de cel waarin het getal minus de korting moet komen:

=C28*(1-ZOEKEN(C1;{0;15;30;50;70};{0;0,15;0,2;0,25;0,3}))

 

[Peha5772]

Een paar haakjes verplaatst:

=ALS(B25<15;C28;ALS(EN(B25>=15;B25<30);(C28*(1-15%));ALS(EN(B25>=30;B25<50);(C28*(1-20%));ALS(EN(B25>=50;B25<70);(C28*(1-25%));ALS(EN(B25>=70);(C28*(1-30%)))))))

Rob bedankt. Nu werkt het zoals ik gedacht had.

Andere oplossingen zijn ook interessante maar ik begrijp niet goed hoe dat zou moeten werken. Mijn bedoeling was als er in B25 (B6 in voorbeeld) een bepaalde waarde ingevuld zou worden er automatisch een bepaald percentage afgehaald zou worden van een in C28 (C8 in voorbeeld) berekende waarde.

Ik heb het bestand ook geupload naar http://www.mijnbestand.nl/Bestand-GYUWKJ6KZ3IW.xlsx

 

[zapatr]

Peha5772,
De oplossing met zoeken die ik hierboven gaf, is nog steeds bruikbaar. Omdat je nu twee andere cellen gebruikt dan in je eerdere voorbeelden, moet je die wijzigen als volgt. Typ in D8:

=C8*(1-ZOEKEN(B6;{0;15;30;50;70};{0;0,15;0,2;0,25;0,3}))

Wil je toch de formule gebruiken die nu in je bestand in D8 staat, dan kan die worden ingekort tot:

=C8*(1-ALS(B6<15;0%;ALS(B6<30;15%;ALS(B6<50;20%;ALS(B6<70;25%;30%)))))