Datumverschil in jaren en dagen berekenen

[Henk1908]

Goedemorgen,

Ik probeer in Excel het totaal aantal dagen om te zetten naar het aantal jaren en de rest in dagen. Ik heb een formule die het totaal aantal dagen wel omzet in jaren, maanden en dagen, maar wat ik ook probeer ik krijg het niet voor elkaar om alleen de jaren en dagen te berekenen en de maanden eruit te halen. De formule die ik heb voor het omzetten van het aantal dagen in jaren, maanden en dagen luidt:

=DATUMVERSCHIL(0;8170;"y")&"jaar, "&REST(DATUMVERSCHIL(0;8170;"m");12)&"maand en "&DAG(8170)&" dagen"

Het resultaat is 22 jaar, 4 maanden en 14 dagen. Ik zoek dus naar 22 jaar en X dagen. Wie kan mij hierbij helpen? Alvast bedankt.


Groeten Henk

 

[edmoor]

Zo?

Jaren   : =DATUMVERSCHIL(0;8170;"y")
Maanden : =DATUMVERSCHIL(0;8170;"ym")
Dagen   : =DATUMVERSCHIL(0;8170;"md")

 

[Henk1908]

Hoi Edmoor,

Bedankt. Dit brengt mij een stukje verder, maar het is de bedoeling dat de maanden ook in dagen worden omgezet. In mijn voorbeeld krijg je dus 22 jaar + de dagen van de resterende maanden. De vier maanden die er tussen zitten moeten dus ook in dagen worden omgerekend.

 

[E v R]

zoiets:

=DATEDIF((0);(8170);"y")& " jaar en "&DATEDIF(DATE((0)+DATEDIF(0;(8170);"y");MONTH(0);DAY(0));(8170);"D")&" dagen"

op de plek van (0) de begindatum en op de plek van (8170) de einddatum

 

[Senso]

=ALS(REST(A2;365)=0;A2/365&" Year(s)";INTEGER(A2/365)&" Year(s) & "&REST(A2;365)&" Days")

 

[Henk1908]

Hoi Eric,

Ik heb de formule aangepast zoals aangegeven. Deze is nu: =DATEDIF((24-11-1983);(7-4-2006);"y")& " jaar en "&DATEDIF(DATE((24-11-1983)+DATEDIF(24-11-1983;(7-4-2006);"y");MONTH(24-11-1983);DAY(24-11-1983));(7-4-2006);"D")&" dagen"

Ik krijg nu de foutmelding #NAAM?

 

[edmoor]

Uiteraard moet je dan de NL namen van de functies gebruiken.

 

[AlexCEL]

De functie DATUMVERSCHIL heb je toch niet nodig? Je kunt 2 datums zo van elkaar aftrekken om het aantal dagen te krijgen...

=INTEGER(("7-4-2006"-"24-11-1983")/365)&" jaar en "&365*REST(("7-4-2006"-"24-11-1983")/365;1)&" dagen"

Of als je deze datums eventjes in 2 cellen zet (A1 en B1 bijvoorbeeld):

=INTEGER((A1-B1)/365)&" jaar en "&365*REST((A1-B1)/365;1)&" dagen"

 

[Henk1908]

Ik heb nu in de door Eric aangereikte formule de NL-namen opgenomen en deze werkt nu. Iedereen onwijs bedankt voor de moeite! :thumb::thumb::thumb:

 

[Senso]

Zet die werkende formule hier dan nog eens neer. Ik kom op 134 dagen en dat moet 140 dagen zijn.

 

[snb]

Mij lijkt dit voldoende:

in A1: 8170 (22 jaar, 134 dagen)

=MOD(YEAR(A1);100) &" jaar, " &A1-DATE(YEAR(A1);1;0)&" dagen"

Als je uitgaat van een datum in A1 en met vandaag vergelijkt, lijkt me dit de zuiverste Excel-methode voor het aantal dagen:

=TODAY()-EDATE(A29;FLOOR(DATEDIF(A29;TODAY();"m");12))

 

[Senso]

Waarom geeft die andere berekening dan 140 dagen?

 

[snb]

Het maakt uit of je een jaar als 365 dagen of als 365,25 dagen beschouwt.

 

[sylvester-ponte]

Henk, als je 8170 dagen in jaren en dagen wil verdelen,
dan kan er 1 dag verschil in het antwoord zitten afhankelijk van wanneer het interval start.
dit gebeurt door de invloed van schrikkeljaren.

 

[sylvester-ponte]

zie voorbeeld:
je kan het ook en één formule stoppen maar:
geef ook aan met welke versie van excel je werkt . 365 maakt het vaak een stuk eenvoudiger.

 

[Senso]

Gregoriaanse kalender 365,2425. Was ik vergeten. Zet je dat in de formule moet je wel op een of ander manier INTEGER verwerken?

 

[Henk1908]

Zet die werkende formule hier dan nog eens neer. Ik kom op 134 dagen en dat moet 140 dagen zijn.

.

De formule luidt nu als volgt:

=DATUMVERSCHIL((0);(J4);"y")& " jaar en "&DATUMVERSCHIL(DATUM((0)+DATUMVERSCHIL(0;(J4);"y");MAAND(0);DAG(0));(J4);"D")&" dagen"

 

[Henk1908]

zie voorbeeld:
je kan het ook en één formule stoppen maar:
geef ook aan met welke versie van excel je werkt . 365 maakt het vaak een stuk eenvoudiger.

Ik gebruik MS Officie Professional Plus 2019.

 

[Senso]

Heel mooi. Bedankt voor de formule Henk.:thumb:

 

[Henk1908]

Heel mooi. Bedankt voor de formule Henk.:thumb:

Ik begrijp uit een aantal reacties dat in deze formule dus geen rekening wordt gehouden met schrikkeljaren. Hoe luidt de formule als hier wel rekening mee wordt gehouden? Er moet dus aan onderstaande formule iets worden toegevoegd om rekening te houden met schrikkeljaren:

=DATUMVERSCHIL((0);(J5);"y")& " jaar en "&DATUMVERSCHIL(DATUM((0)+DATUMVERSCHIL(0;(J5);"y");MAAND(0);DAG(0));(J5);"D")&" dagen"