Cel een tekst geven bij bepaalde waarde andere cel

[4xt]

Goedemiddag,

Ik heb al een tijdje zitten zoeken, maar ik kan geen antwoord vinden op deze vraag.

Als de som van de cellen A1 B1 en C1 gelijk is aan 8. Wil ik in cel D1 de tekst: (Heel goed) laten verschijnen.
Als de som gelijk is aan 7 wil ik de tekst: (Goed) laten verschijnen in cel D1.
Zo wil ik voor verschillende waarden een andere tekst laten verschijnen.

Kan iemand mij helpen welke formule of voorwaardelijke opmaak of lijst ik hiervoor kan gebruiken?

Met vriendelijke groet.

 

[AlexCEL]

Zo bijvoorbeeld:

=ALS(SOM(A1:C1)=8;"(Heel goed)";ALS(SOM(A1:C1)=7;"(Goed)";"(Minder goed)"))

 

[4xt]

Zo bijvoorbeeld:

=ALS(SOM(A1:C1)=8;"(Heel goed)";ALS(SOM(A1:C1)=7;"(Goed)";"(Minder goed)"))

Okay bedankt!
Is het ook mogelijk om de tekst in een lijst te zetten en hier dan automatisch uit te selecteren?
Want bij sommige waarden wil ik een vrij grote tekst schrijven.

 

[AlexCEL]

Niet "quoten" s.v.p. Gebruik knop reageer op bericht, of tekstvak snel reageren onderaan.

Dit is ook een optie:

=ALS.FOUT(KIEZEN(SOM(A1:C1);"(Tekst bij een 1)";"(Tekst bij een 2)";"(Tekst bij een 3)";"(Tekst bij een 4)";"(Tekst bij een 5)";"(Tekst bij een 6)";"(Goed)";"(Heel goed)";"(Tekst bij een 9)"; "(Tekst bij een 10)");"")

(NB bij sommige excelversies moet KIEZEN vervangen worden door KIES geloof ik)

Of als je ergens een lijst met teksten hebt, bijvoorbeeld in H1:I10 (met in kolom H de cijfers, en in kolom I de bijbehorende tekst), dan kan dit ook:

=ALS.FOUT(VERT.ZOEKEN(SOM(A1:C1);H1:I10;2;0);"")

 

[4xt]

Die met VERT.ZOEKEN is precies wat ik bedoel.
Bedankt voor de snelle hulp!

 

[4xt]

Nog een vraag. Ik wil uit 2 verschillende lijsten kiezen. Eén voor wanneer er Ja staat in Cel E1 en een ander voor wanneer er Nee staat.
Is die voorwaarde op te nemen in die formule met VERT.ZOEKEN?

 

[Haije]

Dat wordt dan zoiets:

=ALS(E1="Ja";VERT.ZOEKEN(SOM(A1:C1);H1:I10;2;0);VERT.ZOEKEN(SOM(A1:C1);K1:L10;2;0))

 

[AlexCEL]

Of, verder bordurend op mijn voorbeeld in #4, je zet in kolom I de waarde bij "ja" en bij kolom J de waarde voor "nee" bij een bepaald cijfer (in kolom H).

Dan wordt de formule:

=ALS.FOUT(VERT.ZOEKEN(SOM(A1:C1);H1:J10;ALS(E1="ja";2;3);0);"")

De ALS.FOUT staat eromheen voor het geval A1:C1 niets bevat, te grote of negatieve getallen bevat, etc.