Conditional formatting werkt niet

[Rawry]

Hallo,

Ik ben lekker aan het stoeien met Excel vandaag, alleen heb nog een vraag waar ik niet uitkom.

Ik heb cellen een conditional formatting (voorwaardelijke opmaak) gegeven.
De formule achter de voorwaardelijke opmaak werkt prima

=IF($D6="+";$H6>4,5;$H6>2,5) of in het Nederlands:
=ALS($D6="+";$H6>4,5;$H6>2,5)

Alleen wat er gebeurt bij de lege vakken snap ik niet, die worden ook rood terwijl ze volgens mij wit zouden moeten blijven.

Iemand een idee waar dit door komt?

Bekijk bijlage Test sheet vrijwilligers.xlsx

 

[HSV]

De als constructie is overbodig, ook kan het geen getallen aanpassen in een cel.
Enkel doet de Vw opmaak niets anders dan controleren of het WAAR of ONWAAR is in de ingegeven voorwaarde.

In de cellen staat een formule en ziet de uitkomst als >2,5; dus WAAR; vandaar H6<>"".
Ik neem aan dat het rood moet worden als D6=+ of H6>2,5.

=OF($D6="+";EN($H6>2,5;$H6<>""))

Als er aan beide voorwaarden moet worden voldaan; En D6=+ en H6>2,5

=EN($D6="+";$H6>2,5;$H6<>"")

 

[Rawry]

Klopt gedeeltelijk.
Er zijn twee voorwaarden waarop de cel rood moet worden.
1 Als iemand van 23 jaar of ouder meer dan 4,50 per uur verdient (+ in kolom D betekend 23 jaar of ouder)
2 Als iemand jonger dan 23 jaar meer dan 2,50 per uur verdient (- in kolom D betekend jonger dan 23 jaar)

Bij de volgende code wordt dus alleen aan de eerste voorwaarde voldaan en wordt alle - in kolom D ook onterecht rood gekleurd in kolom H

=EN($D6="+";$H6>2,5;$H6<>"")

Hoewel het probleem van de lege cellen die rood kleuren nu wel opgelost is

 

[Rawry]

Ok, die tweede voorwaarde is eigenlijk relatief makkelijk op te lossen bedenk ik me nu

=IF($D6="+";$H6>4,5;IF($D6="-";$H6>2,5;$H6<>""))

Bedankt voor de heldere uitleg en snelle reactie!

 

[Rawry]

Ik heb per ongeluk als gebruikt i.p.v. een EN en Of constructie.
Maar dit werkt blijkbaar toch ook met de $H6<>"" op het einde

 

[HSV]

Je moet de formule eens in cel M6 en verder naar onderen zetten, dan verschijnt er vanzelf WAAR of ONWAAR.
En dan wordt het zoiets.

=OF(EN($D6="+";$H6>4,5;$H6<>"");EN($D6="-";$H6>2,5;$H6<>""))

Als dat goed is bevonden zet je het in de Vw Opmaak.

 

[Rawry]

Ik denk dat ik het nu definitief heb opgelost.

De IF leek in eerste instantie te werken, maar werkte inderdaad toch niet helemaal zoals de bedoeling is.
Met mijn nieuwe formule krijg ik een true value bij een + icm >4,5 een - icm >2,5 en bij het leeg laten van kolom D ook >2,5

=OR(AND($D6="+";$H6>4,5;$H6<>"");OR(AND($D6="-";$H6>2,5;$H6<>""));OR(AND($D6="";$H6>2,5;$H6<>"")))

Bedankt!

 

[HSV]

Je OF constructie is niet helemaal juist.

=OR(AND($D6="+",$H6>4.5,$H6<>""),OR(AND($D6="-",$H6>2.5,$H6<>""),AND($D6="",$H6>2.5,$H6<>"")))

Als er in je validatielijstje alleen maar "+" en "-" staan of leeg is, kan het iets korter.

=OR(AND($D6="+",$H6>4.5,$H6<>""),AND($D6<>"+",$H6>2.5,$H6<>""))

 

[Rawry]

Ik snap het, ik heb de OF functie verkeerd gebruikt.
En die laatste is inderdaad slimmer, fijn!
Hij staat er nu goed in.

=OR(AND($D6="+";$I6>4,5;$I6<>"");AND($D6<>"+";$I6>2,5;$I6<>""))

Wat ik me wel afvraag:
Hoe komt het dat je een komma gebruikt waar mijn versie van excel (2013) alleen een puntkomma herkent en je een punt gebruikt waar ik een komma moet gebruiken.
Is dit niet voor alle versies van excel hetzelfde?
Of is dit een optie die ergens in te stellen is?
Of is dat verschillend voor Nederlands vs Engels?

 

[HSV]

Dat is versie afhankelijk.
Nederlands is volgens mij altijd ;
Engels kan ; of , zijn.