Een ISO weeknummer verkrijgen

[DutchOirs]

Goedemorgen,

Zit met een vraagje / probleempje.

Gaat dus over het weeknummer.

Met

=WEEKNUMMER(C8)     'C8 = Datum met NU()

Met deze formule geeft ie dus het weeknummer. tot dusver correct.
Maar gebruik dus het ISO weeknummer en zoals men weet was het 1 Januari op een zaterdag, dus volgens ISO nog geen nieuwe week, dus viel onder week 52.
Pas de week erop (maandags) werd het week 1 volgens ISO.
Maak iedere zaterdag een updating van gegevens en stuur dit rond.
Nu wordt m'n prog. op 1 januari geüpdatet en alle (oude) gegevens gewist.
Dus liep tegen het probleem aan dat na de Trekking op Zaterdag de Data die ik verkreeg op week 52 werd neergezet.
Maar het geheel loopt dus fout met die weeknummers.
Had als oplossing dat deze Trekking dan week 0 werd genoemd en boven aan de lijst werd neergezet.

Probleem is nu dat de formule niet goed werkt om deze "0" te verkrijgen.
Had als formule in cel C12:

=ALS(INTEGER((C8-DATUM(JAAR(C8-WEEKDAG(C8-1)+4);1;3)+WEEKDAG(DATUM(JAAR(C8-WEEKDAG(C8-1)+4);1;3))+5)/7)=53;0;
INTEGER((C8-DATUM(JAAR(C8-WEEKDAG(C8-1)+4);1;3)+WEEKDAG(DATUM(JAAR(C8-WEEKDAG(C8-1)+4);1;3))+5)/7))

Kom er dus niet helemaal uit, wat is er hier verkeerd aan?
Gaat dus om cel C12


Gr.

Dutch

 

[edmoor]

Het juiste weeknummer haal je op met ISO.WEEKNUMMER(C8) of WEEKNUMMER(C8; 21).
Daarnaast is een weeknummer nooit 0.

 

[DutchOirs]

Hoi Edmoor, de beste wensen nog.

die 2 optie met ISO.WEEKNUMMER C8 en WEEKNUMMER(C8;21) werken beidde niet.
Gebruik Excel 2003, misschien dat het daaraan ligt.

Maar gebruik weeknummer 0, om deze boven aan het lijstje te zetten van uitslagen.

Het volgende gebeurde namelijk:

- 1 januari, start prog. op.
- prog schoont prog. op en ook alle uitslagen van zaterdagen met weeknummers en datum van die zaterdagen.
- vervolgens wordt er een trekking gedaan van die zaterdag, zijnde 1 januari, maar wordt toch onder week 52 neergezet daar het volgens ISO week 52 is.
- om dit probleem te overbruggen dacht ik, maak week 0 aan en vanaf die volgende zaterdag wordt het week 1, want we gebruiken de ISO norm.

 

[snb]

Staat al jaren voor je klaar: https://www.snb-vba.eu/VBA_ISO_weeknummer.html

 

[edmoor]

Tijd voor een update van je Office versie.

 

[snb]

Voor een weeknummerweergave ?

 

[edmoor]

En alle andere mooi dingen die er bij gekomen zijn

 

[AlexCEL]

Uit het archief nog een optie met in A1 de datum:

=INTEGER((A1-SOM(REST(DATUM(JAAR(A1-REST(A1-2;7)+3);1;2);{1E+99\7})*{1\-1})+5)/7)

Met dank aan Albatros (https://www.helpmij.nl/forum/showthread.php/337318-Weeknummer-bepalen)

 

[snb]

@Alexcel

Is die in taal toe te lichten ?

Mijn voorkeur:

=GEHEEL((A1-WEEKDAG(A1;2)+4-DATUM(JAAR(A1-WEEKDAG(A1;2)+4);1;1))/7)+1

 

[AlexCEL]

@snb. Pff, daar zou ik wel even een studie van moeten maken dan. Kwam 'm tegen in het archief (niet zelf bedacht), heb 'm vergeleken met ISO.WEEKNUMMER en er kwamen dezelfde resultaten uit. Maar als ik moet kiezen neem ik ook die van jou...

 

[snb]

Vooral die intrigerende

*{1\-1}

 

[DutchOirs]

Goedenavond allen,

Zo weer even tijd om te kijken.

ISO.WEEKNUMMER werkt niet hier.

Chapeau en thanks voor AlexCEL & snb.

beidde werken en geven op 1 januari week 52 aan (volgens iso weeknummer)

Nu moet ik gaan kiezen welk ik ga gebruiken .

Maar even terugkomende op voorgaande, alles is net opgeschoond na opstart dus alle data om een Update te maken is weg.
Hij zou nu week 52 neer zetten, maar lijkt me niet slim. Dus week "0" blijft nog even staan.
Wat betreft het opzoeken van deze Data, gebeurt met de datum die er aan vast zit.

 

[DutchOirs]

Ok ter afsluiting, het volgende opgelost.

=ALS(EN(INTEGER((C8-SOM(REST(DATUM(JAAR(C8-REST(C8-2;7)+3);1;2);{1E+99\7})*{1\-1})+5)/7)=52;C10=1);0;INTEGER((C8-SOM(REST(DATUM(JAAR(C8-REST(C8-2;7)+3);1;2);{1E+99\7})*{1\-1})+5)/7))

Dus als het week 52 is (ISO) en maand = 12 (december) dan zet ie weeknummer 52 neer
en als het week 52 is (ISO) en maand = 1 (januari) dan zet ie weeknummer 0 neer

Alles ter verkrijging van een oplopend Updating nummer.

Allemaal bedankt voor het meedenken en hulp...

Vr. Gr.

Dutch

 

[snb]

@dutch

De toelichting op de formule staat in de gelinkte pagina.
Dan kun je ook snappen wat zo'n formule doet.

 

[DutchOirs]

Thanks snb