Datum berekenen

[elvanlim]

Hallo,

Ik wil 36,6 maanden op een datum tellen (bijvoorbeeld 15-10-2010). Welk formule kan ik hiervoor gebruiken?

Ik had zelf onderstaande formule gehanteerd, echt hij rekent niet de cijfer achter de komma?

=datum(jaar(A1);maand(A1)+A2;dag(A1))

Groet,

Elvanlim

 

[ExcelAmateur]

elvanlim,

Bedoel je 3,5 jaar?
Zoja dan deze formule

=ZELFDE.DAG(A1;42)

 

[elvanlim]

Hoi,

Bedankt voor je reactie.

Nee, ik wil echt 36,6 maanden op een datum tellen, dus v.b. 1-1-2010 + 36,6 maanden (of 36,8 maanden) = datum???

 

[ExcelAmateur]

Dus je bedoel een 6e of een 8e deel van een maand?

 

[Thoralf]

Hallo Elvanlim,

Als je jouw formule nu eens vervangt door

=DATUM(JAAR(A1);MAAND(A1)+A2;DAG(A1)+REST(A2;1)*30)

geeft dat niet het juiste resultaat?

 

[ExcelAmateur]

Zou dit dan iets zijn?
Dus 2 cellen gebruiken, 1 voor de maanden en 1 voor het aantal dagen.
Zie plaatje.

 

[mcs51mc]

Probeer dit eens met je datum in cel A10

=DATE(YEAR(A10);MONTH(A10)+36;DAY(A10)+DAY(DATE(YEAR(A10);MONTH(A10)+1;1)-1)*0.6)

Let wel, dit is enkel juist als je x volledige jaren bijtelt, 3 in jouw geval.
We blijven immers in dezelfde maand, nu moet er nog 60% van het aantal dagen in die maand bijgeteld worden.

Indien je een willekeurig aantal maanden zou bijtellen, dan moet je eerst je nieuwe maand bepalen en van die maand het aantal dagen bepalen en daar 60% van bijtellen bij je tussenresultaat. In dit geval heb je dus twee stappen nodig.

 

[elvanlim]

Bedankt voor jullie reacties!

Formule van Thoralf is de kortste en de juiste route waar ik naar op zoek was.

Nogmaals bedankt!

Ik zal de status op opgelost zetten.

Vriendelijke groet,

Elvanlim:thumb:

 

[mcs51mc]

Ik geef gerust toe dat dit niet meer leesbaar is maar het werkt wel

=DATE(YEAR(DATE(YEAR(A20);MONTH(A20)+B20;DAY(A20)));MONTH(DATE(YEAR(A20);MONTH(A20)+B20;DAY(A20)));DAY(DATE(YEAR(A20);MONTH(A20)+B20;DAY(A20)))+DAY(DATE(YEAR(DATE(YEAR(A20);MONTH(A20)+B20;DAY(A20)));MONTH(DATE(YEAR(A20);MONTH(A20)+B20;DAY(A20)))+1;1)-1)*B21)

Cel A20 = startdatum : vb 03/05/2010
Cel B20 = willekeurig aantal maanden bij te tellen: vb 21
Cel B21 = decimaal deel van de maand bij te tellen: vb 0.95

Dan komen we uit op 03/02/2012 schrikkeljaar!!!
Daar 0.95ste deel van is 27(.55) dagen
Finaal wordt dit dus 01/03/2012


Die korte formule houd geen rekening van de lengte van de maand!!
Een maand kan 28, 29, 30 of 31 hebben mocht je dat niet weten
Dus zomaar vermenigvuldigen met 30 is zeker niet correct

 

[robdgr]

@Thoralf: Als ik de gemiddelde jaarlengte (365,25) deel door 12 kom ik op 30,44 voor de gemiddelde maandlengte. Kun je niet beter daarmee rekenen? Dus

=DATUM(JAAR(A1);MAAND(A1)+INTEGER(A2);DAG(A1)+REST(A2;1)*30,44)

Ik kom hiermee op 02-11-2013

 

[Thoralf]

@robdgr,

Op zich helemaal correct. Ik heb mij echter beperkt tot het getal 30 omdat dat getal ook in veel financiële berekeningen gehanteerd wordt.
Wil je dan echter de door jou aangehaalde nauwkeurigheid hanteren, dan zou ik in plaats van

+REST(A2;1)*30,44

moeten kiezen voor

+AFRONDEN(REST(A2;1)*30,44;0)

of eventueel een andere vorm van afronden.

 

[mcs51mc]

En waarom zouden we beginnen uitmiddelen, afronden enz om toch maar iets uit te komen die verkeerd is terwijl de juiste berekeningswijze ook al aan bod gekomen is???

Tenzij het inderdaad om financiële berekeningen gaat waar een maand inderdaad 30 dagen telt, ongeacht de maand. Dan is Thoralf zijn formule meer dan ok, maar de draadstarter heeft daar geen informatie rond gegeven.

 

[robdgr]

@mcs51mc: Thoralf heeft zelfs met mijn aanvulling, een Veluwse samenwerking, minder woorden nodig dan u met uw uitgebreide formule waardoor ik met 'onze' formule met uw gegevens uitkom op 02-03-2012. Dus wat is het probleem? Over het algemeen bestaat één oplossing niet.

 

[mcs51mc]

Het probleem is dat 02/03/2012 verkeerd is, het moet wel degelijk 01/03/2012 zijn
Jullie "eenvoudige" formule houdt geen rekening met oa. schrikkeljaren.
Ik geef liever juiste oplossingen :thumb: dan halve oplossingen "voor het gemak"
Wanneer je die "uitgebreide" formule niet begrijpt, vraag gerust een woordje uitleg, maar kom dan niet klagen als er véééél woorden aan te pas komen.

In de trappen van vergelijking, a) fout, b) bijna juist en c) correct zou ik jullie vergelijking bestempelen met "fout" en de mijne met "correct".
Sorry dat ze een beetje langdradig is
Still :love: you guys !!

 

[Thoralf]

Goed of fout zijn relatieve begrippen, ingegeven door het referentie kader van de beoordelaar c.q. de vraagsteller.
Laten we hier de discussie mee sluiten.