bijlage in userform

[maomanna]

Hallo allen,

ik heb momenteel een worddocument dat ingevuld wordt met een userform, deze wordt opgeslagen als een PDF en gelijk gemaild naar een vooraf ingesteld emailadres.

Nu wil ik graag weten of het mogelijk is om in het userform een functie te maken waarbij de gebruiker een bijlage kan toevoegen welke aan de mail wordt toegevoegd.
Het einddoel is dat er twee bijlagen in de verzonden mail komen te hangen.

de huidige VBA is

Private Sub CommandButton1_Click()
Dim olkApp As Object
Dim strSubject As String
Dim strTo As String
Dim strBody As String
Dim strAtt As String

    strSubject = "Aanmelding indiensttreding"
   strBody = "Beste collega, In de bijlage de aanmelding van een nieuwe indiensttreding"
    strTo = "hierje@email.nl"
If ActiveDocument.FullName <> "" Then
'
'Silent Save_to_PDF Macro
'
        DocPDF = Replace(ActiveDocument.FullName, ".docm", ".pdf")
        ActiveDocument.ExportAsFixedFormat OutputFileName:=DocPDF, _
        ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:= _
        wdExportOptimizeForPrint, Range:=wdExportAllDocument, Item:= _
        wdExportDocumentContent, IncludeDocProps:=False, KeepIRM:=True, _
        CreateBookmarks:=wdExportCreateNoBookmarks, DocStructureTags:=True, _
        BitmapMissingFonts:=True, UseISO19005_1:=False
    End If
    strAtt = DocPDF
    
    Set olkApp = CreateObject("outlook.application")
    With olkApp.CreateItem(0)
        .To = strTo
        .Subject = strSubject
        .Body = strBody
        .Attachments.Add strAtt
        .Send
        '.Display
    End With
   Set olkApp = Nothing
End Sub

is het mogelijk om een losse bijlage toe te voegen?

Edit:
Het idee bestaat dus wel (http://www.homeandlearn.org/add_new_photo.html)
de vraag is hoe ik dit dan mee kan laten gaan met de mail?

 

[OctaFish]

Dan heb je een extra regel nodig die dat bestand toevoegt. Je weet ondertussen al hoe je dat doet, want de actieregel heb je al.

        .Attachments.Add strAtt
        .Attachments.Add OpenFile

Function OpenFile() As String
With Application.FileDialog(msoFileDialogOpen)
    .Title = "Selecteer een bestand..."
    .AllowMultiSelect = False
    If .Show = -1 Then
        OpenFile = .SelectedItems(1)
    End If
End With
End Function

 

[maomanna]

Nice! dit werkt top. Ik heb de Verzendknop samen gevoegd met de bijlage knop en dat werkt goed!