Cel gevuld dan wijzig fontcolor e.d.

[ExcelTonnie]

Als bepaalde cellen gevuld zijn dan moet de tekstkleur veranderen in wit en achtergrond groen.
Ben hiermee aan de slag maar kom er niet uit, wie red mij.
Hij doet alle cellen van Kolom C regel 9 t/m 35, moet alleen wijzigen indien hier iets in staat.

Private Sub CommandButton1_Click()


For s = 9 To 35 'begint op regel 9 en dan 35 naar beneden
 If s <> "" Then
   Cells(s, 3).Select
    With Selection.Interior
        .Color = 5287936
    End With
    With Selection.Font
        .ThemeColor = xlThemeColorDark1
        .TintAndShade = 0
    End With
    Selection.Font.Bold = True
End If
   Next s

End Sub

 

[edmoor]

Zo?

Private Sub CommandButton1_Click()
    With Range("C9:C35").SpecialCells(xlCellTypeConstants)
        .Interior.Color = 5287936
        .Font.Color = vbWhite
        .Font.Bold = True
    End With
End Sub

 

[AHulpje]

Je was een heel eind op weg, maar s is altijd <> "".
Wat wel gewerkt zou hebben:

If Cells(s, 3) <> "" Then

Maar de oplossing van edmoor is mooier.

Met voorwaardelijke opmaak heb je trouwens geen VBA nodig.

 

[ExcelTonnie]

Bedankt wederom voor jullie hulp, idd heb de code van edmoor overgenomen.
THx

 

[snb]

Waarom maak je geen gebruik van Excel ???
Gebruik een style of voorwaardelijke opmaak:

Stijl:

Sub M_snb()
  Range("C9:C20").SpecialCells(4).Style = "normal"
  Range("C9:C20").SpecialCells(2, 2).Style = "good"
End Sub

Voorwaardelijke opmaak:
Noblanks: groen/wit/vet