Bereik in VBA formule

[Kaavya]

Ik heb de volgende VBA formule:
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Selection.Interior.ColorIndex = 6 Then
Selection.Interior.ColorIndex = 0
ElseIf Selection.Interior.ColorIndex = xlColorIndexNone Then
Selection.Interior.ColorIndex = 6
End If
End Sub

Ik zou graag een bereik toevoegen waar deze formule werkt, bijvoorbeeld: (A1:C10), (E1:F20) en (H1:H9), zodat alleen in deze cellen bij dubbelklikken de cel geel kleurt.

Is dit mogelijk?
En zo ja, zou iemand hiervan een voorbeeld kunnen geven?

 

[HSV]

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Not Intersect(Target, Range("A1:C10,E1:F20,H1:H9")) Is Nothing Then
 Target.Interior.ColorIndex = IIf(Target.Interior.ColorIndex = 6, xlNone, 6)
  Cancel = True
 End If
End Sub

 

[Kaavya]

Perfect!
Dank je wel

 

[Kaavya]

Het dubbeklikken werkt perfect alleen nu heb ik ook nog een andere formule :
Function TelKleur(R As Range, CelKleur As Range) As Integer
Application.Volatile
Dim C As Object, Kleur As Integer

Kleur = CelKleur.Interior.ColorIndex
TelKleur = 0

For Each C In R
If C.Interior.ColorIndex = Kleur Then TelKleur = TelKleur + 1
Next

End Function

Op een ander tabblad.

Voordat Excel nu een berekening uitvoert moet ik eerst vernieuwen en een keer van tabblad wisselen.

Is dit op te lossen?

 

[HSV]

Waarom staat de function op het ander blad?

Zo hoef je in ieder geval niet meer te vernieuwen.

Private Sub Worksheet_Activate()
 Application.Cells.Dirty
End Sub

Als dat nog niet de bedoeling is, moet je even een bestandje plaatsen van het hoe en waarom.

 

[snb]

@kaavya

gebruik (sinds 2012 !!) code tags.

 

[Kaavya]

Ik heb even geen tijd gehad om naar dit "probleem" te kijken.

In het kort gaat het om een formulier waar resultaten d.m.v. van dubbelklikken geel markeren.
Op een ander tabblad worden deze resultaten vertaald naar een uitslag.
(had hier zelf nooit voor gekozen, maar het is niet voor mij)

Ik ga met de reacties aan de slag, mocht het nog niet lukken plaats ik een voorbeeldbestand.