CheckBox lukt niet

[dbk]

Goedenmorgen,

Ik heb een macro opgenomen welke werkt, maar als ik de regels in een CheckBox plaats doet hij het niet. Hij geeft een fout.


Opgenomen:

Sub Macro6_Dennis()
'
' Macro5_Dennis Macro
' De macro is opgenomen op 13-10-2008
'

'
    Sheets("Perioden verbergen").Select
    Range("A4").Select
    Sheets("Lange termijnplanning E Oost").Select
    Columns("N:Q").Select
    Selection.EntireColumn.Hidden = False
    Sheets("Personeelplanning E Oost").Select
    Columns("N:Q").Select
    Selection.EntireColumn.Hidden = False
    Sheets("Vergelijkingsplanning E Oost").Select
    Columns("N:Q").Select
    Selection.EntireColumn.Hidden = False
    Sheets("Perioden verbergen").Select
    Range("A4").Select
End Sub

En dit heb ik vertaald naar:

Private Sub CheckBox1_Click()

Application.ScreenUpdating = False

    If CheckBox1.Value = True Then
        'Sheets("Perioden verbergen").Select
       'Range("A4").Select
        Sheets("Lange termijnplanning E Oost").Select
        Columns("N:Q").Select
        Selection.EntireColumn.Hidden = True
        Sheets("Personeelplanning E Oost").Select
        Columns("N:Q").Select
        Selection.EntireColumn.Hidden = True
        Sheets("Vergelijkingsplanning E Oost").Select
        Columns("N:Q").Select
        Selection.EntireColumn.Hidden = True
        Sheets("Perioden verbergen").Select
        Range("A4").Select
    Else
        'sheets("Perioden verbergen").Select
        'Range("A4").Select
        Sheets("Lange termijnplanning E Oost").Select
        Columns("N:Q").Select
        Selection.EntireColumn.Hidden = False
        Sheets("Personeelplanning E Oost").Select
        Columns("N:Q").Select
        Selection.EntireColumn.Hidden = False
        Sheets("Vergelijkingsplanning E Oost").Select
        Columns("N:Q").Select
        Selection.EntireColumn.Hidden = False
        Sheets("Perioden verbergen").Select
        Range("A4").Select
    
    Application.ScreenUpdating = True
    End If
End Sub

Heb ik teveel voorwaarden, of doe ik iets stoms

Wie kan mij opweg helpen?

Groet,
DBK

 

[Roncancio]

Het is niet raadzaam om steeds Select te gebruiken. Alleen als het echt noodzakelijk is.
In dit geval heb je het niet nodig.
Ik ben dan ook zo vrij geweest om je code aan te passen.
Zoals je ziet is deze een stuk korter geworden.

Private Sub CheckBox1_Click()

Application.ScreenUpdating = False
Dim WS As Worksheet

    If CheckBox1.Value = True Then
        For Each WS In ActiveWorkbook.Worksheets
            If Right(WS.Name, 4) = "Oost" Then
                WS.Columns("N:Q").EntireColumn.Hidden = True
            End If
        Next
    Else
        For Each WS In ActiveWorkbook.Worksheets
            If Right(WS.Name, 4) = "Oost" Then
                WS.Columns("N:Q").EntireColumn.Hidden = False
            End If
        Next
     
    End If
    Application.ScreenUpdating = True
End Sub

Met vriendelijke groet,


Roncancio

 

[snb]

Of

Private Sub CheckBox1_Click()
  Application.ScreenUpdating = False
  for each sh in ActiveWorkbook.sheets
     if lcase(right(sh.name,4))="oost" then sh.Columns("N:Q").Hidden = CheckBox1.value
  next
  Application.ScreenUpdating = True
End Sub

 

[dbk]

Roncancio ; bedankt voor de aangepaste code. Ik heb hem eringezet en hij werkt :thumb:

SNB ; ik heb jouw code ook gebruikt, maar hij geeft een foutmelding op "ActiveWorkbook.Worksheets("Oost").Columns("N:Q").Hidden = CheckBox1.value"
Ga zelf even kijken waar dat aan ligt.

Alsnog bedankt voor de snelle reactie.

Groet,
DBK

 

[snb]

Hoeft niet, ik had de code al aangepast. Er is nl. geen werkblad met de naam 'oost'.