Bestanden verplaatsen van map naar Map VBA

[Khalid23]

Allen,

Kan iemand mij helpen.

Ik gebruik deze macro voor het verplaatsen van bestanden van een map naar andere map.

Als de file bestaat in het tweede map dan loopt hij vast.

alvast bedankt.

Sub Verplaatsen()
Application.DisplayAlerts = False
    Set FSO = CreateObject("scripting.filesystemobject")
    FSO.MoveFile Source:="U:\Desktop\Nieuwe map\Test\**.xlsx", Destination:="U:\Desktop\Nieuwe map\Test\PREVIOUS REPORTS\" ' replace with source and destination as required.
'
End Sub

 

[edmoor]

Gebruik dit eens:

Sub FC()
    Dim SourceFile, DestinationFile
    SourceFile = "SRCFILE"
    DestinationFile = "DESTFILE"
    
    If Dir(DestinationFile) <> "" Then
        If MsgBox("Doelbestand bestaat al. Overschrijven?", vbQuestion + vbYesNo) = vbYes Then
            FileCopy SourceFile, DestinationFile
        End If
    End If
End Sub

 

[AccessGuru]

Of dit, want je wilt natuurlijk niet kopieren maar verplaatsen:

Sub Verplaatsen()
Const bMap As String = "U:\Desktop\Nieuwe map\Test\"
Dim arr() As Variant, i As Integer
Dim fSO As Object
    
    Set fSO = CreateObject("Scripting.FileSystemObject")
    tmp = Dir(bMap & "*.xls*")
    Do While Not tmp = ""
        ReDim Preserve arr(i)
        arr(i) = tmp
        i = i + 1
        tmp = Dir
    Loop
    
    For i = LBound(arr) To UBound(arr)
        If Dir(bMap & "PREVIOUS REPORTS\" & arr(i)) = "" Then
            fSO.MoveFile Source:=bMap & arr(i), Destination:=bMap & "PREVIOUS REPORTS\"
        End If
    Next i
End Sub

 

[snb]

Je moet natuurlijk wel eerst vertellen wat er moet gebeuren als de bestandsnaam al bestaat.

'Verplaatsen' in VBA doen we zó:

Sub M_snb()
   Name "G:\OF\voorbeeld.xlsx" As "J:\Download\voorbeeld.xslx"
End Sub

 

[AccessGuru]

Er zijn meerdere manieren om bestanden te verplaatsen. Name is er inderdaad ook één van .

 

[Khalid23]

Je moet natuurlijk wel eerst vertellen wat er moet gebeuren als de bestandsnaam al bestaat.

Antwoord:

Bestand vervangen.

 

[Khalid23]

Bedankt voor jullie reacties.

Ik heb bovenstaande codes gebruikt maar helaas werkt het niet.

De bedoeling is al volgt:

De macro moet alle bestanden (xls, xlsm en xlsx) in MAP A verplaatsen naar MAP B.
Als het bestand al bestaat in MAP B dan vervangen.

Is dit duidelijk?

Alvast bedankt

 

[JEC.]

Probeer het dan eens zo

Sub jec()
 Dim it, srcPath, destPath, sq
 srcPath = "U:\Desktop\Nieuwe map\Test\"
 destPath = "U:\Desktop\Nieuwe map\Test\PREVIOUS REPORTS\"
 
 With CreateObject("scripting.filesystemobject")
   For Each it In .getfolder(srcPath).Files
     sq = destPath & it.Name
     If .FileExists(sq) Then Kill sq
    .movefile it, destPath & it.Name
   Next
 End With
End Sub

 

[edmoor]

Of zo:

Sub Verplaatsen()
    Bron = "U:\Desktop\Nieuwe map\Test"
    Doel = "U:\Desktop\Nieuwe map\Test\PREVIOUS REPORTS"
    
    BST = Dir(Bron & "\*.xls*")
    While BST <> ""
        If Dir(Doel & "\" & BST) <> "" Then Kill Doel & "\" & BST
        Name Bron & "\" & BST As Doel & "\" & BST
        BST = Dir()
    Wend
End Sub

 

[snb]

Bron: G:\OF\
Doel: G:\OF\OF1\

Sub M_snb()
   Shell "cmd /c copy G:\OF\*.xls* G:\OF\OF1\", 0
   Kill "G:\OF\*.xls*"
End Sub

 

[Khalid23]

Bedankt. Het werkt.