cel selectern

[don42]

Beste allemaal

wie kan mij helpen met het volgende.
als ik een cel selecteer in kolom C
dan wi ik iets van een melding, hier mag u niets in vullen wilt u naar tabblad 3 (in dit geval zie code)
dat lukt mij prima
maar dan wil ik in tabblad 3 ook aangeven welke cel er geselecteerd moet worden
heb nu als voorbeeld T14 gekozen
als ik de regel : Range("T14").Select weglaat gaat hij keurig naar tabblad 3
nu krijg ik een foutmelding
waar ik ook zoek op het net krijg ik de instructie
Sheets("Blad3").Select
Range("T14").Select
maar dat werkt bij mij niet

wie weet de oplossing
graag ook er bij zetten waar ik wat verkeerd doe wil er graag van leren

bvd
Don

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
 If Not Application.Intersect(Range("C:c"), Target) Is Nothing Then
 Dim Response As VbMsgBoxResult
 Response = MsgBox("Je mag hier niks invullen... " & vbNewLine & "Wil je naar het tabblad 3?", vbQuestion + vbYesNo, "Veolia ©")
 If Response = vbNo Then Exit Sub
 Sheets("Blad3").Select
 Range("T14").Select
 End If
 End Sub

 

[edmoor]

Het valt mij vaak op dat mensen zeggen een foutmelding te krijgen en vragen wat er moet gebeuren om dit op te lossen, zonder erbij te zeggen wat die foutmelding is. Wat is volgens jou dan het nut van een foutmelding?

 

[don42]

de foutmelding

Daar heb je volkomen gelijk in,
dat was niet handig van mij (sorry)
Methode select van klasse range mislukt

is het geen ik te zien krijg

 

[HSV]

Je code staat in blad1 neem ik aan.
Je selecteert met je code blad3, en wil dan T14 van blad1 selecteren, en dat gaat niet.

 Sheets("Blad3").Range("T14").Select

 

[edmoor]

Maak er eens dit van:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim Response As VbMsgBoxResult
    
    If Not Application.Intersect(Range("C:c"), Target) Is Nothing Then
        Response = MsgBox("Je mag hier niks invullen... " & vbNewLine & _
        "Wil je naar het tabblad 3?", vbQuestion + vbYesNo, "Veolia ©")
        If Response = vbNo Then Exit Sub
        ActiveWorkbook.Sheets("Blad3").Activate
        Sheets("Blad3").Range("T14").Select
    End If
End Sub

Edit:
HSV was me net voor.

 

[HSV]

Persoonlijk.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
 If Not Application.Intersect(Range("C:c"), Target) Is Nothing Then
 Dim Response As VbMsgBoxResult
      Response = MsgBox("Je mag hier niks invullen... " & vbNewLine & "Wil je naar het tabblad 3?", vbQuestion + vbYesNo, "Veolia ©")
     If Response = vbNo Then Exit Sub
    Application.Goto Sheets("Blad3").Range("T14")
 End If
 End Sub

 

[edmoor]

Ok

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
 If Not Intersect(Range("C:c"), Target) Is Nothing Then
    If MsgBox("Je mag hier niks invullen... " & vbNewLine & "Wil je naar het tabblad 3?", vbQuestion + vbYesNo, "Veolia ©") = vbYes Then
        Application.Goto Sheets("Blad3").Range("T14")
    End If
 End If
End Sub

 

[Warme bakkertje]

De Application voor Intersect is ook niet echt nodig.

 

[edmoor]

Daar heb je helemaal gelijk in.
Direct aangepast

 

[HSV]

Ook vind ik columns(3) makkelijker typen dan range("C:C").
Het blijft eigenlijk een code van niets.
Als ik vbNo kies kan je gewoon iets invullen.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
 If Not Intersect(Columns(3), Target) Is Nothing Then
    If MsgBox("Je mag hier niks invullen... " & vbNewLine & "Wil je naar het tabblad 3?", vbQuestion + vbYesNo, "Veolia ©") = vbYes Then
        Application.Goto Sheets("Blad3").Range("T14")
        Else
      Application.Goto Target.Offset(, 1)
    End If
 End If
End Sub

 

[edmoor]

Ik hoop dat TS het nog snapt
Waar het maar om gaat m.b.t. zijn vraag is je opmerking in #4.

 

[HSV]

Dwalen we af ?

 

[don42]

Allemaal bedankt voor de medewerking
uiteindelijk heb ik met de code Application.Goto Sheets("Blad3").Range("T14")
mijn gewenste resultaat
helemaal top