Automatisch sorteren op minst voorkomend cijfer.

[Zerty]

Ik ben op zoek naar een formule om uit een reeks cijfers (0-9) naar het cijfer dat het minst aantal keren er in voorkomt.
Ik zoek naar een oplossing zonder VBA.

Heb al heel wat geprobeerd maar zonder resultaat.
Ook volgende formule gevonden maar die heeft het verkeerde resultaat.
{=INDEX(A1:A50;1;MIN(ALS(AANTAL.ALS($A$1:$A$50;A1:A50)=MIN(AANTAL.ALS($A$1:$A$50;A1:A50));0)))}

Kan iemand mij verder helpen?

 

[AlexCEL]

Deze?

=MIN(ALS(AANTAL.ALS($A$1:$C$50;RIJ($1:$10)-1)=KLEINSTE(AANTAL.ALS($A$1:$C$50;RIJ($1:$10)-1);[COLOR="#FF0000"]1[/COLOR]);RIJ($1:$10)-1))

Matrixfunctie, afsluiten met CSE dus.

Door de rode 1 te veranderen in 2 of 3, bijvoorbeeld handmatig, door celverwijzing of middels RIJ-functie krijg je de gewenste 3 kleinste cijfers.

 

[snb]

gebruik de matrixformule

=MATCH(MIN(COUNTIF(A1:C50;ROW(1:10)-1));COUNTIF(A1:C50;ROW(1:10)-1);0)-1

 

[Zerty]

Bedankt.

Hartelijk dank AlexCel en nsb voor de oplossingen :thumb:
Ben heel blij dat ik nu verder kan.

Zerty.

 

[snb]

Toch is de volgorde van de letters in mijn alias anders.....

 

[Cobbe]

toch is de volgorde van de letters in mijn alias anders.....

Haha gelukkig voor u.

 

[Zerty]

Sorry snb voor het verkeerd spellen, zal beter opletten in het vervolg

 

[cow18]

matrixformules zijn mijn specialiteit niet, maar er is een probleempje als bv 0 en 1 beiden 12 keer voorkomen, dan wordt 0 2 keer vermeld en 1 niet.

 

[Zerty]

Inderdaad, zojuist eens uitgetest.
Bedankt voor de tip.

 

[snb]

@cow

Je hebt gelijk; 'ties' worden niet verwerkt.

Had je deze al geprobeerd ?

=MATCH(SMALL(COUNTIF($A$1:$C$50;ROW($1:$10)-1)+ROW($1:$10)*10^-7;2);COUNTIF($A$1:$C$50;ROW($1:$10)-1)+ROW($1:$10)*10^-7;0)-1

 

[Zerty]

Dit werkt inderdaad, bedankt voor de oplossing.