Opgelost Een formule die alles na de laatste / bewaard. Is dat mogelijk ?

[peterkiers]

Hoi,
Ik heb duizende records met een kolom waarbij een pad is opgeslagen: bijv: xx/xxxxxx/xxxxxx/xxx
Is het mogelijk een formule te maken of is er een andere manier die alleen de tekst bewaard na de laatste /

gr

 

[peter59]

Yep, power query.

 

[peterkiers]

Ik heb ook deze formule gevonden:
=ALS(FOUT(VIND.ALLES("/";F2));F2;RECHTS(F2;LEN(F2)-VINDEN("|";SUBSTITUEREN(F2;"/";"|";LEN(F2)-LEN(SUBSTITUEREN(F2;"/";""))))))
maar krijg deze functie is ongeldig
En F2 is de cell waar het om gaat
Ik mag niet in Power query

 

[keesbl]

Kan het zijn dat je lengte moet gebruiken in plaats van len?

Kees

 

[HSV]

Bv.
Voor Office 365.

=TEKST.NA(A1;"/";LENGTE(A1)-LENGTE(SUBSTITUEREN(A1;"/";"")))

Of iedere versie.

=DEEL(A1;VIND.ALLES("#";SUBSTITUEREN(A1;"/";"#";LENGTE(A1)-LENGTE(SUBSTITUEREN(A1;"/";""))))+1;99)

 

[JEC.]

Met een TAKE en een TEXTSPLIT ben je er ook.

Of nog beter via TEKST.NA(txt; delimiter;-1)

 

[HSV]

En dan gelijk het gehele bereik met die duizend records erin.

 

[AlexCEL]

Nog eentje voor (bijna) alle versies van Excel:

=XML.FILTEREN("<t><s>"&SUBSTITUEREN(A1;"/";"</s><s>")&"</s></t>";"//s[last()]")