Opgelost De hoeveelste zondag van de maand

[gst]

Geacht forum.

Bestaat er een mogelijkheid om a.d.h. een ingevoerde datum via een formule te bepalen welke zondag het is van de maand? Voorbeeld: bij een ingevoerde datum 20-10-2024, geeft dit als resultaat: 3e.

 

[cow18]

=NETWERKDAGEN.INTL(LAATSTE.DAG(F1;-1);F1;"1111110")

 

[AlexCEL]

Minder elegant dan die van cow, maar nog een optie:

=LET(x;LAATSTE.DAG(F1;-1);SOM(--(WEEKDAG(REEKS(F1-x+1;;x))=1)))

 

[gst]

Erg bedankt voor de reacties!
Beide suggesties zijn voor mij goed bruikbaar.

 

[rebmog]

De opgegeven formules kloppen volgens mij net niet helemaal. Bij 7-4-2024 geven deze formules een 2 terug, terwijl het een 1 moet zijn. Dit komt omdat gerekend wordt vanaf LAATSTE.DAG(F1;-1) in plaats van LAATSTE.DAG(F1;-1)+1.

De formules moeten dan volgens mij worden:

=NETWERKDAGEN.INTL(LAATSTE.DAG(F1;-1)+1;F1;"1111110")

=LET(x;LAATSTE.DAG(F1;-1);SOM(--(WEEKDAG(REEKS(F1-x;;x+1))=1)))

of nog een andere formule:

=SOM(--(WEEKDAG(RIJ(INDIRECT(LAATSTE.DAG(F1;-1)+1&":"&F1)))=1))

 

[lam201]

Volgens mij werkt deze ook

=AFRONDEN.NAAR.BOVEN(DAG(G9)/7;0)

 

[gst]

Ik moet toch even terugkomen op de reacties die ik ontvangen heb.
Het blijkt inderdaad dat de voorgestelde formules niet allemaal de juiste weergave geven zoals al door rebmog reeds aangegeven. De juiste formule blijkt toch van lam201.
Zie bijgaande bijlage waarbij alle voorgestelde formules getest heb.
Hieruit blijkt dat alleen de formule van lam201 het correcte resultaat levert.
Nogmaals allen dankt voor de moeite!

 

[Warme bakkertje]

Hieruit blijkt dat alleen de formule van lam201 het correcte resultaat levert.

Dit vind ik toch een iets te sterke uitspraak.
Het hangt ervan af hoe je jouw vraag interpreteert. In je openingsvraag gaf je de datum op van een zondag en wou je weten de hoeveelste zondag dit was van die maand.
En dit doen bijna alle formules juist als je in de bijlage de rechterkolom filtert op 1.
Het enige verschil is dat je met de formule van @lam201 tijdens een dag in de week de aanduiding krijgt de hoeveelste zondag de eerstkomende zal zijn.
Dus wil je van een specifieke zondagdatum weten de hoeveelste zondag dit is, is de aangepaste formule van @cow18 ook altijd correct. Wil je van een willekeurige weekdatum weten de hoeveelste zondag de eerstkomende zal zijn is de formule van @lam201 de juiste.

 

[gst]

Oké, hier zit wat in, je hebt gelijk.
Dank voor je opmerking.