Bepaalde waarden onder elkaar zetten

[Nudi]

Beste Excelexperts

Wellicht weten jullie hier een oplossing voor..

Ik zou graag bepaalde waarden(in dit geval alleen de codes waar een "C" voor staat in de tabblad invullijsteenheidsprijzen, netjes onder kolom A in de tabblad VC-NC onder elkaar willen hebben. Nu staan ze ergens in het midden. Ik zou denken om functie Links en kleinste te kunnen gebruiken, maar het lukt mij nog niet.

Alvast bedankt!

mvg,

Nudi

 

[AlexCEL]

Analoog aan de eerdere oplossing:

A16: =ALS.FOUT(INDEX(Invullijsteenheidsprijzen!$A:$A;KLEINSTE(ALS(LINKS(Invullijsteenheidsprijzen!$A$5:$A$32;1)="C";RIJ($5:$32);10^99);RIJ()-15));"")

Let op: dit is weer een matrixfunctie.

Edit: (suggesties)

B16: =ALS.FOUT(VERT.ZOEKEN(A16;Invullijsteenheidsprijzen!$C$5:$D$32;2;0);"")
F16: =ALS(C16>0;C16*D16;"") (SOM-functie is overbodig)
I16: =ALS.FOUT(G16*D16;"") (idem)

 

[Nudi]

Beste Alex,

Bedankt voor uw reactie, maar ik krijg iedere keer een foutvenster. Doe ik het misschien verkeerd?

 

[AlexCEL]

Wat voor foutmelding?

Zie bijlage voor (bij mij) werkende versie.

 

[Nudi]

Oh nee, de eerste oplossing werkt toch! U hebt mij weer super geholpen! u bent een topper!:thumb:

Hartstikke bedankt Alex!

Mvg,

Nudi

 

[Nudi]

Nog een vraag,

Kan ik ook een "OF" functie tussen voegen als ik bijvoorbeeld codes onder elkaar wil hebben waar een "C" of een "G" voor staan?

 

[AlexCEL]

Een OF functie is niet direct in de matrixformule in te bouwen. Ik heb het gedaan via een omweg...

Voldoet dit?

=ALS.FOUT(INDEX(Invullijsteenheidsprijzen!$A:$A;KLEINSTE(ALS(LINKS(SUBSTITUEREN(Invullijsteenheidsprijzen!$A$5:$A$32;"F";"C");1)="C";RIJ($5:$32);10^99);RIJ()-15));"")

 

[HSV]

Een matrix voor meerdere letters.

=ALS.FOUT(INDEX(Invullijsteenheidsprijzen!A$5:A$32;KLEINSTE(ALS(LINKS(Invullijsteenheidsprijzen!A$5:A$32;1)=[COLOR=#0000ff]{"F";"C";"G"}[/COLOR];RIJ($1:$28));RIJ(A1)));"")

Versie afhankelijk in de matrix (blauw aangegeven); waar nu een puntkomma staat moet in sommige gevallen een backslash (wordt automatisch omgezet met doorsturen of delen van bestand).

 

[AlexCEL]

:thumb:

 

[Nudi]

Yes!!

Dank je wel Harry en Alex voor jullie hulp! mijn vraag is opgelost!

mvg,

Nudi