Beginpad bladeren

[Woffels]

Met onderstaande code laat ik de gebruiker een bestand selecteren en schrijf ik de locatie en bestandsnaam naar cel A1. Op het moment dat ik de code run, begint het bladeren altijd in "mijn documenten", hoe kan ik er voor zorgen dat het bladeren altijd begint in de map waar de sheet zelf staat?

Sub OpenNewBox()
Dim xFilePath As String
Dim xObjFD As FileDialog
Set xObjFD = Application.FileDialog(msoFileDialogFilePicker)
  With xObjFD
        .AllowMultiSelect = False
        .Filters.Add "Excel Files", "*.xls; *.xlsx; *.xlsm; *.xlsb", 1
        .Show
        If .SelectedItems.Count > 0 Then
            xFilePath = .SelectedItems.Item(1)
            Range("A1") = xFilePath
        Else
            Exit Sub
        End If
    End With
End Sub

 

[JEC.]

Kijk eens naar de property .initialfilename van de filepicker

 

[Woffels]

Dank u voor de tip. Dit is hem geworden:

Private Sub cmdSelectSource_Click()
Dim xFilePath As String
Dim xObjFD As FileDialog
Set xObjFD = Application.FileDialog(msoFileDialogFilePicker)
  With xObjFD
        .AllowMultiSelect = False
        .Filters.Add "Data", "*.txt", 1
        .InitialFileName = ThisWorkbook.Path
        .Show
        If .SelectedItems.Count > 0 Then
            xFilePath = .SelectedItems.Item(1)
            Range("D3") = xFilePath
        Else
            Exit Sub
        End If
    End With
End Sub

 

[edmoor]

Of maak er dit van:

Sub OpenNewBox()
    With Application.FileDialog(msoFileDialogFilePicker)
        .InitialFileName = ThisWorkbook.Path
        .Filters.Add "Data", "*.txt", 1
        .Show
        If .SelectedItems.Count > 0 Then Range("D3") = .SelectedItems.Item(1)
    End With
End Sub

 

[Woffels]

Even better, thanks.

 

[snb]

Nog drie schepjes erboven op (of af, zo je wil):

Sub OpenNewBox()
  With Application.FileDialog(3)
    .InitialFileName = ThisWorkbook.Path & "\*.txt"
    If .Show Then Range("D3") = .SelectedItems(1)
  End With
End Sub