Dubbel verticaal zoeken

[kassie21]

Beste
Ik kom niet uit een formule waarbij ik dubbel vertikaal naar een waarde wil zoeken.
Volgens mij komt dit doordat ik een verwijzing naar een validatie lijst heb gemaakt.
Ik heb een voorbeeld bijgevoegd in de bijlagen. Op tabblad 1 heb ik het validatie keuze menu weergegeven.
En op tabblad 2 moet er het uur van het jaar worden weergegeven in 1 cel. Ik heb dit geprobeerd met de formule
Index(matrix;vergelijken(1;(zoekwaarde;matrix)*(zoekwaarde;matrix);0)) echter krijg ik dan de foutcode NB

Heeft iemand een andere oplossing?

Met vriendelijke groet,

 

[gelens]

Kassie

De formule werkt prima maar er was een probleem met de validatie.
Ik heb er nog een formule bijgezet.

 

[Thankyou]

Heb je al gezien dat de datum & tijdwaarden niet altijd overeenkomen? Als ik deze gebruik =Blad1!B2&Blad1!C2 komt daar 401800,458333333333334 uit en bij de zelfde truuk bij blad 2 dan komt daat 401800,458333333333333 uit en dat is de rede van de #NB. Wat hier de oorzaak van is weet ik niet.

 

[Thankyou]

Dit zou je kunnen proberen:

=INDEX(Blad2!L2:L745;VERGELIJKEN(AFRONDEN(Blad1!B2&Blad1!C2;14);AFRONDEN(Blad2!J2:J745&Blad2!K2:K745;14);0))

Of in het engels:
=INDEX(Blad2!L2:L745,MATCH(ROUND(Blad1!B2&Blad1!C2,14),ROUND(Blad2!J2:J745&Blad2!K2:K745,14),0))

Let op: Matrixformule, afsluiten met CTRL+SHIFT+ENTER i.p.v. enter

Succes,

 

[kassie21]

Kassie

De formule werkt prima maar er was een probleem met de validatie.
Ik heb er nog een formule bijgezet.

Hoe bedoel je dat? En de formule som product ken ik niet? Wat doet deze als ik vragen mag?
En als ik dan de datum verander komt er wederom geen waarde uit.

Ik heb de formule afgesloten met ctrl shift enter echter hielp dit niet bij het oplossen van de formule.
En als ik op celeigenschappen kijk wordt er wel datum en tijd weergegeven of heb ik dat fout?

Alvast bedankt!

 

[Thankyou]

@Gelens,

Je formules gaan fout als je een tijd van 11:00 kiest (zie bericht #3). Gebruik afronden in je formule en het werkt.

=SOMPRODUCT((J2:J745=B2)*(AFRONDEN(K2:K745;14)=AFRONDEN(C2;14))*(L2:L745))
of engels: =SUMPRODUCT((J2:J745=B2)*(ROUND(K2:K745,14)=ROUND(C2,14))*(L2:L745))

en voor de ander
=INDEX(L2:L2000;VERGELIJKEN(1;(B2=J2:J2000)*(AFRONDEN(C2;14)=AFRONDEN(K2:K2000;14));0)) (Matrixformule)
in engels:=INDEX(L2:L2000,MATCH(1,(B2=J2:J2000)*(ROUND(C2,14)=ROUND(K2:K2000,14)),0))

Succes,

 

[kassie21]

Dankje! Inderdaad doormiddel van afronden kan ik deze formule wel toepassen!
Hartelijk dank voor je hulp!