Datum springen

[schilderehbo]

Ik heb al verschillende onderwerpen hier gelezen over naar datum springen maar kan niet echt de juiste vinden.
Wat ik dus wil ik heb 5 tabbladen en 1 tabblad met een heel jaar staan en in elke cel staat een datum notatie hoe laat ik de excel blad zo opstarten dat hij naar de juiste datum van vandaag springt.
alvast bedankt.

 

[AHulpje]

Als kolom A op werkblad "JouwWerkblad" de datums bevat:

Function GaNaarVandaag()
    On Error GoTo errHandler
    Application.Goto Sheets("JouwWerkblad").Range("A:A").Find(What:=Date).Offset(0, 1), False
    ActiveWindow.ScrollRow = ActiveCell.Row - 10
    Exit Function
errHandler:
    MsgBox "Datum " & Date & " niet gevonden."
End Function

Aanroepen vanuit workbook_open event.

 

[schilderehbo]

alvast dankje maar staan niet in 1 kolom. zal effe voorbeeld bij plaatsen.

 

[AHulpje]

Dan wordt het heel anders, plaats deze code achter werkblad "Jaaroverzicht trainingen."

Option Explicit

Private Sub Worksheet_Activate()
    GaNaarVandaag
End Sub


Sub GaNaarVandaag()
    Dim Rng As Range
    
    Application.Goto Range("B6")
    Do
        Set Rng = Cells.Find(What:=Day(Date), After:=ActiveCell, LookIn:=xlValues, LookAt:= _
        xlWhole, SearchOrder:=xlByColumns, SearchDirection:=xlNext, MatchCase:=False _
        , SearchFormat:=False)
        Application.Goto Rng
    Loop While Not Rng Is Nothing And Month(ActiveCell) < Month(Date)
    Application.Goto Rng.Offset(1, 0)
    ActiveWindow.ScrollColumn = ActiveCell.Column - 4
End Sub

Maar sommige datums komen twee keer voor op de kalender, niet echt handig.

 

[edmoor]

Of deze:

Private Sub GaNaarVandaag()
    Application.Goto Cells(4, Month(Date) * 7 + 2)
    Set Rng = Range(ActiveCell.Address).Resize(14, 7)
    Set c = Rng.Find(Day(Date), , xlValues, xlWhole)
    If Not c Is Nothing Then
        Application.Goto Cells(c.Row + 1, c.Column)
    End If
End Sub

 

[schilderehbo]

Dankje wel hij doet het. En dubbele datums is inderdaad niet handig maar zou niet weten hoe het anders kan je zit met start datum van het jaar dus het kan volgend jaar zomaar andere cel zijn en daar moet dan wel een notatie staan. ik gebruik wel altijd maandag als eerste dag.

 

[AHulpje]

@edmoor
Er zijn vele wegen die naar Rome leiden, en sommige zijn wat korter ;-)
Nog een ScrollColumn erbij en hij is perfect!

 

[schilderehbo]

Dank je werkt perfect alleen wat zet ik waar om het gehele excel in dat blad te openen. neem aan in This Workbook een korte code.

 

[edmoor]

Deze van AHulpje in de Worksheet module:

Private Sub Worksheet_Activate()
    GaNaarVandaag
End Sub

De Sub GaNaarVandaag() zet je daar dan onder.

 

[schilderehbo]

Die snap ik effe niet die staat er al in. Maar opent in ander tabblad.

 

[AHulpje]

@edmoor
Maar GaNaarVandaag activeert niet het werkblad "Jaaroverzicht trainingen."

Ik zou

Private Sub Workbook_Open()
    Sheets("Jaaroverzicht trainingen.").Activate
End Sub

achter ThisWorkbook plakken, dan wordt dankzij het Worksheet_Activate event van werkblad "Jaaroverzicht trainingen." de sub GaNaarVandaag uitgevoerd.

 

[edmoor]

Als je een ander werkblad actief hebt en je klikt op "Jaaroverzicht trainingen." dan wordt de code uitgevoerd.
Wat AHulpje zegt kan ook.

 

[schilderehbo]

Dank u zeer hij doet het.