Dos Dir in Excel

[AABE]

Geacht forum.

ik zoek een snelle manier om de inhoud van een folder in excel te krijgen.
De systematiek mbv FileSystemObject is op een netwerk erg traag.

Bij het werken met de DOS Dir loop ik tegen het volgende probleem aan.

Test1 doet het prima, echter Test2 niet.

Weten jullie hier een oplossing voor?

mvg,

Aat

Sub test1()

    Dim cmd As String
    Dim ret As Double
    
    rootfolder = "C:\TestFolder\"
     
    cmd = "cmd.exe /c dir " & rootfolder & "/S > C:\contents.txt"
    ret = Shell(cmd, vbHide)

End Sub

Sub test2()

    Dim cmd As String
    Dim ret As Double
    
    rootfolder = "C:\Test Folder\"
     
    cmd = "cmd.exe /c dir " & rootfolder & "/S > C:\contents.txt"
    ret = Shell(cmd, vbHide)

End Sub

 

[Warme bakkertje]

Al eens geprobeerd met het Dir-command ?

 

[AABE]

Al eens geprobeerd met het Dir-command ?

Ja, maar dat is ook erg traag op het netwerk.....

 

[Warme bakkertje]

Eventjes Googlen had je deze opgeleverd

'Written: August 20, 2009
'Author:  Leith Ross
'Summary: Convert Long Window path names to short DOS path names

Private Declare Function GetShortPathNameA Lib "kernel32.dll" _
    (ByVal lpszLongPath As String, _
     ByVal lpszShortPath As String, _
     ByVal cchBuff As Long) As Long
    
Function GetShortPath(LongPath As String)
    Dim BuffSize As Long
    Dim RetVal As Long
    Dim ShortPath As String
  
    BuffSize = 260
    ShortPath = String(BuffSize, " ")
    
    If Asc(Left(LongPath, 1)) = 34 Then
       LongPath = Mid(LongPath, 2, Len(LongPath) - 2)
    End If
    RetVal = GetShortPathNameA(LongPath, ShortPath, BuffSize)
    If RetVal <> 0 Then
        GetShortPath = Left(ShortPath, RetVal)
    End If
End Function

Sub test2()
    Dim cmd As String
    Dim ret As Double
    
    RootFolder = GetShortPath("C:\Test Folder\")
     
    cmd = "cmd.exe /c dir " & RootFolder & "/S > C:\contents.txt"
    ret = Shell(cmd, vbHide)

End Sub

 

[AABE]

Hi Rudi,

bedankt... tja, daar was ik nog niet opgekomen.

mvg,

Aat

 

[AABE]

Hi Rudi,

het werkt.... bedankt....

mvg,

Aat