Controlegetal EAN 13 berekenen

[tobyke]

Hoi, ik ben al een hele poos niet meer hier geweest, maar kom er niet uit.
Ik heb een artikelnummerlijst van 8 cijfers, daarvoor zetten we 4 keer een 9 om aan 12 getallen te komen waarmee het systeem voorheen automatisch een controlegetal aanmaakte (geen excel).
Nu moet ik een template invullen voor de cloudversie van het systeem, we zetten alle nummers om naar nummers waarin diersoort, herkomst en verpakking in opgenomen en herkenbaar zijn. Daardoor krijgen ze ook nieuwe EAN nummers. Normaal gesproken maken we ee nieuw nr. aan en geeft het systeem een controlegetal. In de template wordt nu het hele EAN nr gevraagd....en ik heb 2 formules van Copilot gekregen die alletwee niet werken, of door excel 'hersteld' worden tot iets wat niet meer werkt
=MOD(10 - MOD(SOMPRODUCT(MID(A2,{1,3,5,7,9,11},1)*1) + SOMPRODUCT(MID(A2,{2,4,6,8,10,12},1)*3), 10), 10)
=REST(10 - REST(SOMPRODUCT((MID(A2;{1;3;5;7;9;11};1)*1) + SOMPRODUCT((MID(A2;{2;4;6;8;10;12};1)*3));10);10)

"gewoon" google levert dit op:
=10-REST(SOMPRODUCT(N(MID(A1;RIJ(1:6)*2-1;1))*3;10);10), daarin pakt ie 6 rijen ipv 6 getallen in 1 rij.....

Is er een formule waarmee ik het controlegetal kan berekenen en zo m'n EAN kan samenvoegen?
Alvast dank!

 

[Lampie173]

Voeg een voorbeeldbestand toe dat maakt het wat gemakkelijker voor de helpers.

 

[AlexCEL]

Zo wel ok? (MID=DEEL)

=10-REST(SOMPRODUCT(1*DEEL(A2;{1;3;5;7;9;11};1))+SOMPRODUCT(3*DEEL(A2;{2;4;6;8;10;12};1));10)

Of misschien zoiets voor Excel 365:

=10-REST(SOM(DEEL(A2;REEKS(12);1)*{1;3;1;3;1;3;1;3;1;3;1;3});10)

 

[Warme bakkertje]

@AlexCEL
Heb even snel beide formules geprobeerd op dit nummer

500011254463

De bovenste formule werkt perfect en geeft controlegetal 3 als resultaat hetgeen juist is.
De onderste formule geeft echter 6 als controlegetal wat fout is.

 

[AlexCEL]

Hoi Rudi, bij mij komt er in beide gevallen 3 uit...

 

[peter59]

Lekker gokspelletje weer.

 

[Warme bakkertje]

Lekker gokspelletje weer

Toch niet. Foutje van mijn zijde, waarschijnlijk bij het vertalen v/d formule.
Mea Culpa.

 

[tobyke]

Zo wel ok? (MID=DEEL)

=10-REST(SOMPRODUCT(1*DEEL(A2;{1;3;5;7;9;11};1))+SOMPRODUCT(3*DEEL(A2;{2;4;6;8;10;12};1));10)

Of misschien zoiets voor Excel 365:

=10-REST(SOM(DEEL(A2;REEKS(12);1)*{1;3;1;3;1;3;1;3;1;3;1;3});10)

De onderste werkt!!! Ik heb ter controle bij GS1 een paar nummers ingevoerd en alles klopt. daar waar er 10 uikomt zet ie een 0 achter het nummer. Dat kan ik verwerken. SUPERBEDANKT!!

 

[alphamax]

=10-REST(SOMPRODUCT(1*DEEL(A5;{1;3;5;7;9;11};1))+SOMPRODUCT(3*DEEL(A5;{2;4;6;8;10;12};1));10)

uit bericht #3, geeft 10 bij 978030640614 en niet 0

=REST(-SOM((3-2*REST(RIJ($1:$12);2))*DEEL(A2;RIJ($1:$12);1));10)

bij oudere excelversies bevestigen met CTRL+SHIFT+ENTER = matrixformule
geeft 0 bij 978030640614 wat juist is

p.s. hier kan je bulk testen, zie https://www.morovia.com/bulk-check-digit-calculation/

 

[AlexCEL]

Zo dan:

=REST(10-REST(SOMPRODUCT(1*DEEL(A5;{1;3;5;7;9;11};1))+SOMPRODUCT(3*DEEL(A5;{2;4;6;8;10;12};1));10);10)
=REST(10-REST(SOM(DEEL(A2;REEKS(12);1)*{1;3;1;3;1;3;1;3;1;3;1;3});10);10)