Dubbelklikken cel

[HammerJohn]

Ik zou willen weten of het mogelijk is wanneer ik in een cel dubbelklik 4 andere cellen in te vullen met een cel waarde uit een
aangewezen cel

dus ik wil b1-b4 invullen met een A deze a staat in X1 en de dubbel te klikken cel is A10 hier mag van mij een letter inkomen of
een getal of de waarde uit X1

iemand die mij helpen kan

 

[VenA]

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Address = "$A$10" Then
  Cancel = -1
  Range("B1:B4") = Range("X1").Value
End If
End Sub

 

[Ginger]

Ik lees 'm algemener....

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

  Cancel = -1
  activecell.offset(,1).resize(,4).value = activecell.Value

End Sub

[EDIT] Ha ha ha... Maar bij nogmaals lezen heb ik het vermoeden helemaal fout te zitten met m'n oplossing...

 

[HammerJohn]

VenA inderdaad dat werkt perfect nu ben ik zelf even verder gegaan maar
het gaat om 100 regels of misschien nog meer.
Ik heb het hier onder gezet hoe ik het doe, zou veel type werk zijn maar
als het niet anders kan ga ik wel uurtje zitten....

Misschien heeft U een idee? zou me verwonderen als u zou zeggen nee heb ik
niet 1 - 2 - 3

alvast bedankt

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Address = "$N$4" Then
Cancel = -1
Range("B4:E4") = Range("F1").Value
End If
If Target.Address = "$O$4" Then
Cancel = -1
Range("G4:J4") = Range("F1").Value
End If
If Target.Address = "$N$5" Then
Cancel = -1
Range("B5:E5") = Range("F1").Value
End If
If Target.Address = "$O$5" Then
Cancel = -1
Range("G5:J5") = Range("F1").Value
End If
End Sub

:thumb::d

 

[VenA]

Misschien is het handig dat je eerst wat basiskennis tot je neemt. Cancel = -1 is hetzelfde als Cancel = True. Hierdoor zorg je ervoor dat de cel niet 'open' blijft staan. Dit hoef je natuurlijk maar één keer te gebruiken.

Zonder voorbeeldbestand denk ik dat je zoiets wil

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Not Intersect(Target, Range("N4:O200")) Is Nothing Then
  Cancel = True
  Cells(Target.Row, 5 * (Target.Column - 14) + 2).Resize(, 4) = Range("F1").Value
 End If
End Sub