DAO-gesynchroniseerde comboboxen

[cadvba]

Hoi ,
Ik zit met het volgende probleem
Over gesynchroniseerde comboboxen binnen Access + DAO problemen is op je forum
op verschillende plaatsen geschreven. (leuk forum trouwens)
Nu, als ik beide problemen combineer, loopt het voor mij vast.
Ik heb hierbij een zip-bestand gezet, met daarin een Excel en een Access bestand.
Als ik beiden in C\TEST-DAO\ zet, open het Excel bestand en start de macro,gaat
deze waarden uit de queries van Access-bestand halen om de verschillende comboboxen
te vullen.
In de macro kan je zien dat ik voor de tweede en derde combobox vaste waardes “BELGIE” + “Limburg” heb gezet. Dit is natuurlijk niet de bedoeling.
Ik wil hier telkens ik de vorige combobox wijzig, deze waarde laten veranderen.
Ik hoop dat ik mijn probleem duidelijk heb overgebracht, en dat je even tijd hebt om er
naar te kijken.
Alvast dank bij voorbaat.

 

[Spiderman]

Hoi cadvba,

Ik zou de code hieronder gebruiken:

Option Explicit
Private Sub cmb_Landen_Change()
    
    cmb_Provincies.Clear
    Dim dbs11 As DAO.Database
    Dim rst11 As DAO.Recordset
    Set dbs11 = OpenDatabase(Name:="C:\TEST-DAO\" & "\data.mdb")
    Set rst11 = dbs11.OpenRecordset("Select provincies FROM Query_LANDEN_PROVINCIES WHERE landen = '" & cmb_Landen.Text & "';")
    Do While Not rst11.EOF
        cmb_Provincies.AddItem rst11("provincies")
        rst11.MoveNext
    Loop

End Sub

Private Sub cmb_Provincies_Change()
    cmb_Steden.Clear
    Dim dbs12 As DAO.Database
    Dim rst12 As DAO.Recordset
    Set dbs12 = OpenDatabase(Name:="C:\TEST-DAO\" & "\data.mdb")
    Set rst12 = dbs12.OpenRecordset("Select steden FROM Query_LANDEN_PROVINCIES_STEDEN WHERE provincies = '" & cmb_Provincies.Text & "';")
    Do While Not rst12.EOF
        cmb_Steden.AddItem rst12("steden")
        rst12.MoveNext
    Loop

End Sub

Private Sub UserForm_Initialize()
'Keuze uit Acces Database Data.mdb met combobox

    Dim dbs10 As DAO.Database
    Dim rst10 As DAO.Recordset
    Set dbs10 = OpenDatabase(Name:="C:\TEST-DAO\" & "\data.mdb")
    Set rst10 = dbs10.OpenRecordset("Select landen FROM Query_LANDEN;") '
    Do While Not rst10.EOF
        cmb_Landen.AddItem rst10("landen")
        rst10.MoveNext
    Loop
   
End Sub

P.S. Je kunt beter het forum http://www.helpmij.nl/forum/forumdisplay.php?f=5 gebruiken.
De sectie die je nu gebruikt is meer voor het testen van programma's, niet voor problemen.

 

[cadvba]

Dank Arno

Ik dit even getest.

Dit werkt perfect.

Mijn dank is groot!!!

Groeten

 

[aaajeetee]

Topic verplaatst en status op opgelost gezet.