Automatisch vullen helpteksten

[jofred]

In bijgevoegd bestandje zit een formulier, waarbij ik hintteksten heb opgenomen, die in een werkblad zijn gedefinieerd.
Ik heb nu een harde verwijzing in de vba-code opgenomen naar de cel, waarin de helptekst staat.
Wat ik graag zou willen is een procedure, die de tabel voor de helptekst doorloopt en adhv de opgenomen helpteksten (sleutel is objectnaam) de helpteksten vul bij het openen van het formulier.
Weet iemand hoe je dit moet doen?

 

[henkhoogerbrug]

je zou onderstaande code kunnen gebruiken:

Private Sub UserForm_Initialize()

Dim shtHelptekst As Worksheet
Set shtHelptekst = Worksheets(1)

txtAanvraag.ControlTipText = ZoekVind("txtAanvraag", shtHelptekst, shtHelptekst.UsedRange)
txtGebrCode.ControlTipText = ZoekVind("txtGebrCode", shtHelptekst, shtHelptekst.UsedRange)

End Sub


Function ZoekVind(Zoekwaarde As String, TabPage As Worksheet, Zoekgebied As Range)

On Error GoTo Einde

ZoekVind = TabPage.Range(Zoekgebied.Find(Zoekwaarde, _
           LookIn:=xlValues, SearchOrder:=xlByColumns).Address).Offset(0, 1)
Exit Function

Einde:
Set ZoekVind = Nothing

End Function

 

[jofred]

Henk,

Hartelijk dank voor je reactie, maar het is nog niet helemaal wat ik bedoel.
Ik zie nu dat ik mijn vraag niet helemaal volledig heb gesteld. Wat ik nog zou willen is dat je niet in de code de besturingselementen hoeft op te nemen, die je van een helptekst wilt voorzien, maar dat dit wordt gedaan adhv het definitieoverzicht uit het excelblad (een soort dynamisch VBA).

 

[henkhoogerbrug]

Je zou dit kunnen gebruiken.
De namen van de textboxes moeten met "txt" beginnen, anders worden ze overgeslagen.

Private Sub UserForm_Initialize()

Dim Ctrl As Control
Dim intAantalTextboxes As Integer
Dim shtHelptekst As Worksheet
Set shtHelptekst = Worksheets(1)

For Each Ctrl In Me.Controls
    If Left(Ctrl.Name, 3) = "txt" Then
        Ctrl.ControlTipText = ZoekVind(Ctrl.Name, shtHelptekst, shtHelptekst.UsedRange)
    End If
Next Ctrl

End Sub

 

[jofred]

Henk,

Je aanvulling is precies wat ik bedoel.
Hartelijk dank.